arch/arm/cpu/arm1136/u-boot-spl.lds

   1 /*
   2  * (C) Copyright 2002
   3  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   4  *
   5  * (C) Copyright 2010
   6  * Texas Instruments, <www.ti.com>
   7  *      Aneesh V <aneesh@ti.com>
   8  *
   9  * SPDX-License-Identifier:     GPL-2.0+
  10  */
  11
  12 MEMORY { .sram : ORIGIN = CONFIG_SPL_TEXT_BASE,\
  13                 LENGTH = CONFIG_SPL_MAX_SIZE }
  14 MEMORY { .sdram : ORIGIN = CONFIG_SPL_BSS_START_ADDR, \
  15                 LENGTH = CONFIG_SPL_BSS_MAX_SIZE }
  16
  17 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  18 OUTPUT_ARCH(arm)
  19 ENTRY(_start)
  20 SECTIONS
  21 {
  22         .text      :
  23         {
  24         __start = .;
  25           arch/arm/cpu/arm1136/start.o  (.text*)
  26           *(.text*)
  27         } >.sram
  28
  29         . = ALIGN(4);
  30         .rodata : { *(SORT_BY_ALIGNMENT(.rodata*)) } >.sram
  31
  32         . = ALIGN(4);
  33         .data : { *(SORT_BY_ALIGNMENT(.data*)) } >.sram
  34         . = ALIGN(4);
  35         __image_copy_end = .;
  36         _end = .;
  37
  38         .bss :
  39         {
  40                 . = ALIGN(4);
  41                 __bss_start = .;
  42                 *(.bss*)
  43                 . = ALIGN(4);
  44                 __bss_end = .;
  45         } >.sdram
  46 }