board/vpac270/u-boot-spl.lds

   1 /*
   2  * Copyright (C) 2011 Marek Vasut <marek.vasut@gmail.com>
   3  * on behalf of DENX Software Engineering GmbH
   4  *
   5  * January 2004 - Changed to support H4 device
   6  * Copyright (c) 2004-2008 Texas Instruments
   7  *
   8  * (C) Copyright 2002
   9  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
  10  *
  11  * SPDX-License-Identifier:     GPL-2.0+
  12  */
  13
  14 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  15 OUTPUT_ARCH(arm)
  16 ENTRY(_start)
  17 SECTIONS
  18 {
  19         . = CONFIG_SPL_TEXT_BASE;
  20         .text.0 :
  21         {
  22                 arch/arm/cpu/pxa/start.o                (.text*)
  23                 board/vpac270/libvpac270.o              (.text*)
  24                 drivers/mtd/onenand/libonenand.o        (.text*)
  25         }
  26
  27
  28         /* Start of the rest of the SPL */
  29         . = CONFIG_SPL_TEXT_BASE + 0x800;
  30
  31         .text.1 :
  32         {
  33                 *(.text*)
  34         }
  35
  36         . = ALIGN(4);
  37         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  38
  39         . = ALIGN(4);
  40         .data : {
  41                 *(.data*)
  42         }
  43
  44         . = ALIGN(4);
  45
  46         __image_copy_end = .;
  47
  48         .rel.dyn : {
  49                 __rel_dyn_start = .;
  50                 *(.rel*)
  51                 __rel_dyn_end = .;
  52         }
  53
  54         . = ALIGN(0x800);
  55
  56         _end = .;
  57
  58         .bss __rel_dyn_start (OVERLAY) : {
  59                 __bss_start = .;
  60                 *(.bss*)
  61                  . = ALIGN(4);
  62                 __bss_end = .;
  63         }
  64
  65         /DISCARD/ : { *(.bss*) }
  66         /DISCARD/ : { *(.dynsym) }
  67         /DISCARD/ : { *(.dynstr*) }
  68         /DISCARD/ : { *(.dynsym*) }
  69         /DISCARD/ : { *(.dynamic*) }
  70         /DISCARD/ : { *(.hash*) }
  71         /DISCARD/ : { *(.plt*) }
  72         /DISCARD/ : { *(.interp*) }
  73         /DISCARD/ : { *(.gnu*) }
  74 }