arch/arm/cpu/arm926ejs/start.S

   1 /*
   2  *  armboot - Startup Code for ARM926EJS CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
  13  *  Copyright (c) 2010  Albert Aribaud <albert.u.boot@aribaud.net>
  14  *
  15  * SPDX-License-Identifier:     GPL-2.0+
  16  */
  17
  18 #include <asm-offsets.h>
  19 #include <config.h>
  20 #include <common.h>
  21 #include <version.h>
  22
  23 /*
  24  *************************************************************************
  25  *
  26  * Jump vector table as in table 3.1 in [1]
  27  *
  28  *************************************************************************
  29  */
  30
  31
  32 #ifdef CONFIG_SYS_DV_NOR_BOOT_CFG
  33 .globl _start
  34 _start:
  35 .globl _NOR_BOOT_CFG
  36 _NOR_BOOT_CFG:
  37         .word   CONFIG_SYS_DV_NOR_BOOT_CFG
  38         b       reset
  39 #else
  40 .globl _start
  41 _start:
  42         b       reset
  43 #endif
  44 #ifdef CONFIG_SPL_BUILD
  45 /* No exception handlers in preloader */
  46         ldr     pc, _hang
  47         ldr     pc, _hang
  48         ldr     pc, _hang
  49         ldr     pc, _hang
  50         ldr     pc, _hang
  51         ldr     pc, _hang
  52         ldr     pc, _hang
  53
  54 _hang:
  55         .word   do_hang
  56 /* pad to 64 byte boundary */
  57         .word   0x12345678
  58         .word   0x12345678
  59         .word   0x12345678
  60         .word   0x12345678
  61         .word   0x12345678
  62         .word   0x12345678
  63         .word   0x12345678
  64 #else
  65         ldr     pc, _undefined_instruction
  66         ldr     pc, _software_interrupt
  67         ldr     pc, _prefetch_abort
  68         ldr     pc, _data_abort
  69         ldr     pc, _not_used
  70         ldr     pc, _irq
  71         ldr     pc, _fiq
  72
  73 _undefined_instruction:
  74         .word undefined_instruction
  75 _software_interrupt:
  76         .word software_interrupt
  77 _prefetch_abort:
  78         .word prefetch_abort
  79 _data_abort:
  80         .word data_abort
  81 _not_used:
  82         .word not_used
  83 _irq:
  84         .word irq
  85 _fiq:
  86         .word fiq
  87
  88 #endif  /* CONFIG_SPL_BUILD */
  89         .balignl 16,0xdeadbeef
  90
  91
  92 /*
  93  *************************************************************************
  94  *
  95  * Startup Code (reset vector)
  96  *
  97  * do important init only if we don't start from memory!
  98  * setup Memory and board specific bits prior to relocation.
  99  * relocate armboot to ram
 100  * setup stack
 101  *
 102  *************************************************************************
 103  */
 104
 105 .globl _TEXT_BASE
 106 _TEXT_BASE:
 107 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_TEXT_BASE)
 108         .word   CONFIG_SPL_TEXT_BASE
 109 #else
 110         .word   CONFIG_SYS_TEXT_BASE
 111 #endif
 112
 113 /*
 114  * These are defined in the board-specific linker script.
 115  * Subtracting _start from them lets the linker put their
 116  * relative position in the executable instead of leaving
 117  * them null.
 118  */
 119 .globl _bss_start_ofs
 120 _bss_start_ofs:
 121         .word __bss_start - _start
 122
 123 .globl _bss_end_ofs
 124 _bss_end_ofs:
 125         .word __bss_end - _start
 126
 127 .globl _end_ofs
 128 _end_ofs:
 129         .word _end - _start
 130
 131 #ifdef CONFIG_USE_IRQ
 132 /* IRQ stack memory (calculated at run-time) */
 133 .globl IRQ_STACK_START
 134 IRQ_STACK_START:
 135         .word   0x0badc0de
 136
 137 /* IRQ stack memory (calculated at run-time) */
 138 .globl FIQ_STACK_START
 139 FIQ_STACK_START:
 140         .word 0x0badc0de
 141 #endif
 142
 143 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 144 .globl IRQ_STACK_START_IN
 145 IRQ_STACK_START_IN:
 146 #ifdef IRAM_BASE_ADDR
 147         .word   IRAM_BASE_ADDR + 0x20
 148 #else
 149         .word   0x0badc0de
 150 #endif
 151
 152 /*
 153  * the actual reset code
 154  */
 155
 156 reset:
 157         /*
 158          * set the cpu to SVC32 mode
 159          */
 160         mrs     r0,cpsr
 161         bic     r0,r0,#0x1f
 162         orr     r0,r0,#0xd3
 163         msr     cpsr,r0
 164
 165         /*
 166          * we do sys-critical inits only at reboot,
 167          * not when booting from ram!
 168          */
 169 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 170         bl      cpu_init_crit
 171 #endif
 172
 173         bl      _main
 174
 175 /*------------------------------------------------------------------------------*/
 176
 177         .globl  c_runtime_cpu_setup
 178 c_runtime_cpu_setup:
 179
 180         bx      lr
 181
 182 /*
 183  *************************************************************************
 184  *
 185  * CPU_init_critical registers
 186  *
 187  * setup important registers
 188  * setup memory timing
 189  *
 190  *************************************************************************
 191  */
 192 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 193 cpu_init_crit:
 194         /*
 195          * flush D cache before disabling it
 196          */
 197         mov     r0, #0
 198 flush_dcache:
 199         mrc     p15, 0, r15, c7, c10, 3
 200         bne     flush_dcache
 201
 202         mcr     p15, 0, r0, c8, c7, 0   /* invalidate TLB */
 203         mcr     p15, 0, r0, c7, c5, 0   /* invalidate I Cache */
 204
 205         /*
 206          * disable MMU and D cache
 207          * enable I cache if CONFIG_SYS_ICACHE_OFF is not defined
 208          */
 209         mrc     p15, 0, r0, c1, c0, 0
 210         bic     r0, r0, #0x00000300     /* clear bits 9:8 (---- --RS) */
 211         bic     r0, r0, #0x00000087     /* clear bits 7, 2:0 (B--- -CAM) */
 212 #ifdef CONFIG_SYS_EXCEPTION_VECTORS_HIGH
 213         orr     r0, r0, #0x00002000     /* set bit 13 (--V- ----) */
 214 #else
 215         bic     r0, r0, #0x00002000     /* clear bit 13 (--V- ----) */
 216 #endif
 217         orr     r0, r0, #0x00000002     /* set bit 2 (A) Align */
 218 #ifndef CONFIG_SYS_ICACHE_OFF
 219         orr     r0, r0, #0x00001000     /* set bit 12 (I) I-Cache */
 220 #endif
 221         mcr     p15, 0, r0, c1, c0, 0
 222
 223         /*
 224          * Go setup Memory and board specific bits prior to relocation.
 225          */
 226         mov     ip, lr          /* perserve link reg across call */
 227         bl      lowlevel_init   /* go setup pll,mux,memory */
 228         mov     lr, ip          /* restore link */
 229         mov     pc, lr          /* back to my caller */
 230 #endif /* CONFIG_SKIP_LOWLEVEL_INIT */
 231
 232 #ifndef CONFIG_SPL_BUILD
 233 /*
 234  *************************************************************************
 235  *
 236  * Interrupt handling
 237  *
 238  *************************************************************************
 239  */
 240
 241 @
 242 @ IRQ stack frame.
 243 @
 244 #define S_FRAME_SIZE    72
 245
 246 #define S_OLD_R0        68
 247 #define S_PSR           64
 248 #define S_PC            60
 249 #define S_LR            56
 250 #define S_SP            52
 251
 252 #define S_IP            48
 253 #define S_FP            44
 254 #define S_R10           40
 255 #define S_R9            36
 256 #define S_R8            32
 257 #define S_R7            28
 258 #define S_R6            24
 259 #define S_R5            20
 260 #define S_R4            16
 261 #define S_R3            12
 262 #define S_R2            8
 263 #define S_R1            4
 264 #define S_R0            0
 265
 266 #define MODE_SVC 0x13
 267 #define I_BIT    0x80
 268
 269 /*
 270  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 271  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 272  */
 273
 274         .macro  bad_save_user_regs
 275         @ carve out a frame on current user stack
 276         sub     sp, sp, #S_FRAME_SIZE
 277         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
 278         ldr     r2, IRQ_STACK_START_IN
 279         @ get values for "aborted" pc and cpsr (into parm regs)
 280         ldmia   r2, {r2 - r3}
 281         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 282         add     r5, sp, #S_SP
 283         mov     r1, lr
 284         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
 285         mov     r0, sp          @ save current stack into r0 (param register)
 286         .endm
 287
 288         .macro  irq_save_user_regs
 289         sub     sp, sp, #S_FRAME_SIZE
 290         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 291         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 292         add     r8, sp, #S_PC
 293         stmdb   r8, {sp, lr}^           @ Calling SP, LR
 294         str     lr, [r8, #0]            @ Save calling PC
 295         mrs     r6, spsr
 296         str     r6, [r8, #4]            @ Save CPSR
 297         str     r0, [r8, #8]            @ Save OLD_R0
 298         mov     r0, sp
 299         .endm
 300
 301         .macro  irq_restore_user_regs
 302         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 303         mov     r0, r0
 304         ldr     lr, [sp, #S_PC]                 @ Get PC
 305         add     sp, sp, #S_FRAME_SIZE
 306         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
 307         .endm
 308
 309         .macro get_bad_stack
 310         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 311
 312         str     lr, [r13]       @ save caller lr in position 0 of saved stack
 313         mrs     lr, spsr        @ get the spsr
 314         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
 315         mov     r13, #MODE_SVC  @ prepare SVC-Mode
 316         @ msr   spsr_c, r13
 317         msr     spsr, r13       @ switch modes, make sure moves will execute
 318         mov     lr, pc          @ capture return pc
 319         movs    pc, lr          @ jump to next instruction & switch modes.
 320         .endm
 321
 322         .macro get_bad_stack_swi
 323         @ space on current stack for scratch reg.
 324         sub     r13, r13, #4
 325         str     r0, [r13]
 326         ldr     r0, IRQ_STACK_START_IN  @ get our mode stack
 327         str     lr, [r0]        @ save caller lr in position 0 of saved stack
 328         mrs     lr, spsr        @ get the spsr
 329         str     lr, [r0, #4]    @ save spsr in position 1 of saved stack
 330         ldr     lr, [r0]        @ restore lr
 331         ldr     r0, [r13]       @ restore r0
 332         add     r13, r13, #4    @ pop stack entry
 333         .endm
 334
 335         .macro get_irq_stack                    @ setup IRQ stack
 336         ldr     sp, IRQ_STACK_START
 337         .endm
 338
 339         .macro get_fiq_stack                    @ setup FIQ stack
 340         ldr     sp, FIQ_STACK_START
 341         .endm
 342 #endif  /* CONFIG_SPL_BUILD */
 343
 344 /*
 345  * exception handlers
 346  */
 347 #ifdef CONFIG_SPL_BUILD
 348         .align  5
 349 do_hang:
 350         ldr     sp, _TEXT_BASE                  /* switch to abort stack */
 351 1:
 352         bl      1b                              /* hang and never return */
 353 #else   /* !CONFIG_SPL_BUILD */
 354         .align  5
 355 undefined_instruction:
 356         get_bad_stack
 357         bad_save_user_regs
 358         bl      do_undefined_instruction
 359
 360         .align  5
 361 software_interrupt:
 362         get_bad_stack_swi
 363         bad_save_user_regs
 364         bl      do_software_interrupt
 365
 366         .align  5
 367 prefetch_abort:
 368         get_bad_stack
 369         bad_save_user_regs
 370         bl      do_prefetch_abort
 371
 372         .align  5
 373 data_abort:
 374         get_bad_stack
 375         bad_save_user_regs
 376         bl      do_data_abort
 377
 378         .align  5
 379 not_used:
 380         get_bad_stack
 381         bad_save_user_regs
 382         bl      do_not_used
 383
 384 #ifdef CONFIG_USE_IRQ
 385
 386         .align  5
 387 irq:
 388         get_irq_stack
 389         irq_save_user_regs
 390         bl      do_irq
 391         irq_restore_user_regs
 392
 393         .align  5
 394 fiq:
 395         get_fiq_stack
 396         /* someone ought to write a more effiction fiq_save_user_regs */
 397         irq_save_user_regs
 398         bl      do_fiq
 399         irq_restore_user_regs
 400
 401 #else
 402
 403         .align  5
 404 irq:
 405         get_bad_stack
 406         bad_save_user_regs
 407         bl      do_irq
 408
 409         .align  5
 410 fiq:
 411         get_bad_stack
 412         bad_save_user_regs
 413         bl      do_fiq
 414
 415 #endif
 416 #endif  /* CONFIG_SPL_BUILD */