arch/arm/cpu/armv7/omap-common/lowlevel_init.S

   1 /*
   2  * Board specific setup info
   3  *
   4  * (C) Copyright 2010
   5  * Texas Instruments, <www.ti.com>
   6  *
   7  * Author :
   8  *      Aneesh V        <aneesh@ti.com>
   9  *
  10  * See file CREDITS for list of people who contributed to this
  11  * project.
  12  *
  13  * This program is free software; you can redistribute it and/or
  14  * modify it under the terms of the GNU General Public License as
  15  * published by the Free Software Foundation; either version 2 of
  16  * the License, or (at your option) any later version.
  17  *
  18  * This program is distributed in the hope that it will be useful,
  19  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  20  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  21  * GNU General Public License for more details.
  22  *
  23  * You should have received a copy of the GNU General Public License
  24  * along with this program; if not, write to the Free Software
  25  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  26  * MA 02111-1307 USA
  27  */
  28
  29 #include <asm/arch/omap.h>
  30 #include <asm/arch/spl.h>
  31 #include <linux/linkage.h>
  32
  33 ENTRY(save_boot_params)
  34         /*
  35          * See if the rom code passed pointer is valid:
  36          * It is not valid if it is not in non-secure SRAM
  37          * This may happen if you are booting with the help of
  38          * debugger
  39          */
  40         ldr     r2, =NON_SECURE_SRAM_START
  41         cmp     r2, r0
  42         bgt     1f
  43         ldr     r2, =NON_SECURE_SRAM_END
  44         cmp     r2, r0
  45         blt     1f
  46
  47         /*
  48          * store the boot params passed from rom code or saved
  49          * and passed by SPL
  50          */
  51         cmp     r0, #0
  52         beq     1f
  53         ldr     r1, =boot_params
  54         str     r0, [r1]
  55 #ifdef CONFIG_SPL_BUILD
  56         /* Store the boot device in spl_boot_device */
  57         ldrb    r2, [r0, #BOOT_DEVICE_OFFSET]   @ r1 <- value of boot device
  58         and     r2, #BOOT_DEVICE_MASK
  59         ldr     r3, =boot_params
  60         strb    r2, [r3, #BOOT_DEVICE_OFFSET]   @ spl_boot_device <- r1
  61
  62         /* boot mode is passed only for devices that can raw/fat mode */
  63         cmp     r2, #BOOT_DEVICE_XIP
  64         blt     2f
  65         cmp     r2, #BOOT_DEVICE_MMC2
  66         bgt     2f
  67         /* Store the boot mode (raw/FAT) in omap_bootmode */
  68         ldr     r2, [r0, #DEV_DESC_PTR_OFFSET]  @ get the device descriptor ptr
  69         ldr     r2, [r2, #DEV_DATA_PTR_OFFSET]  @ get the pDeviceData ptr
  70         ldr     r2, [r2, #BOOT_MODE_OFFSET]     @ get the boot mode
  71         ldr     r3, =omap_bootmode
  72         str     r2, [r3]
  73 #endif
  74 2:
  75         ldrb    r2, [r0, #CH_FLAGS_OFFSET]
  76         ldr     r3, =boot_params
  77         strb    r2, [r3, #CH_FLAGS_OFFSET]
  78 1:
  79         bx      lr
  80 ENDPROC(save_boot_params)
  81
  82 ENTRY(set_pl310_ctrl_reg)
  83         PUSH    {r4-r11, lr}    @ save registers - ROM code may pollute
  84                                 @ our registers
  85         LDR     r12, =0x102     @ Set PL310 control register - value in R0
  86         .word   0xe1600070      @ SMC #0 - hand assembled because -march=armv5
  87                                 @ call ROM Code API to set control register
  88         POP     {r4-r11, pc}
  89 ENDPROC(set_pl310_ctrl_reg)