arch/powerpc/kernel/exceptions-64s.S

   1 /*
   2  * This file contains the 64-bit "server" PowerPC variant
   3  * of the low level exception handling including exception
   4  * vectors, exception return, part of the slb and stab
   5  * handling and other fixed offset specific things.
   6  *
   7  * This file is meant to be #included from head_64.S due to
   8  * position dependent assembly.
   9  *
  10  * Most of this originates from head_64.S and thus has the same
  11  * copyright history.
  12  *
  13  */
  14
  15 #include <asm/hw_irq.h>
  16 #include <asm/exception-64s.h>
  17 #include <asm/ptrace.h>
  18 #include <asm/cpuidle.h>
  19 #include <asm/head-64.h>
  20
  21 /*
  22  * There are a few constraints to be concerned with.
  23  * - Real mode exceptions code/data must be located at their physical location.
  24  * - Virtual mode exceptions must be mapped at their 0xc000... location.
  25  * - Fixed location code must not call directly beyond the __end_interrupts
  26  *   area when built with CONFIG_RELOCATABLE. LOAD_HANDLER / bctr sequence
  27  *   must be used.
  28  * - LOAD_HANDLER targets must be within first 64K of physical 0 /
  29  *   virtual 0xc00...
  30  * - Conditional branch targets must be within +/-32K of caller.
  31  *
  32  * "Virtual exceptions" run with relocation on (MSR_IR=1, MSR_DR=1), and
  33  * therefore don't have to run in physically located code or rfid to
  34  * virtual mode kernel code. However on relocatable kernels they do have
  35  * to branch to KERNELBASE offset because the rest of the kernel (outside
  36  * the exception vectors) may be located elsewhere.
  37  *
  38  * Virtual exceptions correspond with physical, except their entry points
  39  * are offset by 0xc000000000000000 and also tend to get an added 0x4000
  40  * offset applied. Virtual exceptions are enabled with the Alternate
  41  * Interrupt Location (AIL) bit set in the LPCR. However this does not
  42  * guarantee they will be delivered virtually. Some conditions (see the ISA)
  43  * cause exceptions to be delivered in real mode.
  44  *
  45  * It's impossible to receive interrupts below 0x300 via AIL.
  46  *
  47  * KVM: None of the virtual exceptions are from the guest. Anything that
  48  * escalated to HV=1 from HV=0 is delivered via real mode handlers.
  49  *
  50  *
  51  * We layout physical memory as follows:
  52  * 0x0000 - 0x00ff : Secondary processor spin code
  53  * 0x0100 - 0x18ff : Real mode pSeries interrupt vectors
  54  * 0x1900 - 0x3fff : Real mode trampolines
  55  * 0x4000 - 0x58ff : Relon (IR=1,DR=1) mode pSeries interrupt vectors
  56  * 0x5900 - 0x6fff : Relon mode trampolines
  57  * 0x7000 - 0x7fff : FWNMI data area
  58  * 0x8000 -   .... : Common interrupt handlers, remaining early
  59  *                   setup code, rest of kernel.
  60  */
  61 OPEN_FIXED_SECTION(real_vectors,        0x0100, 0x1900)
  62 OPEN_FIXED_SECTION(real_trampolines,    0x1900, 0x4000)
  63 OPEN_FIXED_SECTION(virt_vectors,        0x4000, 0x5900)
  64 OPEN_FIXED_SECTION(virt_trampolines,    0x5900, 0x7000)
  65 #if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
  66 /*
  67  * Data area reserved for FWNMI option.
  68  * This address (0x7000) is fixed by the RPA.
  69  * pseries and powernv need to keep the whole page from
  70  * 0x7000 to 0x8000 free for use by the firmware
  71  */
  72 ZERO_FIXED_SECTION(fwnmi_page,          0x7000, 0x8000)
  73 OPEN_TEXT_SECTION(0x8000)
  74 #else
  75 OPEN_TEXT_SECTION(0x7000)
  76 #endif
  77
  78 USE_FIXED_SECTION(real_vectors)
  79
  80 #define LOAD_SYSCALL_HANDLER(reg)                               \
  81         ld      reg,PACAKBASE(r13);                             \
  82         ori     reg,reg,(ABS_ADDR(system_call_common))@l;
  83
  84         /* Syscall routine is used twice, in reloc-off and reloc-on paths */
  85 #define SYSCALL_PSERIES_1                                       \
  86 BEGIN_FTR_SECTION                                               \
  87         cmpdi   r0,0x1ebe ;                                     \
  88         beq-    1f ;                                            \
  89 END_FTR_SECTION_IFSET(CPU_FTR_REAL_LE)                          \
  90         mr      r9,r13 ;                                        \
  91         GET_PACA(r13) ;                                         \
  92         mfspr   r11,SPRN_SRR0 ;                                 \
  93 0:
  94
  95 #define SYSCALL_PSERIES_2_RFID                                  \
  96         mfspr   r12,SPRN_SRR1 ;                                 \
  97         LOAD_SYSCALL_HANDLER(r10) ;                             \
  98         mtspr   SPRN_SRR0,r10 ;                                 \
  99         ld      r10,PACAKMSR(r13) ;                             \
 100         mtspr   SPRN_SRR1,r10 ;                                 \
 101         rfid ;                                                  \
 102         b       . ;     /* prevent speculative execution */
 103
 104 #define SYSCALL_PSERIES_3                                       \
 105         /* Fast LE/BE switch system call */                     \
 106 1:      mfspr   r12,SPRN_SRR1 ;                                 \
 107         xori    r12,r12,MSR_LE ;                                \
 108         mtspr   SPRN_SRR1,r12 ;                                 \
 109         rfid ;          /* return to userspace */               \
 110         b       . ;     /* prevent speculative execution */
 111
 112 #if defined(CONFIG_RELOCATABLE)
 113         /*
 114          * We can't branch directly so we do it via the CTR which
 115          * is volatile across system calls.
 116          */
 117 #define SYSCALL_PSERIES_2_DIRECT                                \
 118         LOAD_SYSCALL_HANDLER(r12) ;                             \
 119         mtctr   r12 ;                                           \
 120         mfspr   r12,SPRN_SRR1 ;                                 \
 121         li      r10,MSR_RI ;                                    \
 122         mtmsrd  r10,1 ;                                         \
 123         bctr ;
 124 #else
 125         /* We can branch directly */
 126 #define SYSCALL_PSERIES_2_DIRECT                                \
 127         mfspr   r12,SPRN_SRR1 ;                                 \
 128         li      r10,MSR_RI ;                                    \
 129         mtmsrd  r10,1 ;                 /* Set RI (EE=0) */     \
 130         b       system_call_common ;
 131 #endif
 132
 133 /*
 134  * This is the start of the interrupt handlers for pSeries
 135  * This code runs with relocation off.
 136  * Code from here to __end_interrupts gets copied down to real
 137  * address 0x100 when we are running a relocatable kernel.
 138  * Therefore any relative branches in this section must only
 139  * branch to labels in this section.
 140  */
 141         .globl __start_interrupts
 142 __start_interrupts:
 143
 144 EXC_REAL_BEGIN(system_reset, 0x100, 0x200)
 145         SET_SCRATCH0(r13)
 146 #ifdef CONFIG_PPC_P7_NAP
 147 BEGIN_FTR_SECTION
 148         /* Running native on arch 2.06 or later, check if we are
 149          * waking up from nap/sleep/winkle.
 150          */
 151         mfspr   r13,SPRN_SRR1
 152         rlwinm. r13,r13,47-31,30,31
 153         beq     9f
 154
 155         cmpwi   cr3,r13,2
 156         GET_PACA(r13)
 157         bl      pnv_restore_hyp_resource
 158
 159         li      r0,PNV_THREAD_RUNNING
 160         stb     r0,PACA_THREAD_IDLE_STATE(r13)  /* Clear thread state */
 161
 162 #ifdef CONFIG_KVM_BOOK3S_HV_POSSIBLE
 163         li      r0,KVM_HWTHREAD_IN_KERNEL
 164         stb     r0,HSTATE_HWTHREAD_STATE(r13)
 165         /* Order setting hwthread_state vs. testing hwthread_req */
 166         sync
 167         lbz     r0,HSTATE_HWTHREAD_REQ(r13)
 168         cmpwi   r0,0
 169         beq     1f
 170         b       kvm_start_guest
 171 1:
 172 #endif
 173
 174         /* Return SRR1 from power7_nap() */
 175         mfspr   r3,SPRN_SRR1
 176         blt     cr3,2f
 177         b       pnv_wakeup_loss
 178 2:      b       pnv_wakeup_noloss
 179
 180 9:
 181 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 182 #endif /* CONFIG_PPC_P7_NAP */
 183         EXCEPTION_PROLOG_PSERIES(PACA_EXGEN, system_reset_common, EXC_STD,
 184                                  NOTEST, 0x100)
 185 EXC_REAL_END(system_reset, 0x100, 0x200)
 186 EXC_VIRT_NONE(0x4100, 0x4200)
 187 EXC_COMMON(system_reset_common, 0x100, system_reset_exception)
 188
 189 #ifdef CONFIG_PPC_PSERIES
 190 /*
 191  * Vectors for the FWNMI option.  Share common code.
 192  */
 193 TRAMP_REAL_BEGIN(system_reset_fwnmi)
 194         SET_SCRATCH0(r13)               /* save r13 */
 195         EXCEPTION_PROLOG_PSERIES(PACA_EXGEN, system_reset_common, EXC_STD,
 196                                  NOTEST, 0x100)
 197 #endif /* CONFIG_PPC_PSERIES */
 198
 199
 200 EXC_REAL_BEGIN(machine_check, 0x200, 0x300)
 201         /* This is moved out of line as it can be patched by FW, but
 202          * some code path might still want to branch into the original
 203          * vector
 204          */
 205         SET_SCRATCH0(r13)               /* save r13 */
 206         /*
 207          * Running native on arch 2.06 or later, we may wakeup from winkle
 208          * inside machine check. If yes, then last bit of HSPGR0 would be set
 209          * to 1. Hence clear it unconditionally.
 210          */
 211         GET_PACA(r13)
 212         clrrdi  r13,r13,1
 213         SET_PACA(r13)
 214         EXCEPTION_PROLOG_0(PACA_EXMC)
 215 BEGIN_FTR_SECTION
 216         b       machine_check_powernv_early
 217 FTR_SECTION_ELSE
 218         b       machine_check_pSeries_0
 219 ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE)
 220 EXC_REAL_END(machine_check, 0x200, 0x300)
 221 EXC_VIRT_NONE(0x4200, 0x4300)
 222 TRAMP_REAL_BEGIN(machine_check_powernv_early)
 223 BEGIN_FTR_SECTION
 224         EXCEPTION_PROLOG_1(PACA_EXMC, NOTEST, 0x200)
 225         /*
 226          * Register contents:
 227          * R13          = PACA
 228          * R9           = CR
 229          * Original R9 to R13 is saved on PACA_EXMC
 230          *
 231          * Switch to mc_emergency stack and handle re-entrancy (we limit
 232          * the nested MCE upto level 4 to avoid stack overflow).
 233          * Save MCE registers srr1, srr0, dar and dsisr and then set ME=1
 234          *
 235          * We use paca->in_mce to check whether this is the first entry or
 236          * nested machine check. We increment paca->in_mce to track nested
 237          * machine checks.
 238          *
 239          * If this is the first entry then set stack pointer to
 240          * paca->mc_emergency_sp, otherwise r1 is already pointing to
 241          * stack frame on mc_emergency stack.
 242          *
 243          * NOTE: We are here with MSR_ME=0 (off), which means we risk a
 244          * checkstop if we get another machine check exception before we do
 245          * rfid with MSR_ME=1.
 246          */
 247         mr      r11,r1                  /* Save r1 */
 248         lhz     r10,PACA_IN_MCE(r13)
 249         cmpwi   r10,0                   /* Are we in nested machine check */
 250         bne     0f                      /* Yes, we are. */
 251         /* First machine check entry */
 252         ld      r1,PACAMCEMERGSP(r13)   /* Use MC emergency stack */
 253 0:      subi    r1,r1,INT_FRAME_SIZE    /* alloc stack frame */
 254         addi    r10,r10,1               /* increment paca->in_mce */
 255         sth     r10,PACA_IN_MCE(r13)
 256         /* Limit nested MCE to level 4 to avoid stack overflow */
 257         cmpwi   r10,4
 258         bgt     2f                      /* Check if we hit limit of 4 */
 259         std     r11,GPR1(r1)            /* Save r1 on the stack. */
 260         std     r11,0(r1)               /* make stack chain pointer */
 261         mfspr   r11,SPRN_SRR0           /* Save SRR0 */
 262         std     r11,_NIP(r1)
 263         mfspr   r11,SPRN_SRR1           /* Save SRR1 */
 264         std     r11,_MSR(r1)
 265         mfspr   r11,SPRN_DAR            /* Save DAR */
 266         std     r11,_DAR(r1)
 267         mfspr   r11,SPRN_DSISR          /* Save DSISR */
 268         std     r11,_DSISR(r1)
 269         std     r9,_CCR(r1)             /* Save CR in stackframe */
 270         /* Save r9 through r13 from EXMC save area to stack frame. */
 271         EXCEPTION_PROLOG_COMMON_2(PACA_EXMC)
 272         mfmsr   r11                     /* get MSR value */
 273         ori     r11,r11,MSR_ME          /* turn on ME bit */
 274         ori     r11,r11,MSR_RI          /* turn on RI bit */
 275         LOAD_HANDLER(r12, machine_check_handle_early)
 276 1:      mtspr   SPRN_SRR0,r12
 277         mtspr   SPRN_SRR1,r11
 278         rfid
 279         b       .       /* prevent speculative execution */
 280 2:
 281         /* Stack overflow. Stay on emergency stack and panic.
 282          * Keep the ME bit off while panic-ing, so that if we hit
 283          * another machine check we checkstop.
 284          */
 285         addi    r1,r1,INT_FRAME_SIZE    /* go back to previous stack frame */
 286         ld      r11,PACAKMSR(r13)
 287         LOAD_HANDLER(r12, unrecover_mce)
 288         li      r10,MSR_ME
 289         andc    r11,r11,r10             /* Turn off MSR_ME */
 290         b       1b
 291         b       .       /* prevent speculative execution */
 292 END_FTR_SECTION_IFSET(CPU_FTR_HVMODE)
 293
 294 TRAMP_REAL_BEGIN(machine_check_pSeries)
 295         .globl machine_check_fwnmi
 296 machine_check_fwnmi:
 297         SET_SCRATCH0(r13)               /* save r13 */
 298         EXCEPTION_PROLOG_0(PACA_EXMC)
 299 machine_check_pSeries_0:
 300         EXCEPTION_PROLOG_1(PACA_EXMC, KVMTEST_PR, 0x200)
 301         /*
 302          * The following is essentially EXCEPTION_PROLOG_PSERIES_1 with the
 303          * difference that MSR_RI is not enabled, because PACA_EXMC is being
 304          * used, so nested machine check corrupts it. machine_check_common
 305          * enables MSR_RI.
 306          */
 307         ld      r10,PACAKMSR(r13)
 308         xori    r10,r10,MSR_RI
 309         mfspr   r11,SPRN_SRR0
 310         LOAD_HANDLER(r12, machine_check_common)
 311         mtspr   SPRN_SRR0,r12
 312         mfspr   r12,SPRN_SRR1
 313         mtspr   SPRN_SRR1,r10
 314         rfid
 315         b       .       /* prevent speculative execution */
 316
 317 TRAMP_KVM_SKIP(PACA_EXMC, 0x200)
 318
 319 EXC_COMMON_BEGIN(machine_check_common)
 320         /*
 321          * Machine check is different because we use a different
 322          * save area: PACA_EXMC instead of PACA_EXGEN.
 323          */
 324         mfspr   r10,SPRN_DAR
 325         std     r10,PACA_EXMC+EX_DAR(r13)
 326         mfspr   r10,SPRN_DSISR
 327         stw     r10,PACA_EXMC+EX_DSISR(r13)
 328         EXCEPTION_PROLOG_COMMON(0x200, PACA_EXMC)
 329         FINISH_NAP
 330         RECONCILE_IRQ_STATE(r10, r11)
 331         ld      r3,PACA_EXMC+EX_DAR(r13)
 332         lwz     r4,PACA_EXMC+EX_DSISR(r13)
 333         /* Enable MSR_RI when finished with PACA_EXMC */
 334         li      r10,MSR_RI
 335         mtmsrd  r10,1
 336         std     r3,_DAR(r1)
 337         std     r4,_DSISR(r1)
 338         bl      save_nvgprs
 339         addi    r3,r1,STACK_FRAME_OVERHEAD
 340         bl      machine_check_exception
 341         b       ret_from_except
 342
 343 #define MACHINE_CHECK_HANDLER_WINDUP                    \
 344         /* Clear MSR_RI before setting SRR0 and SRR1. */\
 345         li      r0,MSR_RI;                              \
 346         mfmsr   r9;             /* get MSR value */     \
 347         andc    r9,r9,r0;                               \
 348         mtmsrd  r9,1;           /* Clear MSR_RI */      \
 349         /* Move original SRR0 and SRR1 into the respective regs */      \
 350         ld      r9,_MSR(r1);                            \
 351         mtspr   SPRN_SRR1,r9;                           \
 352         ld      r3,_NIP(r1);                            \
 353         mtspr   SPRN_SRR0,r3;                           \
 354         ld      r9,_CTR(r1);                            \
 355         mtctr   r9;                                     \
 356         ld      r9,_XER(r1);                            \
 357         mtxer   r9;                                     \
 358         ld      r9,_LINK(r1);                           \
 359         mtlr    r9;                                     \
 360         REST_GPR(0, r1);                                \
 361         REST_8GPRS(2, r1);                              \
 362         REST_GPR(10, r1);                               \
 363         ld      r11,_CCR(r1);                           \
 364         mtcr    r11;                                    \
 365         /* Decrement paca->in_mce. */                   \
 366         lhz     r12,PACA_IN_MCE(r13);                   \
 367         subi    r12,r12,1;                              \
 368         sth     r12,PACA_IN_MCE(r13);                   \
 369         REST_GPR(11, r1);                               \
 370         REST_2GPRS(12, r1);                             \
 371         /* restore original r1. */                      \
 372         ld      r1,GPR1(r1)
 373
 374         /*
 375          * Handle machine check early in real mode. We come here with
 376          * ME=1, MMU (IR=0 and DR=0) off and using MC emergency stack.
 377          */
 378 EXC_COMMON_BEGIN(machine_check_handle_early)
 379         std     r0,GPR0(r1)     /* Save r0 */
 380         EXCEPTION_PROLOG_COMMON_3(0x200)
 381         bl      save_nvgprs
 382         addi    r3,r1,STACK_FRAME_OVERHEAD
 383         bl      machine_check_early
 384         std     r3,RESULT(r1)   /* Save result */
 385         ld      r12,_MSR(r1)
 386 #ifdef  CONFIG_PPC_P7_NAP
 387         /*
 388          * Check if thread was in power saving mode. We come here when any
 389          * of the following is true:
 390          * a. thread wasn't in power saving mode
 391          * b. thread was in power saving mode with no state loss,
 392          *    supervisor state loss or hypervisor state loss.
 393          *
 394          * Go back to nap/sleep/winkle mode again if (b) is true.
 395          */
 396         rlwinm. r11,r12,47-31,30,31     /* Was it in power saving mode? */
 397         beq     4f                      /* No, it wasn;t */
 398         /* Thread was in power saving mode. Go back to nap again. */
 399         cmpwi   r11,2
 400         blt     3f
 401         /* Supervisor/Hypervisor state loss */
 402         li      r0,1
 403         stb     r0,PACA_NAPSTATELOST(r13)
 404 3:      bl      machine_check_queue_event
 405         MACHINE_CHECK_HANDLER_WINDUP
 406         GET_PACA(r13)
 407         ld      r1,PACAR1(r13)
 408         /*
 409          * Check what idle state this CPU was in and go back to same mode
 410          * again.
 411          */
 412         lbz     r3,PACA_THREAD_IDLE_STATE(r13)
 413         cmpwi   r3,PNV_THREAD_NAP
 414         bgt     10f
 415         IDLE_STATE_ENTER_SEQ(PPC_NAP)
 416         /* No return */
 417 10:
 418         cmpwi   r3,PNV_THREAD_SLEEP
 419         bgt     2f
 420         IDLE_STATE_ENTER_SEQ(PPC_SLEEP)
 421         /* No return */
 422
 423 2:
 424         /*
 425          * Go back to winkle. Please note that this thread was woken up in
 426          * machine check from winkle and have not restored the per-subcore
 427          * state. Hence before going back to winkle, set last bit of HSPGR0
 428          * to 1. This will make sure that if this thread gets woken up
 429          * again at reset vector 0x100 then it will get chance to restore
 430          * the subcore state.
 431          */
 432         ori     r13,r13,1
 433         SET_PACA(r13)
 434         IDLE_STATE_ENTER_SEQ(PPC_WINKLE)
 435         /* No return */
 436 4:
 437 #endif
 438         /*
 439          * Check if we are coming from hypervisor userspace. If yes then we
 440          * continue in host kernel in V mode to deliver the MC event.
 441          */
 442         rldicl. r11,r12,4,63            /* See if MC hit while in HV mode. */
 443         beq     5f
 444         andi.   r11,r12,MSR_PR          /* See if coming from user. */
 445         bne     9f                      /* continue in V mode if we are. */
 446
 447 5:
 448 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
 449         /*
 450          * We are coming from kernel context. Check if we are coming from
 451          * guest. if yes, then we can continue. We will fall through
 452          * do_kvm_200->kvmppc_interrupt to deliver the MC event to guest.
 453          */
 454         lbz     r11,HSTATE_IN_GUEST(r13)
 455         cmpwi   r11,0                   /* Check if coming from guest */
 456         bne     9f                      /* continue if we are. */
 457 #endif
 458         /*
 459          * At this point we are not sure about what context we come from.
 460          * Queue up the MCE event and return from the interrupt.
 461          * But before that, check if this is an un-recoverable exception.
 462          * If yes, then stay on emergency stack and panic.
 463          */
 464         andi.   r11,r12,MSR_RI
 465         bne     2f
 466 1:      mfspr   r11,SPRN_SRR0
 467         LOAD_HANDLER(r10,unrecover_mce)
 468         mtspr   SPRN_SRR0,r10
 469         ld      r10,PACAKMSR(r13)
 470         /*
 471          * We are going down. But there are chances that we might get hit by
 472          * another MCE during panic path and we may run into unstable state
 473          * with no way out. Hence, turn ME bit off while going down, so that
 474          * when another MCE is hit during panic path, system will checkstop
 475          * and hypervisor will get restarted cleanly by SP.
 476          */
 477         li      r3,MSR_ME
 478         andc    r10,r10,r3              /* Turn off MSR_ME */
 479         mtspr   SPRN_SRR1,r10
 480         rfid
 481         b       .
 482 2:
 483         /*
 484          * Check if we have successfully handled/recovered from error, if not
 485          * then stay on emergency stack and panic.
 486          */
 487         ld      r3,RESULT(r1)   /* Load result */
 488         cmpdi   r3,0            /* see if we handled MCE successfully */
 489
 490         beq     1b              /* if !handled then panic */
 491         /*
 492          * Return from MC interrupt.
 493          * Queue up the MCE event so that we can log it later, while
 494          * returning from kernel or opal call.
 495          */
 496         bl      machine_check_queue_event
 497         MACHINE_CHECK_HANDLER_WINDUP
 498         rfid
 499 9:
 500         /* Deliver the machine check to host kernel in V mode. */
 501         MACHINE_CHECK_HANDLER_WINDUP
 502         b       machine_check_pSeries
 503
 504 EXC_COMMON_BEGIN(unrecover_mce)
 505         /* Invoke machine_check_exception to print MCE event and panic. */
 506         addi    r3,r1,STACK_FRAME_OVERHEAD
 507         bl      machine_check_exception
 508         /*
 509          * We will not reach here. Even if we did, there is no way out. Call
 510          * unrecoverable_exception and die.
 511          */
 512 1:      addi    r3,r1,STACK_FRAME_OVERHEAD
 513         bl      unrecoverable_exception
 514         b       1b
 515
 516
 517 EXC_REAL(data_access, 0x300, 0x380)
 518 EXC_VIRT(data_access, 0x4300, 0x4380, 0x300)
 519 TRAMP_KVM_SKIP(PACA_EXGEN, 0x300)
 520
 521 EXC_COMMON_BEGIN(data_access_common)
 522         /*
 523          * Here r13 points to the paca, r9 contains the saved CR,
 524          * SRR0 and SRR1 are saved in r11 and r12,
 525          * r9 - r13 are saved in paca->exgen.
 526          */
 527         mfspr   r10,SPRN_DAR
 528         std     r10,PACA_EXGEN+EX_DAR(r13)
 529         mfspr   r10,SPRN_DSISR
 530         stw     r10,PACA_EXGEN+EX_DSISR(r13)
 531         EXCEPTION_PROLOG_COMMON(0x300, PACA_EXGEN)
 532         RECONCILE_IRQ_STATE(r10, r11)
 533         ld      r12,_MSR(r1)
 534         ld      r3,PACA_EXGEN+EX_DAR(r13)
 535         lwz     r4,PACA_EXGEN+EX_DSISR(r13)
 536         li      r5,0x300
 537         std     r3,_DAR(r1)
 538         std     r4,_DSISR(r1)
 539 BEGIN_MMU_FTR_SECTION
 540         b       do_hash_page            /* Try to handle as hpte fault */
 541 MMU_FTR_SECTION_ELSE
 542         b       handle_page_fault
 543 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
 544
 545
 546 EXC_REAL_BEGIN(data_access_slb, 0x380, 0x400)
 547         SET_SCRATCH0(r13)
 548         EXCEPTION_PROLOG_0(PACA_EXSLB)
 549         EXCEPTION_PROLOG_1(PACA_EXSLB, KVMTEST_PR, 0x380)
 550         std     r3,PACA_EXSLB+EX_R3(r13)
 551         mfspr   r3,SPRN_DAR
 552         mfspr   r12,SPRN_SRR1
 553         crset   4*cr6+eq
 554 #ifndef CONFIG_RELOCATABLE
 555         b       slb_miss_realmode
 556 #else
 557         /*
 558          * We can't just use a direct branch to slb_miss_realmode
 559          * because the distance from here to there depends on where
 560          * the kernel ends up being put.
 561          */
 562         mfctr   r11
 563         LOAD_HANDLER(r10, slb_miss_realmode)
 564         mtctr   r10
 565         bctr
 566 #endif
 567 EXC_REAL_END(data_access_slb, 0x380, 0x400)
 568
 569 EXC_VIRT_BEGIN(data_access_slb, 0x4380, 0x4400)
 570         SET_SCRATCH0(r13)
 571         EXCEPTION_PROLOG_0(PACA_EXSLB)
 572         EXCEPTION_PROLOG_1(PACA_EXSLB, NOTEST, 0x380)
 573         std     r3,PACA_EXSLB+EX_R3(r13)
 574         mfspr   r3,SPRN_DAR
 575         mfspr   r12,SPRN_SRR1
 576         crset   4*cr6+eq
 577 #ifndef CONFIG_RELOCATABLE
 578         b       slb_miss_realmode
 579 #else
 580         /*
 581          * We can't just use a direct branch to slb_miss_realmode
 582          * because the distance from here to there depends on where
 583          * the kernel ends up being put.
 584          */
 585         mfctr   r11
 586         LOAD_HANDLER(r10, slb_miss_realmode)
 587         mtctr   r10
 588         bctr
 589 #endif
 590 EXC_VIRT_END(data_access_slb, 0x4380, 0x4400)
 591 TRAMP_KVM_SKIP(PACA_EXSLB, 0x380)
 592
 593
 594 EXC_REAL(instruction_access, 0x400, 0x480)
 595 EXC_VIRT(instruction_access, 0x4400, 0x4480, 0x400)
 596 TRAMP_KVM(PACA_EXGEN, 0x400)
 597
 598 EXC_COMMON_BEGIN(instruction_access_common)
 599         EXCEPTION_PROLOG_COMMON(0x400, PACA_EXGEN)
 600         RECONCILE_IRQ_STATE(r10, r11)
 601         ld      r12,_MSR(r1)
 602         ld      r3,_NIP(r1)
 603         andis.  r4,r12,0x5820
 604         li      r5,0x400
 605         std     r3,_DAR(r1)
 606         std     r4,_DSISR(r1)
 607 BEGIN_MMU_FTR_SECTION
 608         b       do_hash_page            /* Try to handle as hpte fault */
 609 MMU_FTR_SECTION_ELSE
 610         b       handle_page_fault
 611 ALT_MMU_FTR_SECTION_END_IFCLR(MMU_FTR_TYPE_RADIX)
 612
 613
 614 EXC_REAL_BEGIN(instruction_access_slb, 0x480, 0x500)
 615         SET_SCRATCH0(r13)
 616         EXCEPTION_PROLOG_0(PACA_EXSLB)
 617         EXCEPTION_PROLOG_1(PACA_EXSLB, KVMTEST_PR, 0x480)
 618         std     r3,PACA_EXSLB+EX_R3(r13)
 619         mfspr   r3,SPRN_SRR0            /* SRR0 is faulting address */
 620         mfspr   r12,SPRN_SRR1
 621         crclr   4*cr6+eq
 622 #ifndef CONFIG_RELOCATABLE
 623         b       slb_miss_realmode
 624 #else
 625         mfctr   r11
 626         LOAD_HANDLER(r10, slb_miss_realmode)
 627         mtctr   r10
 628         bctr
 629 #endif
 630 EXC_REAL_END(instruction_access_slb, 0x480, 0x500)
 631
 632 EXC_REAL_BEGIN(hardware_interrupt, 0x500, 0x600)
 633         .globl hardware_interrupt_hv;
 634 hardware_interrupt_hv:
 635         BEGIN_FTR_SECTION
 636                 _MASKABLE_EXCEPTION_PSERIES(0x500, hardware_interrupt_common,
 637                                             EXC_HV, SOFTEN_TEST_HV)
 638 do_kvm_H0x500:
 639                 KVM_HANDLER(PACA_EXGEN, EXC_HV, 0x502)
 640         FTR_SECTION_ELSE
 641                 _MASKABLE_EXCEPTION_PSERIES(0x500, hardware_interrupt_common,
 642                                             EXC_STD, SOFTEN_TEST_PR)
 643 do_kvm_0x500:
 644                 KVM_HANDLER(PACA_EXGEN, EXC_STD, 0x500)
 645         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE | CPU_FTR_ARCH_206)
 646 EXC_REAL_END(hardware_interrupt, 0x500, 0x600)
 647
 648 EXC_REAL(alignment, 0x600, 0x700)
 649
 650 TRAMP_KVM(PACA_EXGEN, 0x600)
 651
 652 EXC_REAL(program_check, 0x700, 0x800)
 653
 654 TRAMP_KVM(PACA_EXGEN, 0x700)
 655
 656 EXC_REAL(fp_unavailable, 0x800, 0x900)
 657
 658 TRAMP_KVM(PACA_EXGEN, 0x800)
 659
 660 EXC_REAL_MASKABLE(decrementer, 0x900, 0x980)
 661
 662 EXC_REAL_HV(hdecrementer, 0x980, 0xa00)
 663
 664 EXC_REAL_MASKABLE(doorbell_super, 0xa00, 0xb00)
 665
 666 TRAMP_KVM(PACA_EXGEN, 0xa00)
 667
 668 EXC_REAL(trap_0b, 0xb00, 0xc00)
 669
 670 TRAMP_KVM(PACA_EXGEN, 0xb00)
 671
 672 EXC_REAL_BEGIN(system_call, 0xc00, 0xd00)
 673          /*
 674           * If CONFIG_KVM_BOOK3S_64_HANDLER is set, save the PPR (on systems
 675           * that support it) before changing to HMT_MEDIUM. That allows the KVM
 676           * code to save that value into the guest state (it is the guest's PPR
 677           * value). Otherwise just change to HMT_MEDIUM as userspace has
 678           * already saved the PPR.
 679           */
 680 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
 681         SET_SCRATCH0(r13)
 682         GET_PACA(r13)
 683         std     r9,PACA_EXGEN+EX_R9(r13)
 684         OPT_GET_SPR(r9, SPRN_PPR, CPU_FTR_HAS_PPR);
 685         HMT_MEDIUM;
 686         std     r10,PACA_EXGEN+EX_R10(r13)
 687         OPT_SAVE_REG_TO_PACA(PACA_EXGEN+EX_PPR, r9, CPU_FTR_HAS_PPR);
 688         mfcr    r9
 689         KVMTEST_PR(0xc00)
 690         GET_SCRATCH0(r13)
 691 #else
 692         HMT_MEDIUM;
 693 #endif
 694         SYSCALL_PSERIES_1
 695         SYSCALL_PSERIES_2_RFID
 696         SYSCALL_PSERIES_3
 697 EXC_REAL_END(system_call, 0xc00, 0xd00)
 698
 699 TRAMP_KVM(PACA_EXGEN, 0xc00)
 700
 701 EXC_REAL(single_step, 0xd00, 0xe00)
 702
 703 TRAMP_KVM(PACA_EXGEN, 0xd00)
 704
 705
 706         /* At 0xe??? we have a bunch of hypervisor exceptions, we branch
 707          * out of line to handle them
 708          */
 709 __EXC_REAL_OOL_HV(h_data_storage, 0xe00, 0xe20)
 710
 711 __EXC_REAL_OOL_HV(h_instr_storage, 0xe20, 0xe40)
 712
 713 __EXC_REAL_OOL_HV(emulation_assist, 0xe40, 0xe60)
 714
 715 __EXC_REAL_OOL_HV_DIRECT(hmi_exception, 0xe60, 0xe80, hmi_exception_early)
 716
 717 __EXC_REAL_OOL_MASKABLE_HV(h_doorbell, 0xe80, 0xea0)
 718
 719 __EXC_REAL_OOL_MASKABLE_HV(h_virt_irq, 0xea0, 0xec0)
 720
 721 EXC_REAL_NONE(0xec0, 0xf00)
 722
 723 __EXC_REAL_OOL(performance_monitor, 0xf00, 0xf20)
 724
 725 __EXC_REAL_OOL(altivec_unavailable, 0xf20, 0xf40)
 726
 727 __EXC_REAL_OOL(vsx_unavailable, 0xf40, 0xf60)
 728
 729 __EXC_REAL_OOL(facility_unavailable, 0xf60, 0xf80)
 730
 731 __EXC_REAL_OOL_HV(h_facility_unavailable, 0xf80, 0xfa0)
 732
 733 EXC_REAL_NONE(0xfa0, 0x1200)
 734
 735 #ifdef CONFIG_CBE_RAS
 736 EXC_REAL_HV(cbe_system_error, 0x1200, 0x1300)
 737
 738 TRAMP_KVM_HV_SKIP(PACA_EXGEN, 0x1200)
 739
 740 #else /* CONFIG_CBE_RAS */
 741 EXC_REAL_NONE(0x1200, 0x1300)
 742 #endif
 743
 744 EXC_REAL(instruction_breakpoint, 0x1300, 0x1400)
 745
 746 TRAMP_KVM_SKIP(PACA_EXGEN, 0x1300)
 747
 748 EXC_REAL_BEGIN(denorm_exception_hv, 0x1500, 0x1600)
 749         mtspr   SPRN_SPRG_HSCRATCH0,r13
 750         EXCEPTION_PROLOG_0(PACA_EXGEN)
 751         EXCEPTION_PROLOG_1(PACA_EXGEN, NOTEST, 0x1500)
 752
 753 #ifdef CONFIG_PPC_DENORMALISATION
 754         mfspr   r10,SPRN_HSRR1
 755         mfspr   r11,SPRN_HSRR0          /* save HSRR0 */
 756         andis.  r10,r10,(HSRR1_DENORM)@h /* denorm? */
 757         addi    r11,r11,-4              /* HSRR0 is next instruction */
 758         bne+    denorm_assist
 759 #endif
 760
 761         KVMTEST_PR(0x1500)
 762         EXCEPTION_PROLOG_PSERIES_1(denorm_common, EXC_HV)
 763 EXC_REAL_END(denorm_exception_hv, 0x1500, 0x1600)
 764
 765 TRAMP_KVM_SKIP(PACA_EXGEN, 0x1500)
 766
 767 #ifdef CONFIG_CBE_RAS
 768 EXC_REAL_HV(cbe_maintenance, 0x1600, 0x1700)
 769
 770 TRAMP_KVM_HV_SKIP(PACA_EXGEN, 0x1600)
 771
 772 #else /* CONFIG_CBE_RAS */
 773 EXC_REAL_NONE(0x1600, 0x1700)
 774 #endif
 775
 776 EXC_REAL(altivec_assist, 0x1700, 0x1800)
 777
 778 TRAMP_KVM(PACA_EXGEN, 0x1700)
 779
 780 #ifdef CONFIG_CBE_RAS
 781 EXC_REAL_HV(cbe_thermal, 0x1800, 0x1900)
 782
 783 TRAMP_KVM_HV_SKIP(PACA_EXGEN, 0x1800)
 784
 785 #else /* CONFIG_CBE_RAS */
 786 EXC_REAL_NONE(0x1800, 0x1900)
 787 #endif
 788
 789
 790 /*** Out of line interrupts support ***/
 791
 792         /* moved from 0x200 */
 793 TRAMP_KVM(PACA_EXSLB, 0x480)
 794 TRAMP_KVM(PACA_EXGEN, 0x900)
 795 TRAMP_KVM_HV(PACA_EXGEN, 0x980)
 796
 797 #ifdef CONFIG_PPC_DENORMALISATION
 798 TRAMP_REAL_BEGIN(denorm_assist)
 799 BEGIN_FTR_SECTION
 800 /*
 801  * To denormalise we need to move a copy of the register to itself.
 802  * For POWER6 do that here for all FP regs.
 803  */
 804         mfmsr   r10
 805         ori     r10,r10,(MSR_FP|MSR_FE0|MSR_FE1)
 806         xori    r10,r10,(MSR_FE0|MSR_FE1)
 807         mtmsrd  r10
 808         sync
 809
 810 #define FMR2(n)  fmr (n), (n) ; fmr n+1, n+1
 811 #define FMR4(n)  FMR2(n) ; FMR2(n+2)
 812 #define FMR8(n)  FMR4(n) ; FMR4(n+4)
 813 #define FMR16(n) FMR8(n) ; FMR8(n+8)
 814 #define FMR32(n) FMR16(n) ; FMR16(n+16)
 815         FMR32(0)
 816
 817 FTR_SECTION_ELSE
 818 /*
 819  * To denormalise we need to move a copy of the register to itself.
 820  * For POWER7 do that here for the first 32 VSX registers only.
 821  */
 822         mfmsr   r10
 823         oris    r10,r10,MSR_VSX@h
 824         mtmsrd  r10
 825         sync
 826
 827 #define XVCPSGNDP2(n) XVCPSGNDP(n,n,n) ; XVCPSGNDP(n+1,n+1,n+1)
 828 #define XVCPSGNDP4(n) XVCPSGNDP2(n) ; XVCPSGNDP2(n+2)
 829 #define XVCPSGNDP8(n) XVCPSGNDP4(n) ; XVCPSGNDP4(n+4)
 830 #define XVCPSGNDP16(n) XVCPSGNDP8(n) ; XVCPSGNDP8(n+8)
 831 #define XVCPSGNDP32(n) XVCPSGNDP16(n) ; XVCPSGNDP16(n+16)
 832         XVCPSGNDP32(0)
 833
 834 ALT_FTR_SECTION_END_IFCLR(CPU_FTR_ARCH_206)
 835
 836 BEGIN_FTR_SECTION
 837         b       denorm_done
 838 END_FTR_SECTION_IFCLR(CPU_FTR_ARCH_207S)
 839 /*
 840  * To denormalise we need to move a copy of the register to itself.
 841  * For POWER8 we need to do that for all 64 VSX registers
 842  */
 843         XVCPSGNDP32(32)
 844 denorm_done:
 845         mtspr   SPRN_HSRR0,r11
 846         mtcrf   0x80,r9
 847         ld      r9,PACA_EXGEN+EX_R9(r13)
 848         RESTORE_PPR_PACA(PACA_EXGEN, r10)
 849 BEGIN_FTR_SECTION
 850         ld      r10,PACA_EXGEN+EX_CFAR(r13)
 851         mtspr   SPRN_CFAR,r10
 852 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
 853         ld      r10,PACA_EXGEN+EX_R10(r13)
 854         ld      r11,PACA_EXGEN+EX_R11(r13)
 855         ld      r12,PACA_EXGEN+EX_R12(r13)
 856         ld      r13,PACA_EXGEN+EX_R13(r13)
 857         HRFID
 858         b       .
 859 #endif
 860
 861         /* moved from 0xe00 */
 862 __TRAMP_REAL_REAL_OOL_HV(h_data_storage, 0xe00)
 863 TRAMP_KVM_HV_SKIP(PACA_EXGEN, 0xe00)
 864
 865 __TRAMP_REAL_REAL_OOL_HV(h_instr_storage, 0xe20)
 866 TRAMP_KVM_HV(PACA_EXGEN, 0xe20)
 867
 868 __TRAMP_REAL_REAL_OOL_HV(emulation_assist, 0xe40)
 869 TRAMP_KVM_HV(PACA_EXGEN, 0xe40)
 870
 871 __TRAMP_REAL_REAL_OOL_MASKABLE_HV(hmi_exception, 0xe60)
 872 TRAMP_KVM_HV(PACA_EXGEN, 0xe60)
 873
 874 __TRAMP_REAL_REAL_OOL_MASKABLE_HV(h_doorbell, 0xe80)
 875 TRAMP_KVM_HV(PACA_EXGEN, 0xe80)
 876
 877 __TRAMP_REAL_REAL_OOL_MASKABLE_HV(h_virt_irq, 0xea0)
 878 TRAMP_KVM_HV(PACA_EXGEN, 0xea0)
 879
 880         /* moved from 0xf00 */
 881 __TRAMP_REAL_REAL_OOL(performance_monitor, 0xf00)
 882 TRAMP_KVM(PACA_EXGEN, 0xf00)
 883
 884 __TRAMP_REAL_REAL_OOL(altivec_unavailable, 0xf20)
 885 TRAMP_KVM(PACA_EXGEN, 0xf20)
 886
 887 __TRAMP_REAL_REAL_OOL(vsx_unavailable, 0xf40)
 888 TRAMP_KVM(PACA_EXGEN, 0xf40)
 889
 890 __TRAMP_REAL_REAL_OOL(facility_unavailable, 0xf60)
 891 TRAMP_KVM(PACA_EXGEN, 0xf60)
 892
 893 __TRAMP_REAL_REAL_OOL_HV(h_facility_unavailable, 0xf80)
 894 TRAMP_KVM_HV(PACA_EXGEN, 0xf80)
 895
 896 /*
 897  * An interrupt came in while soft-disabled. We set paca->irq_happened, then:
 898  * - If it was a decrementer interrupt, we bump the dec to max and and return.
 899  * - If it was a doorbell we return immediately since doorbells are edge
 900  *   triggered and won't automatically refire.
 901  * - If it was a HMI we return immediately since we handled it in realmode
 902  *   and it won't refire.
 903  * - else we hard disable and return.
 904  * This is called with r10 containing the value to OR to the paca field.
 905  */
 906 #define MASKED_INTERRUPT(_H)                            \
 907 masked_##_H##interrupt:                                 \
 908         std     r11,PACA_EXGEN+EX_R11(r13);             \
 909         lbz     r11,PACAIRQHAPPENED(r13);               \
 910         or      r11,r11,r10;                            \
 911         stb     r11,PACAIRQHAPPENED(r13);               \
 912         cmpwi   r10,PACA_IRQ_DEC;                       \
 913         bne     1f;                                     \
 914         lis     r10,0x7fff;                             \
 915         ori     r10,r10,0xffff;                         \
 916         mtspr   SPRN_DEC,r10;                           \
 917         b       2f;                                     \
 918 1:      cmpwi   r10,PACA_IRQ_DBELL;                     \
 919         beq     2f;                                     \
 920         cmpwi   r10,PACA_IRQ_HMI;                       \
 921         beq     2f;                                     \
 922         mfspr   r10,SPRN_##_H##SRR1;                    \
 923         rldicl  r10,r10,48,1; /* clear MSR_EE */        \
 924         rotldi  r10,r10,16;                             \
 925         mtspr   SPRN_##_H##SRR1,r10;                    \
 926 2:      mtcrf   0x80,r9;                                \
 927         ld      r9,PACA_EXGEN+EX_R9(r13);               \
 928         ld      r10,PACA_EXGEN+EX_R10(r13);             \
 929         ld      r11,PACA_EXGEN+EX_R11(r13);             \
 930         GET_SCRATCH0(r13);                              \
 931         ##_H##rfid;                                     \
 932         b       .
 933
 934 /*
 935  * Real mode exceptions actually use this too, but alternate
 936  * instruction code patches (which end up in the common .text area)
 937  * cannot reach these if they are put there.
 938  */
 939 USE_FIXED_SECTION(virt_trampolines)
 940         MASKED_INTERRUPT()
 941         MASKED_INTERRUPT(H)
 942
 943 /*
 944  * Called from arch_local_irq_enable when an interrupt needs
 945  * to be resent. r3 contains 0x500, 0x900, 0xa00 or 0xe80 to indicate
 946  * which kind of interrupt. MSR:EE is already off. We generate a
 947  * stackframe like if a real interrupt had happened.
 948  *
 949  * Note: While MSR:EE is off, we need to make sure that _MSR
 950  * in the generated frame has EE set to 1 or the exception
 951  * handler will not properly re-enable them.
 952  */
 953 USE_TEXT_SECTION()
 954 _GLOBAL(__replay_interrupt)
 955         /* We are going to jump to the exception common code which
 956          * will retrieve various register values from the PACA which
 957          * we don't give a damn about, so we don't bother storing them.
 958          */
 959         mfmsr   r12
 960         mflr    r11
 961         mfcr    r9
 962         ori     r12,r12,MSR_EE
 963         cmpwi   r3,0x900
 964         beq     decrementer_common
 965         cmpwi   r3,0x500
 966         beq     hardware_interrupt_common
 967 BEGIN_FTR_SECTION
 968         cmpwi   r3,0xe80
 969         beq     h_doorbell_common
 970         cmpwi   r3,0xea0
 971         beq     h_virt_irq_common
 972         cmpwi   r3,0xe60
 973         beq     hmi_exception_common
 974 FTR_SECTION_ELSE
 975         cmpwi   r3,0xa00
 976         beq     doorbell_super_common
 977 ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE)
 978         blr
 979
 980 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
 981 TRAMP_REAL_BEGIN(kvmppc_skip_interrupt)
 982         /*
 983          * Here all GPRs are unchanged from when the interrupt happened
 984          * except for r13, which is saved in SPRG_SCRATCH0.
 985          */
 986         mfspr   r13, SPRN_SRR0
 987         addi    r13, r13, 4
 988         mtspr   SPRN_SRR0, r13
 989         GET_SCRATCH0(r13)
 990         rfid
 991         b       .
 992
 993 TRAMP_REAL_BEGIN(kvmppc_skip_Hinterrupt)
 994         /*
 995          * Here all GPRs are unchanged from when the interrupt happened
 996          * except for r13, which is saved in SPRG_SCRATCH0.
 997          */
 998         mfspr   r13, SPRN_HSRR0
 999         addi    r13, r13, 4
