board/uc100/u-boot.lds.debug

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .interp : { *(.interp) }
  32   .hash          : { *(.hash)           }
  33   .dynsym        : { *(.dynsym)         }
  34   .dynstr        : { *(.dynstr)         }
  35   .rel.text      : { *(.rel.text)               }
  36   .rela.text     : { *(.rela.text)      }
  37   .rel.data      : { *(.rel.data)               }
  38   .rela.data     : { *(.rela.data)      }
  39   .rel.rodata    : { *(.rel.rodata)     }
  40   .rela.rodata   : { *(.rela.rodata)    }
  41   .rel.got       : { *(.rel.got)                }
  42   .rela.got      : { *(.rela.got)               }
  43   .rel.ctors     : { *(.rel.ctors)      }
  44   .rela.ctors    : { *(.rela.ctors)     }
  45   .rel.dtors     : { *(.rel.dtors)      }
  46   .rela.dtors    : { *(.rela.dtors)     }
  47   .rel.bss       : { *(.rel.bss)                }
  48   .rela.bss      : { *(.rela.bss)               }
  49   .rel.plt       : { *(.rel.plt)                }
  50   .rela.plt      : { *(.rela.plt)               }
  51   .init          : { *(.init)   }
  52   .plt : { *(.plt) }
  53   .text      :
  54   {
  55     /* WARNING - the following is hand-optimized to fit within  */
  56     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  57
  58     arch/powerpc/cpu/mpc8xx/start.o     (.text)
  59     common/dlmalloc.o   (.text)
  60     lib/vsprintf.o      (.text)
  61     lib/crc32.o         (.text)
  62
  63     common/env_embedded.o(.text)
  64
  65     *(.text)
  66     *(.got1)
  67   }
  68   _etext = .;
  69   PROVIDE (etext = .);
  70   .rodata    :
  71   {
  72     *(.rodata)
  73     *(.rodata1)
  74     *(.rodata.str1.4)
  75     *(.eh_frame)
  76   }
  77   .fini      : { *(.fini)    } =0
  78   .ctors     : { *(.ctors)   }
  79   .dtors     : { *(.dtors)   }
  80
  81   /* Read-write section, merged into data segment: */
  82   . = (. + 0x0FFF) & 0xFFFFF000;
  83   _erotext = .;
  84   PROVIDE (erotext = .);
  85   .reloc   :
  86   {
  87     *(.got)
  88     _GOT2_TABLE_ = .;
  89     *(.got2)
  90     _FIXUP_TABLE_ = .;
  91     *(.fixup)
  92   }
  93   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  94   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  95
  96   .data    :
  97   {
  98     *(.data)
  99     *(.data1)
 100     *(.sdata)
 101     *(.sdata2)
 102     *(.dynamic)
 103     CONSTRUCTORS
 104   }
 105   _edata  =  .;
 106   PROVIDE (edata = .);
 107
 108   __u_boot_cmd_start = .;
 109   .u_boot_cmd : { *(.u_boot_cmd) }
 110   __u_boot_cmd_end = .;
 111
 112
 113   __start___ex_table = .;
 114   __ex_table : { *(__ex_table) }
 115   __stop___ex_table = .;
 116
 117   . = ALIGN(4096);
 118   __init_begin = .;
 119   .text.init : { *(.text.init) }
 120   .data.init : { *(.data.init) }
 121   . = ALIGN(4096);
 122   __init_end = .;
 123
 124   __bss_start = .;
 125   .bss       :
 126   {
 127    *(.sbss) *(.scommon)
 128    *(.dynbss)
 129    *(.bss)
 130    *(COMMON)
 131   }
 132   _end = . ;
 133   PROVIDE (end = .);
 134 }