board/exbitgen/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   .resetvec 0xFFFFFFFC :
  30   {
  31     *(.resetvec)
  32   } = 0xffff
  33
  34   /* Read-only sections, merged into text segment: */
  35   . = + SIZEOF_HEADERS;
  36   .interp : { *(.interp) }
  37   .hash          : { *(.hash)           }
  38   .dynsym        : { *(.dynsym)         }
  39   .dynstr        : { *(.dynstr)         }
  40   .rel.text      : { *(.rel.text)               }
  41   .rela.text     : { *(.rela.text)      }
  42   .rel.data      : { *(.rel.data)               }
  43   .rela.data     : { *(.rela.data)      }
  44   .rel.rodata    : { *(.rel.rodata)     }
  45   .rela.rodata   : { *(.rela.rodata)    }
  46   .rel.got       : { *(.rel.got)                }
  47   .rela.got      : { *(.rela.got)               }
  48   .rel.ctors     : { *(.rel.ctors)      }
  49   .rela.ctors    : { *(.rela.ctors)     }
  50   .rel.dtors     : { *(.rel.dtors)      }
  51   .rela.dtors    : { *(.rela.dtors)     }
  52   .rel.bss       : { *(.rel.bss)                }
  53   .rela.bss      : { *(.rela.bss)               }
  54   .rel.plt       : { *(.rel.plt)                }
  55   .rela.plt      : { *(.rela.plt)               }
  56   .init          : { *(.init)   }
  57   .plt : { *(.plt) }
  58   .text      :
  59   {
  60     /* WARNING - the following is hand-optimized to fit within  */
  61     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  62
  63     cpu/ppc4xx/start.o  (.text)
  64     board/exbitgen/init.o       (.text)
  65     cpu/ppc4xx/kgdb.o   (.text)
  66     cpu/ppc4xx/traps.o  (.text)
  67     cpu/ppc4xx/interrupts.o     (.text)
  68     cpu/ppc4xx/4xx_uart.o       (.text)
  69     cpu/ppc4xx/cpu_init.o       (.text)
  70     cpu/ppc4xx/speed.o  (.text)
  71     common/dlmalloc.o   (.text)
  72     lib_generic/crc32.o         (.text)
  73     lib_ppc/extable.o   (.text)
  74     lib_generic/zlib.o          (.text)
  75
  76 /*    . = env_offset;*/
  77     common/env_embedded.o(.text)
  78
  79     *(.text)
  80     *(.fixup)
  81     *(.got1)
  82   }
  83   _etext = .;
  84   PROVIDE (etext = .);
  85   .rodata    :
  86   {
  87     *(.eh_frame)
  88     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  89   }
  90   .fini      : { *(.fini)    } =0
  91   .ctors     : { *(.ctors)   }
  92   .dtors     : { *(.dtors)   }
  93
  94   /* Read-write section, merged into data segment: */
  95   . = (. + 0x00FF) & 0xFFFFFF00;
  96   _erotext = .;
  97   PROVIDE (erotext = .);
  98   .reloc   :
  99   {
 100     *(.got)
 101     _GOT2_TABLE_ = .;
 102     *(.got2)
 103     _FIXUP_TABLE_ = .;
 104     *(.fixup)
 105   }
 106   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 107   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 108
 109   .data    :
 110   {
 111     *(.data)
 112     *(.data1)
 113     *(.sdata)
 114     *(.sdata2)
 115     *(.dynamic)
 116     CONSTRUCTORS
 117   }
 118   _edata  =  .;
 119   PROVIDE (edata = .);
 120
 121   . = .;
 122   __u_boot_cmd_start = .;
 123   .u_boot_cmd : { *(.u_boot_cmd) }
 124   __u_boot_cmd_end = .;
 125
 126   . = .;
 127   __start___ex_table = .;
 128   __ex_table : { *(__ex_table) }
 129   __stop___ex_table = .;
 130
 131   . = ALIGN(256);
 132   __init_begin = .;
 133   .text.init : { *(.text.init) }
 134   .data.init : { *(.data.init) }
 135   . = ALIGN(256);
 136   __init_end = .;
 137
 138   __bss_start = .;
 139   .bss (NOLOAD)       :
 140   {
 141    *(.sbss) *(.scommon)
 142    *(.dynbss)
 143   . = ALIGN(4);
 144    *(.bss)
 145    *(COMMON)
 146    . = ALIGN(4);
 147   }
 148   _end = . ;
 149   PROVIDE (end = .);
 150 }