arch/arm/cpu/arm920t/ep93xx/u-boot.lds

   1 /*
   2  * (C) Copyright 2002
   3  * Gary Jennejohn, DENX Software Engineering, <gj@denx.de>
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
   9 OUTPUT_ARCH(arm)
  10 ENTRY(_start)
  11 SECTIONS
  12 {
  13         . = 0x00000000;
  14
  15         . = ALIGN(4);
  16         .text      :
  17         {
  18                 *(.__image_copy_start)
  19           arch/arm/cpu/arm920t/start.o  (.text*)
  20                 /* the EP93xx expects to find the pattern 'CRUS' at 0x1000 */
  21           . = 0x1000;
  22           LONG(0x53555243)
  23           *(.text*)
  24         }
  25
  26         . = ALIGN(4);
  27         .rodata : { *(.rodata*) }
  28
  29         . = ALIGN(4);
  30         .data : { *(.data*) }
  31
  32         . = ALIGN(4);
  33         .got : { *(.got) }
  34
  35         . = .;
  36
  37         . = ALIGN(4);
  38         .u_boot_list : {
  39                 KEEP(*(SORT(.u_boot_list*)));
  40         }
  41
  42         . = ALIGN(4);
  43
  44         .image_copy_end :
  45         {
  46                 *(.__image_copy_end)
  47         }
  48
  49         __bss_start = .;
  50         .bss : { *(.bss*) }
  51         __bss_end = .;
  52
  53         _end = .;
  54 }