board/hermes/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   . = + SIZEOF_HEADERS;
  30   .text      :
  31   {
  32     /* WARNING - the following is hand-optimized to fit within  */
  33     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  34     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  35     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  36     board/hermes/libhermes.o            (.text*)
  37
  38     . = env_offset;
  39     common/env_embedded.o               (.text*)
  40
  41     *(.text*)
  42   }
  43   _etext = .;
  44   PROVIDE (etext = .);
  45   .rodata    :
  46   {
  47     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  48   }
  49
  50   /* Read-write section, merged into data segment: */
  51   . = (. + 0x00FF) & 0xFFFFFF00;
  52   _erotext = .;
  53   PROVIDE (erotext = .);
  54   .reloc   :
  55   {
  56     _GOT2_TABLE_ = .;
  57     KEEP(*(.got2))
  58     KEEP(*(.got))
  59     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  60     _FIXUP_TABLE_ = .;
  61     KEEP(*(.fixup))
  62   }
  63   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  64   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  65
  66   .data    :
  67   {
  68     *(.data*)
  69     *(.sdata*)
  70   }
  71   _edata  =  .;
  72   PROVIDE (edata = .);
  73
  74   . = .;
  75
  76   . = ALIGN(4);
  77   .u_boot_list : {
  78         KEEP(*(SORT(.u_boot_list*)));
  79   }
  80
  81
  82   . = .;
  83   __start___ex_table = .;
  84   __ex_table : { *(__ex_table) }
  85   __stop___ex_table = .;
  86
  87   . = ALIGN(256);
  88   __init_begin = .;
  89   .text.init : { *(.text.init) }
  90   .data.init : { *(.data.init) }
  91   . = ALIGN(256);
  92   __init_end = .;
  93
  94   __bss_start = .;
  95   .bss (NOLOAD)       :
  96   {
  97    *(.bss*)
  98    *(.sbss*)
  99    *(COMMON)
 100    . = ALIGN(4);
 101   }
 102   __bss_end = . ;
 103   PROVIDE (end = .);
 104 }