1000         mtspr   SPRN_HSRR0, r13
1001         GET_SCRATCH0(r13)
1002         hrfid
1003         b       .
1004 #endif
1005
1006 /*
1007  * Ensure that any handlers that get invoked from the exception prologs
1008  * above are below the first 64KB (0x10000) of the kernel image because
1009  * the prologs assemble the addresses of these handlers using the
1010  * LOAD_HANDLER macro, which uses an ori instruction.
1011  */
1012
1013 /*** Common interrupt handlers ***/
1014
1015 EXC_COMMON_ASYNC(hardware_interrupt_common, 0x500, do_IRQ)
1016 EXC_COMMON_ASYNC(decrementer_common, 0x900, timer_interrupt)
1017 EXC_COMMON(hdecrementer_common, 0x980, hdec_interrupt)
1018
1019 #ifdef CONFIG_PPC_DOORBELL
1020 EXC_COMMON_ASYNC(doorbell_super_common, 0xa00, doorbell_exception)
1021 #else
1022 EXC_COMMON_ASYNC(doorbell_super_common, 0xa00, unknown_exception)
1023 #endif
1024 EXC_COMMON(trap_0b_common, 0xb00, unknown_exception)
1025 EXC_COMMON(single_step_common, 0xd00, single_step_exception)
1026 EXC_COMMON(trap_0e_common, 0xe00, unknown_exception)
1027 EXC_COMMON(emulation_assist_common, 0xe40, emulation_assist_interrupt)
1028 EXC_COMMON_ASYNC(hmi_exception_common, 0xe60, handle_hmi_exception)
1029 #ifdef CONFIG_PPC_DOORBELL
1030 EXC_COMMON_ASYNC(h_doorbell_common, 0xe80, doorbell_exception)
1031 #else
1032 EXC_COMMON_ASYNC(h_doorbell_common, 0xe80, unknown_exception)
1033 #endif
1034 EXC_COMMON_ASYNC(h_virt_irq_common, 0xea0, do_IRQ)
1035 EXC_COMMON_ASYNC(performance_monitor_common, 0xf00, performance_monitor_exception)
1036 EXC_COMMON(instruction_breakpoint_common, 0x1300, instruction_breakpoint_exception)
1037 EXC_COMMON_HV(denorm_common, 0x1500, unknown_exception)
1038 #ifdef CONFIG_ALTIVEC
1039 EXC_COMMON(altivec_assist_common, 0x1700, altivec_assist_exception)
1040 #else
1041 EXC_COMMON(altivec_assist_common, 0x1700, unknown_exception)
1042 #endif
1043
1044         /*
1045          * Relocation-on interrupts: A subset of the interrupts can be delivered
1046          * with IR=1/DR=1, if AIL==2 and MSR.HV won't be changed by delivering
1047          * it.  Addresses are the same as the original interrupt addresses, but
1048          * offset by 0xc000000000004000.
1049          * It's impossible to receive interrupts below 0x300 via this mechanism.
1050          * KVM: None of these traps are from the guest ; anything that escalated
1051          * to HV=1 from HV=0 is delivered via real mode handlers.
1052          */
1053
1054         /*
1055          * This uses the standard macro, since the original 0x300 vector
1056          * only has extra guff for STAB-based processors -- which never
1057          * come here.
1058          */
1059
1060 EXC_VIRT_BEGIN(instruction_access_slb, 0x4480, 0x4500)
1061         SET_SCRATCH0(r13)
1062         EXCEPTION_PROLOG_0(PACA_EXSLB)
1063         EXCEPTION_PROLOG_1(PACA_EXSLB, NOTEST, 0x480)
1064         std     r3,PACA_EXSLB+EX_R3(r13)
1065         mfspr   r3,SPRN_SRR0            /* SRR0 is faulting address */
1066         mfspr   r12,SPRN_SRR1
1067         crclr   4*cr6+eq
1068 #ifndef CONFIG_RELOCATABLE
1069         b       slb_miss_realmode
1070 #else
1071         mfctr   r11
1072         LOAD_HANDLER(r10, slb_miss_realmode)
1073         mtctr   r10
1074         bctr
1075 #endif
1076 EXC_VIRT_END(instruction_access_slb, 0x4480, 0x4500)
1077
1078 EXC_VIRT_BEGIN(hardware_interrupt, 0x4500, 0x4600)
1079         .globl hardware_interrupt_relon_hv;
1080 hardware_interrupt_relon_hv:
1081         BEGIN_FTR_SECTION
1082                 _MASKABLE_RELON_EXCEPTION_PSERIES(0x500, hardware_interrupt_common, EXC_HV, SOFTEN_TEST_HV)
1083         FTR_SECTION_ELSE
1084                 _MASKABLE_RELON_EXCEPTION_PSERIES(0x500, hardware_interrupt_common, EXC_STD, SOFTEN_TEST_PR)
1085         ALT_FTR_SECTION_END_IFSET(CPU_FTR_HVMODE)
1086 EXC_VIRT_END(hardware_interrupt, 0x4500, 0x4600)
1087
1088 EXC_VIRT(alignment, 0x4600, 0x4700, 0x600)
1089 EXC_VIRT(program_check, 0x4700, 0x4800, 0x700)
1090 EXC_VIRT(fp_unavailable, 0x4800, 0x4900, 0x800)
1091 EXC_VIRT_MASKABLE(decrementer, 0x4900, 0x4980, 0x900)
1092 EXC_VIRT_HV(hdecrementer, 0x4980, 0x4a00, 0x980)
1093 EXC_VIRT_MASKABLE(doorbell_super, 0x4a00, 0x4b00, 0xa00)
1094 EXC_VIRT(trap_0b, 0x4b00, 0x4c00, 0xb00)
1095
1096 EXC_VIRT_BEGIN(system_call, 0x4c00, 0x4d00)
1097         HMT_MEDIUM
1098         SYSCALL_PSERIES_1
1099         SYSCALL_PSERIES_2_DIRECT
1100         SYSCALL_PSERIES_3
1101 EXC_VIRT_END(system_call, 0x4c00, 0x4d00)
1102
1103 EXC_VIRT(single_step, 0x4d00, 0x4e00, 0xd00)
1104
1105 EXC_VIRT_BEGIN(unused, 0x4e00, 0x4e20)
1106         b       .       /* Can't happen, see v2.07 Book III-S section 6.5 */
1107 EXC_VIRT_END(unused, 0x4e00, 0x4e20)
1108
1109 EXC_VIRT_BEGIN(unused, 0x4e20, 0x4e40)
1110         b       .       /* Can't happen, see v2.07 Book III-S section 6.5 */
1111 EXC_VIRT_END(unused, 0x4e20, 0x4e40)
1112
1113 __EXC_VIRT_OOL_HV(emulation_assist, 0x4e40, 0x4e60)
1114
1115 EXC_VIRT_BEGIN(unused, 0x4e60, 0x4e80)
1116         b       .       /* Can't happen, see v2.07 Book III-S section 6.5 */
1117 EXC_VIRT_END(unused, 0x4e60, 0x4e80)
1118
1119 __EXC_VIRT_OOL_MASKABLE_HV(h_doorbell, 0x4e80, 0x4ea0)
1120
1121 __EXC_VIRT_OOL_MASKABLE_HV(h_virt_irq, 0x4ea0, 0x4ec0)
1122
1123 EXC_VIRT_NONE(0x4ec0, 0x4f00)
1124
1125 __EXC_VIRT_OOL(performance_monitor, 0x4f00, 0x4f20)
1126
1127 __EXC_VIRT_OOL(altivec_unavailable, 0x4f20, 0x4f40)
1128
1129 __EXC_VIRT_OOL(vsx_unavailable, 0x4f40, 0x4f60)
1130
1131 __EXC_VIRT_OOL(facility_unavailable, 0x4f60, 0x4f80)
1132
1133 __EXC_VIRT_OOL_HV(h_facility_unavailable, 0x4f80, 0x4fa0)
1134
1135 EXC_VIRT_NONE(0x4fa0, 0x5200)
1136
1137 EXC_VIRT_NONE(0x5200, 0x5300)
1138
1139 EXC_VIRT(instruction_breakpoint, 0x5300, 0x5400, 0x1300)
1140
1141 #ifdef CONFIG_PPC_DENORMALISATION
1142 EXC_VIRT_BEGIN(denorm_exception, 0x5500, 0x5600)
1143         b       exc_real_0x1500_denorm_exception_hv
1144 EXC_VIRT_END(denorm_exception, 0x5500, 0x5600)
1145 #else
1146 EXC_VIRT_NONE(0x5500, 0x5600)
1147 #endif
1148
1149 EXC_VIRT_NONE(0x5600, 0x5700)
1150
1151 EXC_VIRT(altivec_assist, 0x5700, 0x5800, 0x1700)
1152
1153 EXC_VIRT_NONE(0x5800, 0x5900)
1154
1155 EXC_COMMON_BEGIN(ppc64_runlatch_on_trampoline)
1156         b       __ppc64_runlatch_on
1157
1158 EXC_COMMON_BEGIN(h_data_storage_common)
1159         mfspr   r10,SPRN_HDAR
1160         std     r10,PACA_EXGEN+EX_DAR(r13)
1161         mfspr   r10,SPRN_HDSISR
1162         stw     r10,PACA_EXGEN+EX_DSISR(r13)
1163         EXCEPTION_PROLOG_COMMON(0xe00, PACA_EXGEN)
1164         bl      save_nvgprs
1165         RECONCILE_IRQ_STATE(r10, r11)
1166         addi    r3,r1,STACK_FRAME_OVERHEAD
1167         bl      unknown_exception
1168         b       ret_from_except
1169
1170
1171 EXC_COMMON(h_instr_storage_common, 0xe20, unknown_exception)
1172
1173 EXC_COMMON_BEGIN(alignment_common)
1174         mfspr   r10,SPRN_DAR
1175         std     r10,PACA_EXGEN+EX_DAR(r13)
1176         mfspr   r10,SPRN_DSISR
1177         stw     r10,PACA_EXGEN+EX_DSISR(r13)
1178         EXCEPTION_PROLOG_COMMON(0x600, PACA_EXGEN)
1179         ld      r3,PACA_EXGEN+EX_DAR(r13)
1180         lwz     r4,PACA_EXGEN+EX_DSISR(r13)
1181         std     r3,_DAR(r1)
1182         std     r4,_DSISR(r1)
1183         bl      save_nvgprs
1184         RECONCILE_IRQ_STATE(r10, r11)
1185         addi    r3,r1,STACK_FRAME_OVERHEAD
1186         bl      alignment_exception
1187         b       ret_from_except
1188
1189 EXC_COMMON_BEGIN(program_check_common)
1190         EXCEPTION_PROLOG_COMMON(0x700, PACA_EXGEN)
1191         bl      save_nvgprs
1192         RECONCILE_IRQ_STATE(r10, r11)
1193         addi    r3,r1,STACK_FRAME_OVERHEAD
1194         bl      program_check_exception
1195         b       ret_from_except
1196
1197 EXC_COMMON_BEGIN(fp_unavailable_common)
1198         EXCEPTION_PROLOG_COMMON(0x800, PACA_EXGEN)
1199         bne     1f                      /* if from user, just load it up */
1200         bl      save_nvgprs
1201         RECONCILE_IRQ_STATE(r10, r11)
1202         addi    r3,r1,STACK_FRAME_OVERHEAD
1203         bl      kernel_fp_unavailable_exception
1204         BUG_OPCODE
1205 1:
1206 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1207 BEGIN_FTR_SECTION
1208         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
1209          * transaction), go do TM stuff
1210          */
1211         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
1212         bne-    2f
1213 END_FTR_SECTION_IFSET(CPU_FTR_TM)
1214 #endif
1215         bl      load_up_fpu
1216         b       fast_exception_return
1217 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1218 2:      /* User process was in a transaction */
1219         bl      save_nvgprs
1220         RECONCILE_IRQ_STATE(r10, r11)
1221         addi    r3,r1,STACK_FRAME_OVERHEAD
1222         bl      fp_unavailable_tm
1223         b       ret_from_except
1224 #endif
1225
1226 EXC_COMMON_BEGIN(altivec_unavailable_common)
1227         EXCEPTION_PROLOG_COMMON(0xf20, PACA_EXGEN)
1228 #ifdef CONFIG_ALTIVEC
1229 BEGIN_FTR_SECTION
1230         beq     1f
1231 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1232   BEGIN_FTR_SECTION_NESTED(69)
1233         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
1234          * transaction), go do TM stuff
1235          */
1236         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
1237         bne-    2f
1238   END_FTR_SECTION_NESTED(CPU_FTR_TM, CPU_FTR_TM, 69)
1239 #endif
1240         bl      load_up_altivec
1241         b       fast_exception_return
1242 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1243 2:      /* User process was in a transaction */
1244         bl      save_nvgprs
1245         RECONCILE_IRQ_STATE(r10, r11)
1246         addi    r3,r1,STACK_FRAME_OVERHEAD
1247         bl      altivec_unavailable_tm
1248         b       ret_from_except
1249 #endif
1250 1:
1251 END_FTR_SECTION_IFSET(CPU_FTR_ALTIVEC)
1252 #endif
1253         bl      save_nvgprs
1254         RECONCILE_IRQ_STATE(r10, r11)
1255         addi    r3,r1,STACK_FRAME_OVERHEAD
1256         bl      altivec_unavailable_exception
1257         b       ret_from_except
1258
1259 EXC_COMMON_BEGIN(vsx_unavailable_common)
1260         EXCEPTION_PROLOG_COMMON(0xf40, PACA_EXGEN)
1261 #ifdef CONFIG_VSX
1262 BEGIN_FTR_SECTION
1263         beq     1f
1264 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1265   BEGIN_FTR_SECTION_NESTED(69)
1266         /* Test if 2 TM state bits are zero.  If non-zero (ie. userspace was in
1267          * transaction), go do TM stuff
1268          */
1269         rldicl. r0, r12, (64-MSR_TS_LG), (64-2)
1270         bne-    2f
1271   END_FTR_SECTION_NESTED(CPU_FTR_TM, CPU_FTR_TM, 69)
1272 #endif
1273         b       load_up_vsx
1274 #ifdef CONFIG_PPC_TRANSACTIONAL_MEM
1275 2:      /* User process was in a transaction */
1276         bl      save_nvgprs
1277         RECONCILE_IRQ_STATE(r10, r11)
1278         addi    r3,r1,STACK_FRAME_OVERHEAD
1279         bl      vsx_unavailable_tm
1280         b       ret_from_except
1281 #endif
1282 1:
1283 END_FTR_SECTION_IFSET(CPU_FTR_VSX)
1284 #endif
1285         bl      save_nvgprs
1286         RECONCILE_IRQ_STATE(r10, r11)
1287         addi    r3,r1,STACK_FRAME_OVERHEAD
1288         bl      vsx_unavailable_exception
1289         b       ret_from_except
1290
1291         /* Equivalents to the above handlers for relocation-on interrupt vectors */
1292 __TRAMP_REAL_VIRT_OOL_HV(emulation_assist, 0xe40)
1293 __TRAMP_REAL_VIRT_OOL_MASKABLE_HV(h_doorbell, 0xe80)
1294 __TRAMP_REAL_VIRT_OOL_MASKABLE_HV(h_virt_irq, 0xea0)
1295 __TRAMP_REAL_VIRT_OOL(performance_monitor, 0xf00)
1296 __TRAMP_REAL_VIRT_OOL(altivec_unavailable, 0xf20)
1297 __TRAMP_REAL_VIRT_OOL(vsx_unavailable, 0xf40)
1298 __TRAMP_REAL_VIRT_OOL(facility_unavailable, 0xf60)
1299 __TRAMP_REAL_VIRT_OOL_HV(h_facility_unavailable, 0xf80)
1300
1301 USE_FIXED_SECTION(virt_trampolines)
1302         /*
1303          * The __end_interrupts marker must be past the out-of-line (OOL)
1304          * handlers, so that they are copied to real address 0x100 when running
1305          * a relocatable kernel. This ensures they can be reached from the short
1306          * trampoline handlers (like 0x4f00, 0x4f20, etc.) which branch
1307          * directly, without using LOAD_HANDLER().
1308          */
1309         .align  7
1310         .globl  __end_interrupts
1311 __end_interrupts:
1312 DEFINE_FIXED_SYMBOL(__end_interrupts)
1313
1314 EXC_COMMON(facility_unavailable_common, 0xf60, facility_unavailable_exception)
1315 EXC_COMMON(h_facility_unavailable_common, 0xf80, facility_unavailable_exception)
1316
1317 #ifdef CONFIG_CBE_RAS
1318 EXC_COMMON(cbe_system_error_common, 0x1200, cbe_system_error_exception)
1319 EXC_COMMON(cbe_maintenance_common, 0x1600, cbe_maintenance_exception)
1320 EXC_COMMON(cbe_thermal_common, 0x1800, cbe_thermal_exception)
1321 #endif /* CONFIG_CBE_RAS */
1322
1323
1324 TRAMP_REAL_BEGIN(hmi_exception_early)
1325         EXCEPTION_PROLOG_1(PACA_EXGEN, KVMTEST_HV, 0xe60)
1326         mr      r10,r1                  /* Save r1                      */
1327         ld      r1,PACAEMERGSP(r13)     /* Use emergency stack          */
1328         subi    r1,r1,INT_FRAME_SIZE    /* alloc stack frame            */
1329         std     r9,_CCR(r1)             /* save CR in stackframe        */
1330         mfspr   r11,SPRN_HSRR0          /* Save HSRR0 */
1331         std     r11,_NIP(r1)            /* save HSRR0 in stackframe     */
1332         mfspr   r12,SPRN_HSRR1          /* Save SRR1 */
1333         std     r12,_MSR(r1)            /* save SRR1 in stackframe      */
1334         std     r10,0(r1)               /* make stack chain pointer     */
1335         std     r0,GPR0(r1)             /* save r0 in stackframe        */
1336         std     r10,GPR1(r1)            /* save r1 in stackframe        */
1337         EXCEPTION_PROLOG_COMMON_2(PACA_EXGEN)
1338         EXCEPTION_PROLOG_COMMON_3(0xe60)
1339         addi    r3,r1,STACK_FRAME_OVERHEAD
1340         bl      hmi_exception_realmode
1341         /* Windup the stack. */
1342         /* Move original HSRR0 and HSRR1 into the respective regs */
1343         ld      r9,_MSR(r1)
1344         mtspr   SPRN_HSRR1,r9
1345         ld      r3,_NIP(r1)
1346         mtspr   SPRN_HSRR0,r3
1347         ld      r9,_CTR(r1)
1348         mtctr   r9
1349         ld      r9,_XER(r1)
1350         mtxer   r9
1351         ld      r9,_LINK(r1)
1352         mtlr    r9
1353         REST_GPR(0, r1)
1354         REST_8GPRS(2, r1)
1355         REST_GPR(10, r1)
1356         ld      r11,_CCR(r1)
1357         mtcr    r11
1358         REST_GPR(11, r1)
1359         REST_2GPRS(12, r1)
1360         /* restore original r1. */
1361         ld      r1,GPR1(r1)
1362
1363         /*
1364          * Go to virtual mode and pull the HMI event information from
1365          * firmware.
1366          */
1367         .globl hmi_exception_after_realmode
1368 hmi_exception_after_realmode:
1369         SET_SCRATCH0(r13)
1370         EXCEPTION_PROLOG_0(PACA_EXGEN)
1371         b       tramp_real_hmi_exception
1372
1373 /*
1374  * r13 points to the PACA, r9 contains the saved CR,
1375  * r12 contain the saved SRR1, SRR0 is still ready for return
1376  * r3 has the faulting address
1377  * r9 - r13 are saved in paca->exslb.
1378  * r3 is saved in paca->slb_r3
1379  * cr6.eq is set for a D-SLB miss, clear for a I-SLB miss
1380  * We assume we aren't going to take any exceptions during this procedure.
1381  */
1382 EXC_COMMON_BEGIN(slb_miss_realmode)
1383         mflr    r10
1384 #ifdef CONFIG_RELOCATABLE
1385         mtctr   r11
1386 #endif
1387
1388         stw     r9,PACA_EXSLB+EX_CCR(r13)       /* save CR in exc. frame */
1389         std     r10,PACA_EXSLB+EX_LR(r13)       /* save LR */
1390         std     r3,PACA_EXSLB+EX_DAR(r13)
1391
1392         crset   4*cr0+eq
1393 #ifdef CONFIG_PPC_STD_MMU_64
1394 BEGIN_MMU_FTR_SECTION
1395         bl      slb_allocate_realmode
1396 END_MMU_FTR_SECTION_IFCLR(MMU_FTR_TYPE_RADIX)
1397 #endif
1398
1399         ld      r10,PACA_EXSLB+EX_LR(r13)
1400         ld      r3,PACA_EXSLB+EX_R3(r13)
1401         lwz     r9,PACA_EXSLB+EX_CCR(r13)       /* get saved CR */
1402         mtlr    r10
1403
1404         beq     8f              /* if bad address, make full stack frame */
1405
1406         andi.   r10,r12,MSR_RI  /* check for unrecoverable exception */
1407         beq-    2f
1408
1409         /* All done -- return from exception. */
1410
1411 .machine        push
1412 .machine        "power4"
1413         mtcrf   0x80,r9
1414         mtcrf   0x02,r9         /* I/D indication is in cr6 */
1415         mtcrf   0x01,r9         /* slb_allocate uses cr0 and cr7 */
1416 .machine        pop
1417
1418         RESTORE_PPR_PACA(PACA_EXSLB, r9)
1419         ld      r9,PACA_EXSLB+EX_R9(r13)
1420         ld      r10,PACA_EXSLB+EX_R10(r13)
1421         ld      r11,PACA_EXSLB+EX_R11(r13)
1422         ld      r12,PACA_EXSLB+EX_R12(r13)
1423         ld      r13,PACA_EXSLB+EX_R13(r13)
1424         rfid
1425         b       .       /* prevent speculative execution */
1426
1427 2:      mfspr   r11,SPRN_SRR0
1428         LOAD_HANDLER(r10,unrecov_slb)
1429         mtspr   SPRN_SRR0,r10
1430         ld      r10,PACAKMSR(r13)
1431         mtspr   SPRN_SRR1,r10
1432         rfid
1433         b       .
1434
1435 8:      mfspr   r11,SPRN_SRR0
1436         LOAD_HANDLER(r10,bad_addr_slb)
1437         mtspr   SPRN_SRR0,r10
1438         ld      r10,PACAKMSR(r13)
1439         mtspr   SPRN_SRR1,r10
1440         rfid
1441         b       .
1442
1443 EXC_COMMON_BEGIN(unrecov_slb)
1444         EXCEPTION_PROLOG_COMMON(0x4100, PACA_EXSLB)
1445         RECONCILE_IRQ_STATE(r10, r11)
1446         bl      save_nvgprs
1447 1:      addi    r3,r1,STACK_FRAME_OVERHEAD
1448         bl      unrecoverable_exception
1449         b       1b
1450
1451
1452 EXC_COMMON_BEGIN(bad_addr_slb)
1453         EXCEPTION_PROLOG_COMMON(0x380, PACA_EXSLB)
1454         RECONCILE_IRQ_STATE(r10, r11)
1455         ld      r3, PACA_EXSLB+EX_DAR(r13)
1456         std     r3, _DAR(r1)
1457         beq     cr6, 2f
1458         li      r10, 0x480              /* fix trap number for I-SLB miss */
1459         std     r10, _TRAP(r1)
1460 2:      bl      save_nvgprs
1461         addi    r3, r1, STACK_FRAME_OVERHEAD
1462         bl      slb_miss_bad_addr
1463         b       ret_from_except
1464
1465 #ifdef CONFIG_PPC_970_NAP
1466 TRAMP_REAL_BEGIN(power4_fixup_nap)
1467         andc    r9,r9,r10
1468         std     r9,TI_LOCAL_FLAGS(r11)
1469         ld      r10,_LINK(r1)           /* make idle task do the */
1470         std     r10,_NIP(r1)            /* equivalent of a blr */
1471         blr
1472 #endif
1473
1474 CLOSE_FIXED_SECTION(real_vectors);
1475 CLOSE_FIXED_SECTION(real_trampolines);
1476 CLOSE_FIXED_SECTION(virt_vectors);
1477 CLOSE_FIXED_SECTION(virt_trampolines);
1478
1479 USE_TEXT_SECTION()
1480
1481 /*
1482  * Hash table stuff
1483  */
1484         .align  7
1485 do_hash_page:
1486 #ifdef CONFIG_PPC_STD_MMU_64
1487         andis.  r0,r4,0xa410            /* weird error? */
1488         bne-    handle_page_fault       /* if not, try to insert a HPTE */
1489         andis.  r0,r4,DSISR_DABRMATCH@h
1490         bne-    handle_dabr_fault
1491         CURRENT_THREAD_INFO(r11, r1)
1492         lwz     r0,TI_PREEMPT(r11)      /* If we're in an "NMI" */
1493         andis.  r0,r0,NMI_MASK@h        /* (i.e. an irq when soft-disabled) */
1494         bne     77f                     /* then don't call hash_page now */
1495
1496         /*
1497          * r3 contains the faulting address
1498          * r4 msr
1499          * r5 contains the trap number
1500          * r6 contains dsisr
1501          *
1502          * at return r3 = 0 for success, 1 for page fault, negative for error
1503          */
1504         mr      r4,r12
1505         ld      r6,_DSISR(r1)
1506         bl      __hash_page             /* build HPTE if possible */
1507         cmpdi   r3,0                    /* see if __hash_page succeeded */
1508
1509         /* Success */
1510         beq     fast_exc_return_irq     /* Return from exception on success */
1511
1512         /* Error */
1513         blt-    13f
1514 #endif /* CONFIG_PPC_STD_MMU_64 */
1515
1516 /* Here we have a page fault that hash_page can't handle. */
1517 handle_page_fault:
1518 11:     ld      r4,_DAR(r1)
1519         ld      r5,_DSISR(r1)
1520         addi    r3,r1,STACK_FRAME_OVERHEAD
1521         bl      do_page_fault
1522         cmpdi   r3,0
1523         beq+    12f
1524         bl      save_nvgprs
1525         mr      r5,r3
1526         addi    r3,r1,STACK_FRAME_OVERHEAD
1527         lwz     r4,_DAR(r1)
1528         bl      bad_page_fault
1529         b       ret_from_except
1530
1531 /* We have a data breakpoint exception - handle it */
1532 handle_dabr_fault:
1533         bl      save_nvgprs
1534         ld      r4,_DAR(r1)
1535         ld      r5,_DSISR(r1)
1536         addi    r3,r1,STACK_FRAME_OVERHEAD
1537         bl      do_break
1538 12:     b       ret_from_except_lite
1539
1540
1541 #ifdef CONFIG_PPC_STD_MMU_64
1542 /* We have a page fault that hash_page could handle but HV refused
1543  * the PTE insertion
1544  */
1545 13:     bl      save_nvgprs
1546         mr      r5,r3
1547         addi    r3,r1,STACK_FRAME_OVERHEAD
1548         ld      r4,_DAR(r1)
1549         bl      low_hash_fault
1550         b       ret_from_except
1551 #endif
1552
1553 /*
1554  * We come here as a result of a DSI at a point where we don't want
1555  * to call hash_page, such as when we are accessing memory (possibly
1556  * user memory) inside a PMU interrupt that occurred while interrupts
1557  * were soft-disabled.  We want to invoke the exception handler for
1558  * the access, or panic if there isn't a handler.
1559  */
1560 77:     bl      save_nvgprs
1561         mr      r4,r3
1562         addi    r3,r1,STACK_FRAME_OVERHEAD
1563         li      r5,SIGSEGV
1564         bl      bad_page_fault
1565         b       ret_from_except
1566
1567 /*
1568  * Here we have detected that the kernel stack pointer is bad.
1569  * R9 contains the saved CR, r13 points to the paca,
1570  * r10 contains the (bad) kernel stack pointer,
1571  * r11 and r12 contain the saved SRR0 and SRR1.
1572  * We switch to using an emergency stack, save the registers there,
1573  * and call kernel_bad_stack(), which panics.
1574  */
1575 bad_stack:
1576         ld      r1,PACAEMERGSP(r13)
1577         subi    r1,r1,64+INT_FRAME_SIZE
1578         std     r9,_CCR(r1)
1579         std     r10,GPR1(r1)
1580         std     r11,_NIP(r1)
1581         std     r12,_MSR(r1)
1582         mfspr   r11,SPRN_DAR
1583         mfspr   r12,SPRN_DSISR
1584         std     r11,_DAR(r1)
1585         std     r12,_DSISR(r1)
1586         mflr    r10
1587         mfctr   r11
1588         mfxer   r12
1589         std     r10,_LINK(r1)
1590         std     r11,_CTR(r1)
1591         std     r12,_XER(r1)
1592         SAVE_GPR(0,r1)
1593         SAVE_GPR(2,r1)
1594         ld      r10,EX_R3(r3)
1595         std     r10,GPR3(r1)
1596         SAVE_GPR(4,r1)
1597         SAVE_4GPRS(5,r1)
1598         ld      r9,EX_R9(r3)
1599         ld      r10,EX_R10(r3)
1600         SAVE_2GPRS(9,r1)
1601         ld      r9,EX_R11(r3)
1602         ld      r10,EX_R12(r3)
1603         ld      r11,EX_R13(r3)
1604         std     r9,GPR11(r1)
1605         std     r10,GPR12(r1)
1606         std     r11,GPR13(r1)
1607 BEGIN_FTR_SECTION
1608         ld      r10,EX_CFAR(r3)
1609         std     r10,ORIG_GPR3(r1)
1610 END_FTR_SECTION_IFSET(CPU_FTR_CFAR)
1611         SAVE_8GPRS(14,r1)
1612         SAVE_10GPRS(22,r1)
1613         lhz     r12,PACA_TRAP_SAVE(r13)
1614         std     r12,_TRAP(r1)
1615         addi    r11,r1,INT_FRAME_SIZE
1616         std     r11,0(r1)
1617         li      r12,0
1618         std     r12,0(r11)
1619         ld      r2,PACATOC(r13)
1620         ld      r11,exception_marker@toc(r2)
1621         std     r12,RESULT(r1)
1622         std     r11,STACK_FRAME_OVERHEAD-16(r1)
1623 1:      addi    r3,r1,STACK_FRAME_OVERHEAD
1624         bl      kernel_bad_stack
1625         b       1b