board/adder/u-boot.lds

   1 /*
   2  * (C) Copyright 2001-2003
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * Modified by Yuli Barcohen <yuli@arabellasw.com>
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 OUTPUT_ARCH(powerpc)
  11 SECTIONS
  12 {
  13   /* Read-only sections, merged into text segment: */
  14   . = + SIZEOF_HEADERS;
  15   .text          :
  16   {
  17     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  18     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  19     *(.text*)
  20     . = ALIGN(16);
  21     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  22   }
  23
  24   /* Read-write section, merged into data segment: */
  25   . = (. + 0x0FFF) & 0xFFFFF000;
  26   _erotext = .;
  27   PROVIDE (erotext = .);
  28   .reloc   :
  29   {
  30     _GOT2_TABLE_ = .;
  31     KEEP(*(.got2))
  32     KEEP(*(.got))
  33     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  34     _FIXUP_TABLE_ = .;
  35     KEEP(*(.fixup))
  36   }
  37   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  38   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  39
  40   .data    :
  41   {
  42     *(.data*)
  43     *(.sdata*)
  44   }
  45   _edata  =  .;
  46   PROVIDE (edata = .);
  47
  48   . = .;
  49
  50   . = ALIGN(4);
  51   .u_boot_list : {
  52         KEEP(*(SORT(.u_boot_list*)));
  53   }
  54
  55
  56   . = .;
  57   __start___ex_table = .;
  58   __ex_table : { *(__ex_table) }
  59   __stop___ex_table = .;
  60
  61   . = ALIGN(4096);
  62   __init_begin = .;
  63   .text.init : { *(.text.init) }
  64   .data.init : { *(.data.init) }
  65   . = ALIGN(4096);
  66   __init_end = .;
  67
  68   __bss_start = .;
  69   .bss (NOLOAD)       :
  70   {
  71    *(.bss*)
  72    *(.sbss*)
  73    *(COMMON)
  74    . = ALIGN(4);
  75   }
  76   __bss_end = . ;
  77   PROVIDE (end = .);
  78 }
  79 ENTRY(_start)