arch/arm/cpu/armv7/zynq/u-boot.lds

   1 /*
   2  * Copyright (c) 2004-2008 Texas Instruments
   3  *
   4  * (C) Copyright 2002
   5  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  11 OUTPUT_ARCH(arm)
  12 ENTRY(_start)
  13 SECTIONS
  14 {
  15         . = 0x00000000;
  16
  17         . = ALIGN(4);
  18         .text :
  19         {
  20                 *(.__image_copy_start)
  21                 CPUDIR/start.o (.text*)
  22                 *(.text*)
  23         }
  24
  25         . = ALIGN(4);
  26         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  27
  28         . = ALIGN(4);
  29         .data : {
  30                 *(.data*)
  31         }
  32
  33         . = ALIGN(4);
  34
  35         . = .;
  36
  37         . = ALIGN(4);
  38         .u_boot_list : {
  39                 KEEP(*(SORT(.u_boot_list*)));
  40         }
  41
  42         . = ALIGN(4);
  43
  44         .image_copy_end :
  45         {
  46                 *(.__image_copy_end)
  47         }
  48
  49         .rel_dyn_start :
  50         {
  51                 *(.__rel_dyn_start)
  52         }
  53
  54         .rel.dyn : {
  55                 *(.rel*)
  56         }
  57
  58         .rel_dyn_end :
  59         {
  60                 *(.__rel_dyn_end)
  61         }
  62
  63         _end = .;
  64
  65 /*
  66  * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
  67  * __bss_base and __bss_limit are for linker only (overlay ordering)
  68  */
  69
  70         .bss_start __rel_dyn_start (OVERLAY) : {
  71                 KEEP(*(.__bss_start));
  72                 __bss_base = .;
  73         }
  74
  75         .bss __bss_base (OVERLAY) : {
  76                 *(.bss*)
  77                  . = ALIGN(4);
  78                  __bss_limit = .;
  79         }
  80
  81         .bss_end __bss_limit (OVERLAY) : {
  82                 KEEP(*(.__bss_end));
  83         }
  84
  85         /*
  86          * Zynq needs to discard more sections because the user
  87          * is expected to pass this image on to tools for boot.bin
  88          * generation that require them to be dropped.
  89          */
  90         /DISCARD/ : { *(.dynsym) }
  91         /DISCARD/ : { *(.dynbss*) }
  92         /DISCARD/ : { *(.dynstr*) }
  93         /DISCARD/ : { *(.dynamic*) }
  94         /DISCARD/ : { *(.plt*) }
  95         /DISCARD/ : { *(.interp*) }
  96         /DISCARD/ : { *(.gnu*) }
  97         /DISCARD/ : { *(.ARM.exidx*) }
  98         /DISCARD/ : { *(.gnu.linkonce.armexidx.*) }
  99 }