fix machine definition substitution
[meta-kc-bsp.git] / recipes-kernel / linux / linux-karo_4.9.11.bb
1 # Copyright (C) 2013-2016 Freescale Semiconductor
2 # Copyright 2017 NXP
3 # Copyright 2018 kernel concepts GmbH
4 # Released under the MIT license (see COPYING.MIT for the terms)
5
6 SUMMARY = "Linux Kernel provided and supported by NXP"
7 DESCRIPTION = "Linux Kernel provided and supported by NXP with focus on \
8 i.MX Family Reference Boards. It includes support for many IPs such as GPU, VPU and IPU."
9
10 require recipes-kernel/linux/linux-imx.inc
11
12 SRC_URI = "git://source.codeaurora.org/external/imx/linux-imx;protocol=https;branch=${SRCBRANCH} \
13            file://set-enet_ref_clk-to-50-mhz.patch \
14            file://edt-ft5x06-make-distinction-between.patch \
15            file://edt-ft5x06-fixes.patch \
16            file://add-support-for-edt-m12-touch.patch \
17            file://ethernet-update-driver.patch \
18            file://defconfig \
19 "
20
21 DEPENDS += "lzop-native bc-native"
22
23 SRCBRANCH = "imx_4.9.11_1.0.0_ga"
24 LOCALVERSION = "-1.0.0"
25 SRCREV = "c27010d99a3d91703ea2d1a3f9630a9dedc3f86f"
26
27 KERNEL_EXTRA_ARGS += "LOADADDR=${UBOOT_ENTRYPOINT}"
28
29 COMPATIBLE_MACHINE  = "(tx6[qus]-.*)"
30
31 FILESEXTRAPATHS_prepend = "${THISDIR}/${P}/txbase/${TXBASE}:"
32
33 KERNEL_IMAGETYPE = "uImage"
34
35 # Add NXP binary blob driver for the Vivante GPU to the kernel image.
36 # Otherwise settings in the Kernel defconfig are actively delete or ignored and
37 # the required external LKM ([RFS]/lib/modules/<kernel-version>/extra) is not
38 # available at all ( exception being if specific images are being "bitbaked"
39 # like: fsl-image-multimedia-full )
40
41 # Add Vivante GPU driver support
42 # Handle Vivante kernel driver setting:
43 #   0 - machine does not have Vivante GPU driver support
44 #   1 - machine has Vivante GPU driver support
45 MACHINE_HAS_VIVANTE_KERNEL_DRIVER_SUPPORT ?= "1"
46
47 # Use Vivante kernel driver module:
48 #   0 - enable the builtin kernel driver module
49 #   1 - enable the external kernel module
50 MACHINE_USES_VIVANTE_KERNEL_DRIVER_MODULE ?= "0"
51
52 # Add TX6 module specific DT file(s)
53 SRC_URI += "file://imx6qdl-tx6.dtsi;subdir=git/arch/arm/boot/dts \
54             file://imx6qdl-tx6-gpio.h;subdir=git/include/dt-bindings/gpio \
55            "
56
57 # Add baseboard dtsi file(s)
58 SRC_URI += "file://txbase-${TXBASE}.dtsi;subdir=git/arch/arm/boot/dts"
59
60 # Add TX6 (machine) specific DTS file(s)
61 SRC_URI += "file://${TXTYPE}-${TXNVM}-${TXBASE}.dts;subdir=git/arch/arm/boot/dts"
62
63 KERNEL_DEVICETREE = "${TXTYPE}-${TXNVM}-${TXBASE}.dtb"