arch/arm/lib/vectors.S

   1 /*
   2  *  vectors - Generic ARM exception table code
   3  *
   4  *  Copyright (c) 1998  Dan Malek <dmalek@jlc.net>
   5  *  Copyright (c) 1999  Magnus Damm <kieraypc01.p.y.kie.era.ericsson.se>
   6  *  Copyright (c) 2000  Wolfgang Denk <wd@denx.de>
   7  *  Copyright (c) 2001  Alex Züpke <azu@sysgo.de>
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2002  Kyle Harris <kharris@nexus-tech.net>
  12  *
  13  * SPDX-License-Identifier:     GPL-2.0+
  14  */
  15
  16 #include <config.h>
  17
  18 /*
  19  *************************************************************************
  20  *
  21  * Symbol _start is referenced elsewhere, so make it global
  22  *
  23  *************************************************************************
  24  */
  25
  26 .globl _start
  27
  28 /*
  29  *************************************************************************
  30  *
  31  * Vectors have their own section so linker script can map them easily
  32  *
  33  *************************************************************************
  34  */
  35
  36         .section ".vectors", "ax"
  37
  38 /*
  39  *************************************************************************
  40  *
  41  * Exception vectors as described in ARM reference manuals
  42  *
  43  * Uses indirect branch to allow reaching handlers anywhere in memory.
  44  *
  45  *************************************************************************
  46  */
  47
  48 _start:
  49
  50 #ifdef CONFIG_SYS_DV_NOR_BOOT_CFG
  51         .word   CONFIG_SYS_DV_NOR_BOOT_CFG
  52 #endif
  53
  54         b       reset
  55         ldr     pc, _undefined_instruction
  56         ldr     pc, _software_interrupt
  57         ldr     pc, _prefetch_abort
  58         ldr     pc, _data_abort
  59         ldr     pc, _not_used
  60         ldr     pc, _irq
  61         ldr     pc, _fiq
  62
  63 /*
  64  *************************************************************************
  65  *
  66  * Indirect vectors table
  67  *
  68  * Symbols referenced here must be defined somewhere else
  69  *
  70  *************************************************************************
  71  */
  72
  73         .globl  _undefined_instruction
  74         .globl  _software_interrupt
  75         .globl  _prefetch_abort
  76         .globl  _data_abort
  77         .globl  _not_used
  78         .globl  _irq
  79         .globl  _fiq
  80
  81 _undefined_instruction: .word undefined_instruction
  82 _software_interrupt:    .word software_interrupt
  83 _prefetch_abort:        .word prefetch_abort
  84 _data_abort:            .word data_abort
  85 _not_used:              .word not_used
  86 _irq:                   .word irq
  87 _fiq:                   .word fiq
  88
  89         .balignl 16,0xdeadbeef
  90
  91 /*
  92  *************************************************************************
  93  *
  94  * Interrupt handling
  95  *
  96  *************************************************************************
  97  */
  98
  99 /* SPL interrupt handling: just hang */
 100
 101 #ifdef CONFIG_SPL_BUILD
 102
 103         .align  5
 104 undefined_instruction:
 105 software_interrupt:
 106 prefetch_abort:
 107 data_abort:
 108 not_used:
 109 irq:
 110 fiq:
 111
 112 1:
 113         bl      1b                      /* hang and never return */
 114
 115 #else   /* !CONFIG_SPL_BUILD */
 116
 117 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 118 .globl IRQ_STACK_START_IN
 119 IRQ_STACK_START_IN:
 120 #ifndef IRAM_BASE_ADDR
 121         .word   0x0badc0de
 122 #else
 123         .word   IRAM_BASE_ADDR + 0x20
 124 #endif
 125
 126 #ifdef CONFIG_USE_IRQ
 127 /* IRQ stack memory (calculated at run-time) */
 128 .globl IRQ_STACK_START
 129 IRQ_STACK_START:
 130         .word   0x0badc0de
 131
 132 /* IRQ stack memory (calculated at run-time) */
 133 .globl FIQ_STACK_START
 134 FIQ_STACK_START:
 135         .word 0x0badc0de
 136
 137 #endif /* CONFIG_USE_IRQ */
 138
 139 @
 140 @ IRQ stack frame.
 141 @
 142 #define S_FRAME_SIZE    72
 143
 144 #define S_OLD_R0        68
 145 #define S_PSR           64
 146 #define S_PC            60
 147 #define S_LR            56
 148 #define S_SP            52
 149
 150 #define S_IP            48
 151 #define S_FP            44
 152 #define S_R10           40
 153 #define S_R9            36
 154 #define S_R8            32
 155 #define S_R7            28
 156 #define S_R6            24
 157 #define S_R5            20
 158 #define S_R4            16
 159 #define S_R3            12
 160 #define S_R2            8
 161 #define S_R1            4
 162 #define S_R0            0
 163
 164 #define MODE_SVC 0x13
 165 #define I_BIT    0x80
 166
 167 /*
 168  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 169  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 170  */
 171
 172         .macro  bad_save_user_regs
 173         @ carve out a frame on current user stack
 174         sub     sp, sp, #S_FRAME_SIZE
 175         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
 176         ldr     r2, IRQ_STACK_START_IN
 177         @ get values for "aborted" pc and cpsr (into parm regs)
 178         ldmia   r2, {r2 - r3}
 179         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 180         add     r5, sp, #S_SP
 181         mov     r1, lr
 182         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
 183         mov     r0, sp          @ save current stack into r0 (param register)
 184         .endm
 185
 186         .macro  irq_save_user_regs
 187         sub     sp, sp, #S_FRAME_SIZE
 188         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 189         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 190         add     r8, sp, #S_PC
 191         stmdb   r8, {sp, lr}^           @ Calling SP, LR
 192         str     lr, [r8, #0]            @ Save calling PC
 193         mrs     r6, spsr
 194         str     r6, [r8, #4]            @ Save CPSR
 195         str     r0, [r8, #8]            @ Save OLD_R0
 196         mov     r0, sp
 197         .endm
 198
 199         .macro  irq_restore_user_regs
 200         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 201         mov     r0, r0
 202         ldr     lr, [sp, #S_PC]                 @ Get PC
 203         add     sp, sp, #S_FRAME_SIZE
 204         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
 205         .endm
 206
 207         .macro get_bad_stack
 208         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 209
 210         str     lr, [r13]       @ save caller lr in position 0 of saved stack
 211         mrs     lr, spsr        @ get the spsr
 212         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
 213         mov     r13, #MODE_SVC  @ prepare SVC-Mode
 214         @ msr   spsr_c, r13
 215         msr     spsr, r13       @ switch modes, make sure moves will execute
 216         mov     lr, pc          @ capture return pc
 217         movs    pc, lr          @ jump to next instruction & switch modes.
 218         .endm
 219
 220         .macro get_irq_stack                    @ setup IRQ stack
 221         ldr     sp, IRQ_STACK_START
 222         .endm
 223
 224         .macro get_fiq_stack                    @ setup FIQ stack
 225         ldr     sp, FIQ_STACK_START
 226         .endm
 227
 228 /*
 229  * exception handlers
 230  */
 231
 232         .align  5
 233 undefined_instruction:
 234         get_bad_stack
 235         bad_save_user_regs
 236         bl      do_undefined_instruction
 237
 238         .align  5
 239 software_interrupt:
 240         get_bad_stack
 241         bad_save_user_regs
 242         bl      do_software_interrupt
 243
 244         .align  5
 245 prefetch_abort:
 246         get_bad_stack
 247         bad_save_user_regs
 248         bl      do_prefetch_abort
 249
 250         .align  5
 251 data_abort:
 252         get_bad_stack
 253         bad_save_user_regs
 254         bl      do_data_abort
 255
 256         .align  5
 257 not_used:
 258         get_bad_stack
 259         bad_save_user_regs
 260         bl      do_not_used
 261
 262 #ifdef CONFIG_USE_IRQ
 263
 264         .align  5
 265 irq:
 266         get_irq_stack
 267         irq_save_user_regs
 268         bl      do_irq
 269         irq_restore_user_regs
 270
 271         .align  5
 272 fiq:
 273         get_fiq_stack
 274         /* someone ought to write a more effiction fiq_save_user_regs */
 275         irq_save_user_regs
 276         bl      do_fiq
 277         irq_restore_user_regs
 278
 279 #else
 280
 281         .align  5
 282 irq:
 283         get_bad_stack
 284         bad_save_user_regs
 285         bl      do_irq
 286
 287         .align  5
 288 fiq:
 289         get_bad_stack
 290         bad_save_user_regs
 291         bl      do_fiq
 292
 293 #endif /* CONFIG_USE_IRQ */
 294
 295 #endif  /* CONFIG_SPL_BUILD */