arch/arm/cpu/arm925t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM925 CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1510 from ARM920 code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij  <kshitij@ti.com>
  13  *
  14  * See file CREDITS for list of people who contributed to this
  15  * project.
  16  *
  17  * This program is free software; you can redistribute it and/or
  18  * modify it under the terms of the GNU General Public License as
  19  * published by the Free Software Foundation; either version 2 of
  20  * the License, or (at your option) any later version.
  21  *
  22  * This program is distributed in the hope that it will be useful,
  23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25  * GNU General Public License for more details.
  26  *
  27  * You should have received a copy of the GNU General Public License
  28  * along with this program; if not, write to the Free Software
  29  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  30  * MA 02111-1307 USA
  31  */
  32
  33 #include <asm-offsets.h>
  34 #include <config.h>
  35 #include <version.h>
  36
  37 /*
  38  *************************************************************************
  39  *
  40  * Jump vector table as in table 3.1 in [1]
  41  *
  42  *************************************************************************
  43  */
  44
  45
  46 .globl _start
  47 _start: b       reset
  48         ldr     pc, _undefined_instruction
  49         ldr     pc, _software_interrupt
  50         ldr     pc, _prefetch_abort
  51         ldr     pc, _data_abort
  52         ldr     pc, _not_used
  53         ldr     pc, _irq
  54         ldr     pc, _fiq
  55
  56 _undefined_instruction: .word undefined_instruction
  57 _software_interrupt:    .word software_interrupt
  58 _prefetch_abort:        .word prefetch_abort
  59 _data_abort:            .word data_abort
  60 _not_used:              .word not_used
  61 _irq:                   .word irq
  62 _fiq:                   .word fiq
  63
  64         .balignl 16,0xdeadbeef
  65
  66
  67 /*
  68  *************************************************************************
  69  *
  70  * Startup Code (reset vector)
  71  *
  72  * do important init only if we don't start from memory!
  73  * setup Memory and board specific bits prior to relocation.
  74  * relocate armboot to ram
  75  * setup stack
  76  *
  77  *************************************************************************
  78  */
  79
  80 .globl _TEXT_BASE
  81 _TEXT_BASE:
  82 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_TEXT_BASE)
  83         .word   CONFIG_SPL_TEXT_BASE
  84 #else
  85         .word   CONFIG_SYS_TEXT_BASE
  86 #endif
  87
  88 /*
  89  * These are defined in the board-specific linker script.
  90  * Subtracting _start from them lets the linker put their
  91  * relative position in the executable instead of leaving
  92  * them null.
  93  */
  94 .globl _bss_start_ofs
  95 _bss_start_ofs:
  96         .word __bss_start - _start
  97
  98 .globl _bss_end_ofs
  99 _bss_end_ofs:
 100         .word __bss_end - _start
 101
 102 .globl _end_ofs
 103 _end_ofs:
 104         .word _end - _start
 105
 106 #ifdef CONFIG_USE_IRQ
 107 /* IRQ stack memory (calculated at run-time) */
 108 .globl IRQ_STACK_START
 109 IRQ_STACK_START:
 110         .word   0x0badc0de
 111
 112 /* IRQ stack memory (calculated at run-time) */
 113 .globl FIQ_STACK_START
 114 FIQ_STACK_START:
 115         .word 0x0badc0de
 116 #endif
 117
 118 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 119 .globl IRQ_STACK_START_IN
 120 IRQ_STACK_START_IN:
 121         .word   0x0badc0de
 122
 123 /*
 124  * the actual reset code
 125  */
 126
 127 reset:
 128         /*
 129          * set the cpu to SVC32 mode
 130          */
 131         mrs     r0,cpsr
 132         bic     r0,r0,#0x1f
 133         orr     r0,r0,#0xd3
 134         msr     cpsr,r0
 135
 136         /*
 137          * Set up 925T mode
 138          */
 139         mov r1, #0x81               /* Set ARM925T configuration. */
 140         mcr p15, 0, r1, c15, c1, 0  /* Write ARM925T configuration register. */
 141
 142         /*
 143          * turn off the watchdog, unlock/diable sequence
 144          */
 145         mov  r1, #0xF5
 146         ldr  r0, =WDTIM_MODE
 147         strh r1, [r0]
 148         mov  r1, #0xA0
 149         strh r1, [r0]
 150
 151         /*
 152          * mask all IRQs by setting all bits in the INTMR - default
 153          */
 154         mov r1, #0xffffffff
 155         ldr r0, =REG_IHL1_MIR
 156         str r1, [r0]
 157         ldr r0, =REG_IHL2_MIR
 158         str r1, [r0]
 159
 160         /*
 161          * wait for dpll to lock
 162          */
 163         ldr  r0, =CK_DPLL1
 164         mov  r1, #0x10
 165         strh r1, [r0]
 166 poll1:
 167         ldrh r1, [r0]
 168         ands r1, r1, #0x01
 169         beq poll1
 170
 171         /*
 172          * we do sys-critical inits only at reboot,
 173          * not when booting from ram!
 174          */
 175 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 176         bl  cpu_init_crit
 177 #endif
 178
 179         bl      _main
 180
 181 /*------------------------------------------------------------------------------*/
 182
 183 #ifndef CONFIG_SPL_BUILD
 184 /*
 185  * void relocate_code(addr_moni)
 186  *
 187  * This function relocates the monitor code.
 188  */
 189         .globl  relocate_code
 190 relocate_code:
 191         mov     r6, r0  /* save addr of destination */
 192
 193         adr     r0, _start
 194         subs    r9, r6, r0              /* r9 <- relocation offset */
 195         beq     relocate_done           /* skip relocation */
 196         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 197         ldr     r3, _image_copy_end_ofs
 198         add     r2, r0, r3              /* r2 <- source end address         */
 199
 200 copy_loop:
 201         ldmia   r0!, {r10-r11}          /* copy from source address [r0]    */
 202         stmia   r1!, {r10-r11}          /* copy to   target address [r1]    */
 203         cmp     r0, r2                  /* until source end address [r2]    */
 204         blo     copy_loop
 205
 206         /*
 207          * fix .rel.dyn relocations
 208          */
 209         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 210         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 211         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 212         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 213         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 214         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 215         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 216 fixloop:
 217         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 218         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 219         ldr     r1, [r2, #4]
 220         and     r7, r1, #0xff
 221         cmp     r7, #23                 /* relative fixup? */
 222         beq     fixrel
 223         cmp     r7, #2                  /* absolute fixup? */
 224         beq     fixabs
 225         /* ignore unknown type of fixup */
 226         b       fixnext
 227 fixabs:
 228         /* absolute fix: set location to (offset) symbol value */
 229         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 230         add     r1, r10, r1             /* r1 <- address of symbol in table */
 231         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 232         add     r1, r1, r9              /* r1 <- relocated sym addr */
 233         b       fixnext
 234 fixrel:
 235         /* relative fix: increase location by offset */
 236         ldr     r1, [r0]
 237         add     r1, r1, r9
 238 fixnext:
 239         str     r1, [r0]
 240         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 241         cmp     r2, r3
 242         blo     fixloop
 243
 244 relocate_done:
 245
 246         mov     pc, lr
 247
 248 _image_copy_end_ofs:
 249         .word __image_copy_end - _start
 250 _rel_dyn_start_ofs:
 251         .word __rel_dyn_start - _start
 252 _rel_dyn_end_ofs:
 253         .word __rel_dyn_end - _start
 254 _dynsym_start_ofs:
 255         .word __dynsym_start - _start
 256
 257 #endif
 258
 259         .globl  c_runtime_cpu_setup
 260 c_runtime_cpu_setup:
 261
 262         mov     pc, lr
 263
 264 /*
 265  *************************************************************************
 266  *
 267  * CPU_init_critical registers
 268  *
 269  * setup important registers
 270  * setup memory timing
 271  *
 272  *************************************************************************
 273  */
 274
 275
 276 cpu_init_crit:
 277         /*
 278          * flush v4 I/D caches
 279          */
 280         mov     r0, #0
 281         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 282         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 283
 284         /*
 285          * disable MMU stuff and caches
 286          */
 287         mrc     p15, 0, r0, c1, c0, 0
 288         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 289         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 290         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 291         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 292         mcr     p15, 0, r0, c1, c0, 0
 293
 294         /*
 295          * Go setup Memory and board specific bits prior to relocation.
 296          */
 297         mov     ip, lr          /* perserve link reg across call */
 298         bl      lowlevel_init   /* go setup pll,mux,memory */
 299         mov     lr, ip          /* restore link */
 300         mov     pc, lr          /* back to my caller */
 301 /*
 302  *************************************************************************
 303  *
 304  * Interrupt handling
 305  *
 306  *************************************************************************
 307  */
 308
 309 @
 310 @ IRQ stack frame.
 311 @
 312 #define S_FRAME_SIZE    72
 313
 314 #define S_OLD_R0        68
 315 #define S_PSR           64
 316 #define S_PC            60
 317 #define S_LR            56
 318 #define S_SP            52
 319
 320 #define S_IP            48
 321 #define S_FP            44
 322 #define S_R10           40
 323 #define S_R9            36
 324 #define S_R8            32
 325 #define S_R7            28
 326 #define S_R6            24
 327 #define S_R5            20
 328 #define S_R4            16
 329 #define S_R3            12
 330 #define S_R2            8
 331 #define S_R1            4
 332 #define S_R0            0
 333
 334 #define MODE_SVC 0x13
 335 #define I_BIT    0x80
 336
 337 /*
 338  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 339  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 340  */
 341
 342         .macro  bad_save_user_regs
 343         sub     sp, sp, #S_FRAME_SIZE           @ carve out a frame on current user stack
 344         stmia   sp, {r0 - r12}                  @ Save user registers (now in svc mode) r0-r12
 345
 346         ldr     r2, IRQ_STACK_START_IN
 347         ldmia   r2, {r2 - r3}                   @ get values for "aborted" pc and cpsr (into parm regs)
 348         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 349
 350         add     r5, sp, #S_SP
 351         mov     r1, lr
 352         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 353         mov     r0, sp                          @ save current stack into r0 (param register)
 354         .endm
 355
 356         .macro  irq_save_user_regs
 357         sub     sp, sp, #S_FRAME_SIZE
 358         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 359         add     r8, sp, #S_PC                   @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 360         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 361         str     lr, [r8, #0]                    @ Save calling PC
 362         mrs     r6, spsr
 363         str     r6, [r8, #4]                    @ Save CPSR
 364         str     r0, [r8, #8]                    @ Save OLD_R0
 365         mov     r0, sp
 366         .endm
 367
 368         .macro  irq_restore_user_regs
 369         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 370         mov     r0, r0
 371         ldr     lr, [sp, #S_PC]                 @ Get PC
 372         add     sp, sp, #S_FRAME_SIZE
 373         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 374         .endm
 375
 376         .macro get_bad_stack
 377         ldr     r13, IRQ_STACK_START_IN
 378
 379         str     lr, [r13]                       @ save caller lr in position 0 of saved stack
 380         mrs     lr, spsr                        @ get the spsr
 381         str     lr, [r13, #4]                   @ save spsr in position 1 of saved stack
 382
 383         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 384         @ msr   spsr_c, r13
 385         msr     spsr, r13                       @ switch modes, make sure moves will execute
 386         mov     lr, pc                          @ capture return pc
 387         movs    pc, lr                          @ jump to next instruction & switch modes.
 388         .endm
 389
 390         .macro get_irq_stack                    @ setup IRQ stack
 391         ldr     sp, IRQ_STACK_START
 392         .endm
 393
 394         .macro get_fiq_stack                    @ setup FIQ stack
 395         ldr     sp, FIQ_STACK_START
 396         .endm
 397
 398 /*
 399  * exception handlers
 400  */
 401         .align  5
 402 undefined_instruction:
 403         get_bad_stack
 404         bad_save_user_regs
 405         bl      do_undefined_instruction
 406
 407         .align  5
 408 software_interrupt:
 409         get_bad_stack
 410         bad_save_user_regs
 411         bl      do_software_interrupt
 412
 413         .align  5
 414 prefetch_abort:
 415         get_bad_stack
 416         bad_save_user_regs
 417         bl      do_prefetch_abort
 418
 419         .align  5
 420 data_abort:
 421         get_bad_stack
 422         bad_save_user_regs
 423         bl      do_data_abort
 424
 425         .align  5
 426 not_used:
 427         get_bad_stack
 428         bad_save_user_regs
 429         bl      do_not_used
 430
 431 #ifdef CONFIG_USE_IRQ
 432
 433         .align  5
 434 irq:
 435         get_irq_stack
 436         irq_save_user_regs
 437         bl      do_irq
 438         irq_restore_user_regs
 439
 440         .align  5
 441 fiq:
 442         get_fiq_stack
 443         /* someone ought to write a more effiction fiq_save_user_regs */
 444         irq_save_user_regs
 445         bl      do_fiq
 446         irq_restore_user_regs
 447
 448 #else
 449
 450         .align  5
 451 irq:
 452         get_bad_stack
 453         bad_save_user_regs
 454         bl      do_irq
 455
 456         .align  5
 457 fiq:
 458         get_bad_stack
 459         bad_save_user_regs
 460         bl      do_fiq
 461
 462 #endif
 463
 464         .align  5
 465 .globl reset_cpu
 466 reset_cpu:
 467         ldr     r1, rstctl1     /* get clkm1 reset ctl */
 468         mov     r3, #0x3        /* dsp_en + arm_rst = global reset */
 469         strh    r3, [r1]        /* force reset */
 470         mov     r0, r0
 471 _loop_forever:
 472         b       _loop_forever
 473 rstctl1:
 474         .word   0xfffece10