board/tqc/tqm8xx/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2012
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9
  10 SECTIONS
  11 {
  12   /* Read-only sections, merged into text segment: */
  13   . = + SIZEOF_HEADERS;
  14   .text      :
  15   {
  16     /* WARNING - the following is hand-optimized to fit within  */
  17     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  18
  19     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  20     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  21     arch/powerpc/cpu/mpc8xx/libmpc8xx.o (.text*)
  22     arch/powerpc/lib/libpowerpc.o       (.text*)
  23     board/tqc/tqm8xx/libtqm8xx.o        (.text*)
  24     disk/libdisk.o                      (.text*)
  25     drivers/net/libnet.o                (.text*)
  26     drivers/libdrivers.o                (.text.pcmcia_on)
  27     drivers/libdrivers.o                (.text.pcmcia_hardware_enable)
  28
  29     . = DEFINED(env_offset) ? env_offset : .;
  30     common/env_embedded.o       (.ppcenv*)
  31
  32     *(.text*)
  33   }
  34   _etext = .;
  35   PROVIDE (etext = .);
  36   .rodata    :
  37   {
  38     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  39   }
  40
  41   /* Read-write section, merged into data segment: */
  42   . = (. + 0x00FF) & 0xFFFFFF00;
  43   _erotext = .;
  44   PROVIDE (erotext = .);
  45   .reloc   :
  46   {
  47     _GOT2_TABLE_ = .;
  48     KEEP(*(.got2))
  49     KEEP(*(.got))
  50     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  51     _FIXUP_TABLE_ = .;
  52     KEEP(*(.fixup))
  53   }
  54   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  55   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  56
  57   .data    :
  58   {
  59     *(.data*)
  60     *(.sdata*)
  61   }
  62   _edata  =  .;
  63   PROVIDE (edata = .);
  64
  65   . = .;
  66
  67   . = ALIGN(4);
  68   .u_boot_list : {
  69         KEEP(*(SORT(.u_boot_list*)));
  70   }
  71
  72
  73   . = .;
  74   __start___ex_table = .;
  75   __ex_table : { *(__ex_table) }
  76   __stop___ex_table = .;
  77
  78   . = ALIGN(256);
  79   __init_begin = .;
  80   .text.init : { *(.text.init) }
  81   .data.init : { *(.data.init) }
  82   . = ALIGN(256);
  83   __init_end = .;
  84
  85   __bss_start = .;
  86   .bss (NOLOAD)       :
  87   {
  88    *(.bss*)
  89    *(.sbss*)
  90    *(COMMON)
  91    . = ALIGN(4);
  92   }
  93   __bss_end = . ;
  94   PROVIDE (end = .);
  95 }