arch/powerpc/cpu/mpc5xxx/u-boot-customlayout.lds

   1 /*
   2  * (C) Copyright 2003-2004
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .interp : { *(.interp) }
  32   .hash          : { *(.hash)           }
  33   .dynsym        : { *(.dynsym)         }
  34   .dynstr        : { *(.dynstr)         }
  35   .rel.text      : { *(.rel.text)               }
  36   .rela.text     : { *(.rela.text)      }
  37   .rel.data      : { *(.rel.data)               }
  38   .rela.data     : { *(.rela.data)      }
  39   .rel.rodata    : { *(.rel.rodata)     }
  40   .rela.rodata   : { *(.rela.rodata)    }
  41   .rel.got       : { *(.rel.got)                }
  42   .rela.got      : { *(.rela.got)               }
  43   .rel.ctors     : { *(.rel.ctors)      }
  44   .rela.ctors    : { *(.rela.ctors)     }
  45   .rel.dtors     : { *(.rel.dtors)      }
  46   .rela.dtors    : { *(.rela.dtors)     }
  47   .rel.bss       : { *(.rel.bss)                }
  48   .rela.bss      : { *(.rela.bss)               }
  49   .rel.plt       : { *(.rel.plt)                }
  50   .rela.plt      : { *(.rela.plt)               }
  51   .init          : { *(.init)   }
  52   .plt : { *(.plt) }
  53   .text      :
  54   {
  55     /* WARNING - the following is hand-optimized to fit within  */
  56     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  57
  58     arch/powerpc/cpu/mpc5xxx/start.o          (.text)
  59     arch/powerpc/cpu/mpc5xxx/traps.o          (.text)
  60     lib/crc32.o         (.text)
  61     arch/powerpc/lib/cache.o             (.text)
  62     arch/powerpc/lib/time.o              (.text)
  63
  64     . = DEFINED(env_offset) ? env_offset : .;
  65     common/env_embedded.o        (.ppcenv)
  66
  67     *(.text)
  68     *(.got1)
  69     . = ALIGN(16);
  70     *(.eh_frame)
  71     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  72   }
  73   .fini      : { *(.fini)    } =0
  74   .ctors     : { *(.ctors)   }
  75   .dtors     : { *(.dtors)   }
  76
  77   /* Read-write section, merged into data segment: */
  78   . = (. + 0x0FFF) & 0xFFFFF000;
  79   _erotext = .;
  80   PROVIDE (erotext = .);
  81   .reloc   :
  82   {
  83     *(.got)
  84     _GOT2_TABLE_ = .;
  85     *(.got2)
  86     _FIXUP_TABLE_ = .;
  87     *(.fixup)
  88   }
  89   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  90   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  91
  92   .data    :
  93   {
  94     *(.data)
  95     *(.data1)
  96     *(.sdata)
  97     *(.sdata2)
  98     *(.dynamic)
  99     CONSTRUCTORS
 100   }
 101   _edata  =  .;
 102   PROVIDE (edata = .);
 103
 104   . = .;
 105   __u_boot_cmd_start = .;
 106   .u_boot_cmd : { *(.u_boot_cmd) }
 107   __u_boot_cmd_end = .;
 108
 109
 110   . = .;
 111   __start___ex_table = .;
 112   __ex_table : { *(__ex_table) }
 113   __stop___ex_table = .;
 114
 115   . = ALIGN(4096);
 116   __init_begin = .;
 117   .text.init : { *(.text.init) }
 118   .data.init : { *(.data.init) }
 119   . = ALIGN(4096);
 120   __init_end = .;
 121
 122   __bss_start = .;
 123   .bss (NOLOAD)       :
 124   {
 125    *(.sbss) *(.scommon)
 126    *(.dynbss)
 127    *(.bss)
 128    *(COMMON)
 129    . = ALIGN(4);
 130   }
 131   _end = . ;
 132   PROVIDE (end = .);
 133 }