cpu/i386/start.S

   1 /*
   2  *  U-boot - i386 Startup Code
   3  *
   4  *  Copyright (c) 2002  Omicron Ceti AB, Daniel Engström <denaiel@omicron.se>
   5  *
   6  * See file CREDITS for list of people who contributed to this
   7  * project.
   8  *
   9  * This program is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU General Public License as
  11  * published by the Free Software Foundation; either version 2 of
  12  * the License, or (at your option) any later version.
  13  *
  14  * This program is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  22  * MA 02111-1307 USA
  23  */
  24
  25
  26 #include <config.h>
  27 #include <version.h>
  28
  29
  30 .section .text
  31 .code32
  32 .globl _start
  33 .type _start, @function
  34 .globl _i386boot_start
  35 _i386boot_start:
  36 _start:
  37         movl    $0x18,%eax              /* Load our segement registes, the
  38                                          * gdt have already been loaded by start16.S */
  39         movw    %ax,%fs
  40         movw    %ax,%ds
  41         movw    %ax,%gs
  42         movw    %ax,%es
  43         movw    %ax,%ss
  44
  45         /* We call a few functions in the board support package
  46          * since we have no stack yet we'll have to use %ebp
  47          * to store the return address */
  48
  49         /* Early platform init (setup gpio, etc ) */
  50         mov     $early_board_init_ret, %ebp
  51         jmp     early_board_init
  52 early_board_init_ret:
  53
  54         /* The __port80 entry-point should be usabe by now */
  55         /* so we try to indicate progress */
  56         movw    $0x01, %ax
  57         movl    $.progress0, %ebp
  58         jmp     __show_boot_progress
  59 .progress0:
  60
  61         /* size memory */
  62         mov     $mem_init_ret, %ebp
  63         jmp     mem_init
  64 mem_init_ret:
  65
  66         /* check ammount of configured memory
  67          * (we need atleast bss start+bss size+stack size) */
  68         movl    $_i386boot_bss_start, %ecx        /* BSS start */
  69         addl    $_i386boot_bss_size, %ecx         /* BSS size */
  70         addl    $CFG_STACK_SIZE, %ecx
  71         cmpl    %ecx, %eax
  72         jae     mem_ok
  73
  74         /* indicate (lack of) progress */
  75         movw    $0x81, %ax
  76         movl    $.progress0a, %ebp
  77         jmp     __show_boot_progress
  78 .progress0a:
  79         jmp     die
  80 mem_ok:
  81
  82         /* indicate progress */
  83         movw    $0x02, %ax
  84         movl    $.progress1, %ebp
  85         jmp     __show_boot_progress
  86 .progress1:
  87
  88         /* create a stack after the bss */
  89         movl    $_i386boot_bss_start, %eax
  90         addl    $_i386boot_bss_size, %eax
  91         addl    $CFG_STACK_SIZE, %eax
  92         movl    %eax, %esp
  93
  94         pushl   $0
  95         popl    %eax
  96         cmpl    $0, %eax
  97         jne     no_stack
  98         push    $0x55aa55aa
  99         popl    %ebx
 100         cmpl    $0x55aa55aa, %ebx
 101         je      stack_ok
 102
 103 no_stack:
 104         /* indicate (lack of) progress */
 105         movw    $0x82, %ax
 106         movl    $.progress1a, %ebp
 107         jmp     __show_boot_progress
 108 .progress1a:
 109         jmp die
 110
 111
 112 stack_ok:
 113         /* indicate progress */
 114         movw    $0x03, %ax
 115         movl    $.progress2, %ebp
 116         jmp     __show_boot_progress
 117 .progress2:
 118
 119         /* copy data section to ram, size must be 4-byte aligned */
 120         movl    $_i386boot_romdata_dest, %edi     /* destination address */
 121         movl    $_i386boot_romdata_start, %esi    /* source address */
 122         movl    $_i386boot_romdata_size, %ecx     /* number of bytes to copy */
 123         movl    %ecx, %eax
 124         andl    $3, %eax
 125         jnz     data_fail
 126
 127         shrl    $2, %ecx                          /* copy 4 byte each time */
 128         cld
 129         cmpl    $0, %ecx
 130         je      data_ok
 131 data_segment:
 132         movsl
 133         loop    data_segment
 134         jmp     data_ok
 135 data_fail:
 136         /* indicate (lack of) progress */
 137         movw    $0x83, %ax
 138         movl    $.progress2a, %ebp
 139         jmp     __show_boot_progress
 140 .progress2a:
 141         jmp     die
 142
 143 data_ok:
 144
 145         /* indicate progress */
 146         movw    $0x04, %ax
 147         movl    $.progress3, %ebp
 148         jmp     __show_boot_progress
 149 .progress3:
 150
 151         /* clear bss section in ram, size must be 4-byte aligned  */
 152         movl    $_i386boot_bss_start, %eax        /* BSS start */
 153         movl    $_i386boot_bss_size, %ecx         /* BSS size */
 154         movl    %ecx, %eax
 155         andl    $3, %eax
 156         jnz     bss_fail
 157         shrl    $2, %ecx                          /* clear 4 byte each time */
 158         cld
 159         cmpl    $0, %ecx
 160         je      bss_ok
 161 bss:
 162         movl    $0, (%edi)
 163         add     $4, %edi
 164         loop    bss
 165         jmp     bss_ok
 166
 167 bss_fail:
 168         /* indicate (lack of) progress */
 169         movw    $0x84, %ax
 170         movl    $.progress3a, %ebp
 171         jmp     __show_boot_progress
 172 .progress3a:
 173         jmp     die
 174
 175 bss_ok:
 176
 177         wbinvd
 178
 179
 180         /* indicate progress */
 181         movw    $0x05, %ax
 182         movl    $.progress4, %ebp
 183         jmp     __show_boot_progress
 184 .progress4:
 185
 186         call    start_i386boot  /* Enter, U-boot! */
 187
 188         /* indicate (lack of) progress */
 189         movw    $0x85, %ax
 190         movl    $.progress4a, %ebp
 191         jmp     __show_boot_progress
 192 .progress4a:
 193
 194 die:    hlt
 195         jmp     die
 196         hlt
 197
 198