arch/arm/cpu/ixp/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2006
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_FORMAT("elf32-bigarm", "elf32-bigarm", "elf32-bigarm")
  25 OUTPUT_ARCH(arm)
  26 ENTRY(_start)
  27 SECTIONS
  28 {
  29         . = 0x00000000;
  30
  31         . = ALIGN(4);
  32         .text :
  33         {
  34                 *(.__image_copy_start)
  35                 arch/arm/cpu/ixp/start.o(.text*)
  36                 *(.text*)
  37         }
  38
  39         . = ALIGN(4);
  40         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  41
  42         . = ALIGN(4);
  43         .data : {
  44                 *(.data*)
  45         }
  46
  47         . = ALIGN(4);
  48
  49         . = .;
  50
  51         . = ALIGN(4);
  52         .u_boot_list : {
  53                 KEEP(*(SORT(.u_boot_list*)));
  54         }
  55
  56         . = ALIGN(4);
  57
  58         .image_copy_end :
  59         {
  60                 *(.__image_copy_end)
  61         }
  62
  63         .rel_dyn_start :
  64         {
  65                 *(.__rel_dyn_start)
  66         }
  67
  68         .rel.dyn : {
  69                 *(.rel*)
  70         }
  71
  72         .rel_dyn_end :
  73         {
  74                 *(.__rel_dyn_end)
  75         }
  76
  77         _end = .;
  78
  79 /*
  80  * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
  81  * __bss_base and __bss_limit are for linker only (overlay ordering)
  82  */
  83
  84         .bss_start __rel_dyn_start (OVERLAY) : {
  85                 KEEP(*(.__bss_start));
  86                 __bss_base = .;
  87         }
  88
  89         .bss __bss_base (OVERLAY) : {
  90                 *(.bss*)
  91                  . = ALIGN(4);
  92                  __bss_limit = .;
  93         }
  94         .bss_end __bss_limit (OVERLAY) : {
  95                 KEEP(*(.__bss_end));
  96         }
  97
  98         /DISCARD/ : { *(.dynsym) }
  99         /DISCARD/ : { *(.dynstr*) }
 100         /DISCARD/ : { *(.dynamic*) }
 101         /DISCARD/ : { *(.plt*) }
 102         /DISCARD/ : { *(.interp*) }
 103         /DISCARD/ : { *(.gnu*) }
 104 }