arch/x86/cpu/start.S

   1 /*
   2  *  U-boot - x86 Startup Code
   3  *
   4  * (C) Copyright 2008-2011
   5  * Graeme Russ, <graeme.russ@gmail.com>
   6  *
   7  * (C) Copyright 2002
   8  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
   9  *
  10  * SPDX-License-Identifier:     GPL-2.0+
  11  */
  12
  13 #include <config.h>
  14 #include <version.h>
  15 #include <asm/global_data.h>
  16 #include <asm/post.h>
  17 #include <asm/processor.h>
  18 #include <asm/processor-flags.h>
  19 #include <generated/generic-asm-offsets.h>
  20
  21 .section .text
  22 .code32
  23 .globl _start
  24 .type _start, @function
  25 .globl _x86boot_start
  26 _x86boot_start:
  27         /*
  28          * This is the fail safe 32-bit bootstrap entry point. The
  29          * following code is not executed from a cold-reset (actually, a
  30          * lot of it is, but from real-mode after cold reset. It is
  31          * repeated here to put the board into a state as close to cold
  32          * reset as necessary)
  33          */
  34         cli
  35         cld
  36
  37         /* Turn off cache (this might require a 486-class CPU) */
  38         movl    %cr0, %eax
  39         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  40         movl    %eax, %cr0
  41         wbinvd
  42
  43         /* Tell 32-bit code it is being entered from an in-RAM copy */
  44         movw    $GD_FLG_WARM_BOOT, %bx
  45         jmp     1f
  46 _start:
  47         /*
  48          * This is the 32-bit cold-reset entry point. Initialize %bx to 0
  49          * in case we're preceeded by some sort of boot stub.
  50          */
  51         movw    $GD_FLG_COLD_BOOT, %bx
  52 1:
  53         /* Save BIST */
  54         movl    %eax, %ebp
  55
  56         /* Load the segement registes to match the gdt loaded in start16.S */
  57         movl    $(X86_GDT_ENTRY_32BIT_DS * X86_GDT_ENTRY_SIZE), %eax
  58         movw    %ax, %fs
  59         movw    %ax, %ds
  60         movw    %ax, %gs
  61         movw    %ax, %es
  62         movw    %ax, %ss
  63
  64         /* Clear the interrupt vectors */
  65         lidt    blank_idt_ptr
  66
  67         /* Early platform init (setup gpio, etc ) */
  68         jmp     early_board_init
  69 .globl early_board_init_ret
  70 early_board_init_ret:
  71         post_code(POST_START)
  72
  73         /* Initialise Cache-As-RAM */
  74         jmp     car_init
  75 .globl car_init_ret
  76 car_init_ret:
  77         /*
  78          * We now have CONFIG_SYS_CAR_SIZE bytes of Cache-As-RAM (or SRAM,
  79          * or fully initialised SDRAM - we really don't care which)
  80          * starting at CONFIG_SYS_CAR_ADDR to be used as a temporary stack
  81          * and early malloc area.
  82          *
  83          * Stack grows down from top of CAR. We have:
  84          *
  85          * top-> CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE
  86          *      global_data
  87          *      x86 global descriptor table
  88          *      early malloc area
  89          *      stack
  90          * bottom-> CONFIG_SYS_CAR_ADDR
  91          */
  92
  93         /* Stack grows down from top of CAR */
  94         movl    $(CONFIG_SYS_CAR_ADDR + CONFIG_SYS_CAR_SIZE), %esp
  95
  96         /* Reserve space on stack for global data */
  97         subl    $GENERATED_GBL_DATA_SIZE, %esp
  98
  99         /* Align global data to 16-byte boundary */
 100         andl    $0xfffffff0, %esp
 101         post_code(POST_START_STACK)
 102
 103         /* Zero the global data since it won't happen later */
 104         xorl    %eax, %eax
 105         movl    $GENERATED_GBL_DATA_SIZE, %ecx
 106         movl    %esp, %edi
 107         rep     stosb
 108
 109         /* Setup first parameter to setup_gdt, pointer to global_data */
 110         movl    %esp, %eax
 111
 112         /* Reserve space for global descriptor table */
 113         subl    $X86_GDT_SIZE, %esp
 114
 115         /* Align temporary global descriptor table to 16-byte boundary */
 116         andl    $0xfffffff0, %esp
 117         movl    %esp, %ecx
 118
 119 #if defined(CONFIG_SYS_MALLOC_F_LEN)
 120         subl    $CONFIG_SYS_MALLOC_F_LEN, %esp
 121         movl    %eax, %edx
 122         addl    $GD_MALLOC_BASE, %edx
 123         movl    %esp, (%edx)
 124 #endif
 125         /* Store BIST */
 126         movl    %eax, %edx
 127         addl    $GD_BIST, %edx
 128         movl    %ebp, (%edx)
 129
 130         /* Set second parameter to setup_gdt */
 131         movl    %ecx, %edx
 132
 133         /* Setup global descriptor table so gd->xyz works */
 134         call    setup_gdt
 135
 136         /* Set parameter to board_init_f() to boot flags */
 137         post_code(POST_START_DONE)
 138         xorl    %eax, %eax
 139
 140         /* Enter, U-boot! */
 141         call    board_init_f
 142
 143         /* indicate (lack of) progress */
 144         movw    $0x85, %ax
 145         jmp     die
 146
 147 .globl board_init_f_r_trampoline
 148 .type board_init_f_r_trampoline, @function
 149 board_init_f_r_trampoline:
 150         /*
 151          * SDRAM has been initialised, U-Boot code has been copied into
 152          * RAM, BSS has been cleared and relocation adjustments have been
 153          * made. It is now time to jump into the in-RAM copy of U-Boot
 154          *
 155          * %eax = Address of top of new stack
 156          */
 157
 158         /* Stack grows down from top of SDRAM */
 159         movl    %eax, %esp
 160
 161         /* Reserve space on stack for global data */
 162         subl    $GENERATED_GBL_DATA_SIZE, %esp
 163
 164         /* Align global data to 16-byte boundary */
 165         andl    $0xfffffff0, %esp
 166
 167         /* Setup first parameter to memcpy (and setup_gdt) */
 168         movl    %esp, %eax
 169
 170         /* Setup second parameter to memcpy */
 171         fs movl 0, %edx
 172
 173         /* Set third parameter to memcpy */
 174         movl    $GENERATED_GBL_DATA_SIZE, %ecx
 175
 176         /* Copy global data from CAR to SDRAM stack */
 177         call    memcpy
 178
 179         /* Reserve space for global descriptor table */
 180         subl    $X86_GDT_SIZE, %esp
 181
 182         /* Align global descriptor table to 16-byte boundary */
 183         andl    $0xfffffff0, %esp
 184
 185         /* Set second parameter to setup_gdt */
 186         movl    %esp, %edx
 187
 188         /* Setup global descriptor table so gd->xyz works */
 189         call    setup_gdt
 190
 191         /* Re-enter U-Boot by calling board_init_f_r */
 192         call    board_init_f_r
 193
 194 die:
 195         hlt
 196         jmp     die
 197         hlt
 198
 199 blank_idt_ptr:
 200         .word   0               /* limit */
 201         .long   0               /* base */
 202
 203         .p2align        2       /* force 4-byte alignment */
 204
 205 multiboot_header:
 206         /* magic */
 207         .long   0x1BADB002
 208         /* flags */
 209         .long   (1 << 16)
 210         /* checksum */
 211         .long   -0x1BADB002 - (1 << 16)
 212         /* header addr */
 213         .long   multiboot_header - _x86boot_start + CONFIG_SYS_TEXT_BASE
 214         /* load addr */
 215         .long   CONFIG_SYS_TEXT_BASE
 216         /* load end addr */
 217         .long   0
 218         /* bss end addr */
 219         .long   0
 220         /* entry addr */
 221         .long   CONFIG_SYS_TEXT_BASE