arch/arm/lib/crt0.S

   1 /*
   2  *  crt0 - C-runtime startup Code for ARM U-Boot
   3  *
   4  *  Copyright (c) 2012  Albert ARIBAUD <albert.u.boot@aribaud.net>
   5  *
   6  * SPDX-License-Identifier:     GPL-2.0+
   7  */
   8
   9 #include <config.h>
  10 #include <asm-offsets.h>
  11 #include <linux/linkage.h>
  12
  13 /*
  14  * This file handles the target-independent stages of the U-Boot
  15  * start-up where a C runtime environment is needed. Its entry point
  16  * is _main and is branched into from the target's start.S file.
  17  *
  18  * _main execution sequence is:
  19  *
  20  * 1. Set up initial environment for calling board_init_f().
  21  *    This environment only provides a stack and a place to store
  22  *    the GD ('global data') structure, both located in some readily
  23  *    available RAM (SRAM, locked cache...). In this context, VARIABLE
  24  *    global data, initialized or not (BSS), are UNAVAILABLE; only
  25  *    CONSTANT initialized data are available.
  26  *
  27  * 2. Call board_init_f(). This function prepares the hardware for
  28  *    execution from system RAM (DRAM, DDR...) As system RAM may not
  29  *    be available yet, , board_init_f() must use the current GD to
  30  *    store any data which must be passed on to later stages. These
  31  *    data include the relocation destination, the future stack, and
  32  *    the future GD location.
  33  *
  34  * (the following applies only to non-SPL builds)
  35  *
  36  * 3. Set up intermediate environment where the stack and GD are the
  37  *    ones allocated by board_init_f() in system RAM, but BSS and
  38  *    initialized non-const data are still not available.
  39  *
  40  * 4. Call relocate_code(). This function relocates U-Boot from its
  41  *    current location into the relocation destination computed by
  42  *    board_init_f().
  43  *
  44  * 5. Set up final environment for calling board_init_r(). This
  45  *    environment has BSS (initialized to 0), initialized non-const
  46  *    data (initialized to their intended value), and stack in system
  47  *    RAM. GD has retained values set by board_init_f(). Some CPUs
  48  *    have some work left to do at this point regarding memory, so
  49  *    call c_runtime_cpu_setup.
  50  *
  51  * 6. Branch to board_init_r().
  52  */
  53
  54 /*
  55  * entry point of crt0 sequence
  56  */
  57
  58 ENTRY(_main)
  59
  60 /*
  61  * Set up initial C runtime environment and call board_init_f(0).
  62  */
  63
  64 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_STACK)
  65         ldr     sp, =(CONFIG_SPL_STACK)
  66 #else
  67         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
  68 #endif
  69         bic     sp, sp, #7      /* 8-byte alignment for ABI compliance */
  70         mov     r2, sp
  71         sub     sp, sp, #GD_SIZE        /* allocate one GD above SP */
  72         bic     sp, sp, #7      /* 8-byte alignment for ABI compliance */
  73         mov     r9, sp          /* GD is above SP */
  74         mov     r1, sp
  75         mov     r0, #0
  76 clr_gd:
  77         cmp     r1, r2                  /* while not at end of GD */
  78         strlo   r0, [r1]                /* clear 32-bit GD word */
  79         addlo   r1, r1, #4              /* move to next */
  80         blo     clr_gd
  81 #if defined(CONFIG_SYS_MALLOC_F_LEN)
  82         sub     sp, sp, #CONFIG_SYS_MALLOC_F_LEN
  83         str     sp, [r9, #GD_MALLOC_BASE]
  84 #endif
  85         /* mov r0, #0 not needed due to above code */
  86         bl      board_init_f
  87
  88 #if ! defined(CONFIG_SPL_BUILD)
  89
  90 /*
  91  * Set up intermediate environment (new sp and gd) and call
  92  * relocate_code(addr_moni). Trick here is that we'll return
  93  * 'here' but relocated.
  94  */
  95
  96         ldr     sp, [r9, #GD_START_ADDR_SP]     /* sp = gd->start_addr_sp */
  97         bic     sp, sp, #7      /* 8-byte alignment for ABI compliance */
  98         ldr     r9, [r9, #GD_BD]                /* r9 = gd->bd */
  99         sub     r9, r9, #GD_SIZE                /* new GD is below bd */
 100
 101         adr     lr, here
 102         ldr     r0, [r9, #GD_RELOC_OFF]         /* r0 = gd->reloc_off */
 103         add     lr, lr, r0
 104         ldr     r0, [r9, #GD_RELOCADDR]         /* r0 = gd->relocaddr */
 105         b       relocate_code
 106 here:
 107 /*
 108  * now relocate vectors
 109  */
 110
 111         bl      relocate_vectors
 112
 113 /* Set up final (full) environment */
 114
 115         bl      c_runtime_cpu_setup     /* we still call old routine here */
 116
 117         ldr     r0, =__bss_start        /* this is auto-relocated! */
 118         ldr     r1, =__bss_end          /* this is auto-relocated! */
 119
 120         mov     r2, #0x00000000         /* prepare zero to clear BSS */
 121
 122 clbss_l:cmp     r0, r1                  /* while not at end of BSS */
 123         strlo   r2, [r0]                /* clear 32-bit BSS word */
 124         addlo   r0, r0, #4              /* move to next */
 125         blo     clbss_l
 126
 127         bl coloured_LED_init
 128         bl red_led_on
 129
 130         /* call board_init_r(gd_t *id, ulong dest_addr) */
 131         mov     r0, r9                  /* gd_t */
 132         ldr     r1, [r9, #GD_RELOCADDR] /* dest_addr */
 133         /* call board_init_r */
 134         ldr     pc, =board_init_r       /* this is auto-relocated! */
 135
 136         /* we should not return here. */
 137
 138 #endif
 139
 140 ENDPROC(_main)