arch/blackfin/cpu/start.S

   1 /*
   2  * U-boot - start.S Startup file for Blackfin u-boot
   3  *
   4  * Copyright (c) 2005-2008 Analog Devices Inc.
   5  *
   6  * This file is based on head.S
   7  * Copyright (c) 2003  Metrowerks/Motorola
   8  * Copyright (C) 1998  D. Jeff Dionne <jeff@ryeham.ee.ryerson.ca>,
   9  *                     Kenneth Albanowski <kjahds@kjahds.com>,
  10  *                     The Silver Hammer Group, Ltd.
  11  * (c) 1995, Dionne & Associates
  12  * (c) 1995, DKG Display Tech.
  13  *
  14  * See file CREDITS for list of people who contributed to this
  15  * project.
  16  *
  17  * This program is free software; you can redistribute it and/or
  18  * modify it under the terms of the GNU General Public License as
  19  * published by the Free Software Foundation; either version 2 of
  20  * the License, or (at your option) any later version.
  21  *
  22  * This program is distributed in the hope that it will be useful,
  23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25  * GNU General Public License for more details.
  26  *
  27  * You should have received a copy of the GNU General Public License
  28  * along with this program; if not, write to the Free Software
  29  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
  30  * MA 02110-1301 USA
  31  */
  32
  33 #include <config.h>
  34 #include <asm/blackfin.h>
  35 #include <asm/mach-common/bits/core.h>
  36 #include <asm/mach-common/bits/dma.h>
  37 #include <asm/mach-common/bits/pll.h>
  38
  39 #include "serial.h"
  40
  41 /* It may seem odd that we make calls to functions even though we haven't
  42  * relocated ourselves yet out of {flash,ram,wherever}.  This is OK because
  43  * the "call" instruction in the Blackfin architecture is actually PC
  44  * relative.  So we can call functions all we want and not worry about them
  45  * not being relocated yet.
  46  */
  47
  48 .text
  49 ENTRY(_start)
  50
  51         /* Set our initial stack to L1 scratch space */
  52         sp.l = LO(L1_SRAM_SCRATCH_END - 20);
  53         sp.h = HI(L1_SRAM_SCRATCH_END - 20);
  54
  55         /* Optimization register tricks: keep a base value in the
  56          * reserved P registers so we use the load/store with an
  57          * offset syntax.  R0 = [P5 + <constant>];
  58          *   P4 - system MMR base
  59          *   P5 - core MMR base
  60          */
  61 #ifdef CONFIG_HW_WATCHDOG
  62         p4.l = 0;
  63         p4.h = HI(SYSMMR_BASE);
  64 #endif
  65         p5.l = 0;
  66         p5.h = HI(COREMMR_BASE);
  67
  68 #ifdef CONFIG_HW_WATCHDOG
  69 # ifndef CONFIG_HW_WATCHDOG_TIMEOUT_START
  70 #  define CONFIG_HW_WATCHDOG_TIMEOUT_START 5000
  71 # endif
  72         /* Program the watchdog with an initial timeout of ~5 seconds.
  73          * That should be long enough to bootstrap ourselves up and
  74          * then the common u-boot code can take over.
  75          */
  76         r0 = 0;
  77         r0.h = HI(MSEC_TO_SCLK(CONFIG_HW_WATCHDOG_TIMEOUT_START));
  78         [p4 + (WDOG_CNT - SYSMMR_BASE)] = r0;
  79         /* fire up the watchdog - R0.L above needs to be 0x0000 */
  80         W[p4 + (WDOG_CTL - SYSMMR_BASE)] = r0;
  81 #endif
  82
  83         /* Turn on the serial for debugging the init process */
  84         serial_early_init
  85         serial_early_set_baud
  86
  87         serial_early_puts("Init Registers");
  88
  89         /* Disable self-nested interrupts and enable CYCLES for udelay() */
  90         R0 = CCEN | 0x30;
  91         SYSCFG = R0;
  92
  93         /* Zero out registers required by Blackfin ABI.
  94          * http://docs.blackfin.uclinux.org/doku.php?id=application_binary_interface
  95          */
  96         r1 = 0 (x);
  97         /* Disable circular buffers */
  98         l0 = r1;
  99         l1 = r1;
 100         l2 = r1;
 101         l3 = r1;
 102         /* Disable hardware loops in case we were started by 'go' */
 103         lc0 = r1;
 104         lc1 = r1;
 105
 106         /* Save RETX so we can pass it while booting Linux */
 107         r7 = RETX;
 108
 109 #if CONFIG_MEM_SIZE
 110         /* Figure out where we are currently executing so that we can decide
 111          * how to best reprogram and relocate things.  We'll pass below:
 112          *  R4: load address of _start
 113          *  R5: current (not load) address of _start
 114          */
 115         serial_early_puts("Find ourselves");
 116
 117         call _get_pc;
 118 .Loffset:
 119         r1.l = .Loffset;
 120         r1.h = .Loffset;
 121         r4.l = _start;
 122         r4.h = _start;
 123         r3 = r1 - r4;
 124         r5 = r0 - r3;
 125
 126         /* Inform upper layers if we had to do the relocation ourselves.
 127          * This allows us to detect whether we were loaded by 'go 0x1000'
 128          * or by the bootrom from an LDR.  "R6" is "loaded_from_ldr".
 129          */
 130         r6 = 1 (x);
 131         cc = r4 == r5;
 132         if cc jump .Lnorelocate;
 133         r6 = 0 (x);
 134
 135         /* Turn off caches as they require CPLBs and a CPLB miss requires
 136          * a software exception handler to process it.  But we're about to
 137          * clobber any previous executing software (like U-Boot that just
 138          * launched a new U-Boot via 'go'), so any handler state will be
 139          * unreliable after the memcpy below.
 140          */
 141         serial_early_puts("Kill Caches");
 142         r0 = 0;
 143         [p5 + (IMEM_CONTROL - COREMMR_BASE)] = r0;
 144         [p5 + (DMEM_CONTROL - COREMMR_BASE)] = r0;
 145         ssync;
 146
 147         /* In bypass mode, we don't have an LDR with an init block
 148          * so we need to explicitly call it ourselves.  This will
 149          * reprogram our clocks, memory, and setup our async banks.
 150          */
 151         serial_early_puts("Program Clocks");
 152
 153         /* if we're executing >=0x20000000, then we dont need to dma */
 154         r3 = 0x0;
 155         r3.h = 0x2000;
 156         cc = r5 < r3 (iu);
 157         if cc jump .Ldma_and_reprogram;
 158 #else
 159         r6 = 1 (x);     /* fake loaded_from_ldr = 1 */
 160 #endif
 161         r0 = 0 (x);     /* set bootstruct to NULL */
 162         call _initcode;
 163         jump .Lprogrammed;
 164
 165         /* we're sitting in external memory, so dma into L1 and reprogram */
 166 .Ldma_and_reprogram:
 167         r0.l = LO(L1_INST_SRAM);
 168         r0.h = HI(L1_INST_SRAM);
 169         r1.l = __initcode_lma;
 170         r1.h = __initcode_lma;
 171         r2.l = __initcode_len;
 172         r2.h = __initcode_len;
 173         r1 = r1 - r4;   /* convert r1 from load address of initcode ... */
 174         r1 = r1 + r5;   /* ... to current (not load) address of initcode */
 175         p3 = r0;
 176         call _dma_memcpy_nocache;
 177         r0 = 0 (x);     /* set bootstruct to NULL */
 178         call (p3);
 179
 180         /* Since we reprogrammed SCLK, we need to update the serial divisor */
 181 .Lprogrammed:
 182         serial_early_set_baud
 183
 184 #if CONFIG_MEM_SIZE
 185         /* Relocate from wherever we are (FLASH/RAM/etc...) to the hardcoded
 186          * monitor location in the end of RAM.  We know that memcpy() only
 187          * uses registers, so it is safe to call here.  Note that this only
 188          * copies to external memory ... we do not start executing out of
 189          * it yet (see "lower to 15" below).
 190          */
 191         serial_early_puts("Relocate");
 192         r0 = r4;
 193         r1 = r5;
 194         r2.l = LO(CONFIG_SYS_MONITOR_LEN);
 195         r2.h = HI(CONFIG_SYS_MONITOR_LEN);
 196         call _memcpy_ASM;
 197 #endif
 198
 199         /* Initialize BSS section ... we know that memset() does not
 200          * use the BSS, so it is safe to call here.  The bootrom LDR
 201          * takes care of clearing things for us.
 202          */
 203         serial_early_puts("Zero BSS");
 204         r0.l = __bss_vma;
 205         r0.h = __bss_vma;
 206         r1 = 0 (x);
 207         r2.l = __bss_len;
 208         r2.h = __bss_len;
 209         call _memset;
 210
 211 .Lnorelocate:
 212
 213         /* Setup the actual stack in external memory */
 214         sp.h = HI(CONFIG_STACKBASE);
 215         sp.l = LO(CONFIG_STACKBASE);
 216         fp = sp;
 217
 218         /* Now lower ourselves from the highest interrupt level to
 219          * the lowest.  We do this by masking all interrupts but 15,
 220          * setting the 15 handler to ".Lenable_nested", raising the 15
 221          * interrupt, and then returning from the highest interrupt
 222          * level to the dummy "jump" until the interrupt controller
 223          * services the pending 15 interrupt.  If executing out of
 224          * flash, these steps also changes the code flow from flash
 225          * to external memory.
 226          */
 227         serial_early_puts("Lower to 15");
 228         r0 = r7;
 229         r1 = r6;
 230         p1.l = .Lenable_nested;
 231         p1.h = .Lenable_nested;
 232         [p5 + (EVT15 - COREMMR_BASE)] = p1;
 233         r7 = EVT_IVG15 (z);
 234         sti r7;
 235         raise 15;
 236         p3.l = .LWAIT_HERE;
 237         p3.h = .LWAIT_HERE;
 238         reti = p3;
 239         rti;
 240
 241         /* Enable nested interrupts before continuing with cpu init */
 242 .Lenable_nested:
 243         cli r7;
 244         [--sp] = reti;
 245         jump.l _cpu_init_f;
 246
 247 .LWAIT_HERE:
 248         jump .LWAIT_HERE;
 249 ENDPROC(_start)
 250
 251 LENTRY(_get_pc)
 252         r0 = rets;
 253 #if ANOMALY_05000371
 254         NOP;
 255         NOP;
 256         NOP;
 257 #endif
 258         rts;
 259 ENDPROC(_get_pc)