870127e0b7c15a08b38aa918588ef61221ccdd6f
[meta-kc-bsp.git] / recipes-bsp / dotsplash / dotsplash_git.bb
1 SUMMARY = "./dotsplash - a tiny and customizable splash screen"
2 LICENSE = "GPLv2"
3 PV = "1.0+git${SRCPV}"
4 SRCREV = "ff34b85bfed5401910b2bc28a150a347f26ce97f"
5
6
7 LIC_FILES_CHKSUM = "file://COPYING;md5=39bba7d2cf0ba1036f2a6e2be52fe3f0"
8
9 SRC_URI = "git://git@gitlab.kernelconcepts.de:2224/danb/dotsplash.git;protocol=ssh \
10           file://dotsplash-default \
11           file://dotsplash-init \
12           file://splashfuncs"
13
14 inherit pkgconfig update-rc.d meson
15
16 DOTSPLASH_THEME ?= "kc-800"
17 DOTSPLASH_THEME_lamobo-r1 ?= "kc-fullhd"
18 DOTSPLASH_THEME_topasa900 ?= "kc-320"
19
20 DOTSPLASH_PARAMS ?= "-s 15 --theme ${DOTSPLASH_THEME}"
21
22 S = "${WORKDIR}/git"
23
24 FILES_${PN} += "/mnt/.psplash/"
25
26 do_install_append() {
27     install -d ${D}/mnt/.psplash/
28     install -d ${D}${sysconfdir}/init.d/
29     install -m 0755 ${WORKDIR}/dotsplash-init ${D}${sysconfdir}/init.d/dotsplash.sh
30     install -d ${D}${sysconfdir}/default/
31     sed -i 's/@PARAMS@/${DOTSPLASH_PARAMS}/g' ${WORKDIR}/dotsplash-default
32     install -m 0644 ${WORKDIR}/dotsplash-default ${D}${sysconfdir}/default/dotsplash
33     install -m 0755 ${WORKDIR}/splashfuncs ${D}${sysconfdir}/default/splashfuncs
34     cd ${D}/${bindir}
35     ln -s dotsplash-write psplash-write
36 }
37
38 INITSCRIPT_NAME = "dotsplash.sh"
39 INITSCRIPT_PARAMS = "start 0 S . stop 20 0 1 6 ."
40
41 RRECOMMENDS_${PN} = "${PN}-theme-mucross"
42
43 python populate_packages_prepend () {
44     themedir = d.expand('${datadir}/dotsplash/themes')
45     do_split_packages(d, themedir, '^(.*)$',
46                      'dotsplash-theme-%s', './dotsplash theme %s',
47                       extra_depends='', allow_dirs=True, prepend=True)
48 }
49
50 PACKAGES_DYNAMIC += "^dotsplash-theme-.*"