board/bf561-ezkit/u-boot.lds.S

   1 /*
   2  * U-boot - u-boot.lds.S
   3  *
   4  * Copyright (c) 2005-2007 Analog Device Inc.
   5  *
   6  * (C) Copyright 2000-2004
   7  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   8  *
   9  * See file CREDITS for list of people who contributed to this
  10  * project.
  11  *
  12  * This program is free software; you can redistribute it and/or
  13  * modify it under the terms of the GNU General Public License as
  14  * published by the Free Software Foundation; either version 2 of
  15  * the License, or (at your option) any later version.
  16  *
  17  * This program is distributed in the hope that it will be useful,
  18  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  19  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20  * GNU General Public License for more details.
  21  *
  22  * You should have received a copy of the GNU General Public License
  23  * along with this program; if not, write to the Free Software
  24  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  25  * MA 02111-1307 USA
  26  */
  27
  28 #include <config.h>
  29
  30 OUTPUT_ARCH(bfin)
  31 OUTPUT_ARCH(bfin)
  32 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib);
  33 /* Do we need any of these for elf?
  34    __DYNAMIC = 0;    */
  35 SECTIONS
  36 {
  37   /* Read-only sections, merged into text segment: */
  38   . = + SIZEOF_HEADERS;
  39   .interp : { *(.interp) }
  40   .hash         : { *(.hash)            }
  41   .dynsym       : { *(.dynsym)          }
  42   .dynstr       : { *(.dynstr)          }
  43   .rel.text     : { *(.rel.text)        }
  44   .rela.text    : { *(.rela.text)       }
  45   .rel.data     : { *(.rel.data)        }
  46   .rela.data    : { *(.rela.data)       }
  47   .rel.rodata   : { *(.rel.rodata)      }
  48   .rela.rodata  : { *(.rela.rodata)     }
  49   .rel.got      : { *(.rel.got)         }
  50   .rela.got     : { *(.rela.got)        }
  51   .rel.ctors    : { *(.rel.ctors)       }
  52   .rela.ctors   : { *(.rela.ctors)      }
  53   .rel.dtors    : { *(.rel.dtors)       }
  54   .rela.dtors   : { *(.rela.dtors)      }
  55   .rel.bss      : { *(.rel.bss) }
  56   .rela.bss     : { *(.rela.bss)        }
  57   .rel.plt      : { *(.rel.plt) }
  58   .rela.plt     : { *(.rela.plt)        }
  59   .init         : { *(.init)            }
  60   .plt : { *(.plt) }
  61   . = CFG_MONITOR_BASE;
  62   .text      :
  63   {
  64     /* WARNING - the following is hand-optimized to fit within  */
  65     /* the sector before the environment sector. If it throws   */
  66     /* an error during compilation remove an object here to get */
  67     /* it linked after the configuration sector.                */
  68
  69     cpu/bf561/start.o           (.text)
  70     cpu/bf561/start1.o          (.text)
  71     cpu/bf561/traps.o           (.text)
  72     cpu/bf561/interrupt.o       (.text)
  73     cpu/bf561/serial.o          (.text)
  74     common/dlmalloc.o           (.text)
  75 /*  lib_blackfin/bf533_string.o (.text) */
  76 /*  lib_generic/vsprintf.o      (.text) */
  77     lib_generic/crc32.o         (.text)
  78     lib_generic/zlib.o          (.text)
  79     board/bf561-ezkit/bf561-ezkit.o             (.text)
  80
  81     . = DEFINED(env_offset) ? env_offset : .;
  82     common/environment.o        (.text)
  83
  84     *(.text)
  85     *(.fixup)
  86     *(.got1)
  87   }
  88   _etext = .;
  89   PROVIDE (etext = .);
  90   .rodata    :
  91   {
  92     *(.rodata)
  93     *(.rodata1)
  94     *(.rodata.str1.4)
  95   }
  96   .fini      : { *(.fini)    } =0
  97   .ctors     : { *(.ctors)   }
  98   .dtors     : { *(.dtors)   }
  99
 100   /* Read-write section, merged into data segment: */
 101   . = (. + 0x00FF) & 0xFFFFFF00;
 102   _erotext = .;
 103   PROVIDE (erotext = .);
 104   .reloc   :
 105   {
 106     *(.got)
 107     _GOT2_TABLE_ = .;
 108     *(.got2)
 109     _FIXUP_TABLE_ = .;
 110     *(.fixup)
 111   }
 112   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 113   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 114
 115   .data    :
 116   {
 117     *(.data)
 118     *(.data1)
 119     *(.sdata)
 120     *(.sdata2)
 121     *(.dynamic)
 122     CONSTRUCTORS
 123   }
 124   _edata  =  .;
 125   PROVIDE (edata = .);
 126
 127   ___u_boot_cmd_start = .;
 128   .u_boot_cmd : { *(.u_boot_cmd) }
 129   ___u_boot_cmd_end = .;
 130
 131
 132   __start___ex_table = .;
 133   __ex_table : { *(__ex_table) }
 134   __stop___ex_table = .;
 135
 136   . = ALIGN(256);
 137   __init_begin = .;
 138   .text.init : { *(.text.init) }
 139   .data.init : { *(.data.init) }
 140   . = ALIGN(256);
 141   __init_end = .;
 142
 143   __bss_start = .;
 144   .bss       :
 145   {
 146    *(.sbss) *(.scommon)
 147    *(.dynbss)
 148    *(.bss)
 149    *(COMMON)
 150   }
 151   _end = . ;
 152   PROVIDE (end = .);
 153 }