arch/arm/cpu/u-boot-spl.lds

   1 /*
   2  * Copyright (c) 2004-2008 Texas Instruments
   3  *
   4  * (C) Copyright 2002
   5  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  11 OUTPUT_ARCH(arm)
  12 ENTRY(_start)
  13 SECTIONS
  14 {
  15         . = 0x00000000;
  16
  17         . = ALIGN(4);
  18         .text :
  19         {
  20                 __image_copy_start = .;
  21                 *(.vectors)
  22                 CPUDIR/start.o (.text*)
  23                 *(.text*)
  24         }
  25
  26         . = ALIGN(4);
  27         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  28
  29         . = ALIGN(4);
  30         .data : {
  31                 *(.data*)
  32         }
  33
  34         . = ALIGN(4);
  35
  36         . = .;
  37 #ifdef CONFIG_SPL_DM
  38         .u_boot_list : {
  39                 KEEP(*(SORT(.u_boot_list_*_driver_*)));
  40                 KEEP(*(SORT(.u_boot_list_*_uclass_*)));
  41         }
  42 #endif
  43         . = ALIGN(4);
  44
  45         __image_copy_end = .;
  46
  47         .rel.dyn : {
  48                 __rel_dyn_start = .;
  49                 *(.rel*)
  50                 __rel_dyn_end = .;
  51         }
  52
  53         .end :
  54         {
  55                 *(.__end)
  56         }
  57
  58         _image_binary_end = .;
  59
  60         .bss __rel_dyn_start (OVERLAY) : {
  61                 __bss_start = .;
  62                 *(.bss*)
  63                  . = ALIGN(4);
  64                 __bss_end = .;
  65         }
  66
  67         .dynsym _image_binary_end : { *(.dynsym) }
  68         .dynbss : { *(.dynbss) }
  69         .dynstr : { *(.dynstr*) }
  70         .dynamic : { *(.dynamic*) }
  71         .hash : { *(.hash*) }
  72         .plt : { *(.plt*) }
  73         .interp : { *(.interp*) }
  74         .gnu : { *(.gnu*) }
  75         .ARM.exidx : { *(.ARM.exidx*) }
  76 }
  77
  78 #if defined(CONFIG_SPL_MAX_SIZE)
  79 ASSERT(__image_copy_end - __image_copy_start < (CONFIG_SPL_MAX_SIZE), \
  80         "SPL image too big");
  81 #endif
  82
  83 #if defined(CONFIG_SPL_BSS_MAX_SIZE)
  84 ASSERT(__bss_end - __bss_start < (CONFIG_SPL_BSS_MAX_SIZE), \
  85         "SPL image BSS too big");
  86 #endif
  87
  88 #if defined(CONFIG_SPL_MAX_FOOTPRINT)
  89 ASSERT(__bss_end - _start < (CONFIG_SPL_MAX_FOOTPRINT), \
  90         "SPL image plus BSS too big");
  91 #endif