arch/arm/cpu/arm946es/start.S

   1 /*
   2  *  armboot - Startup Code for ARM926EJS CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
  13  *  Copyright (c) 2010  Albert Aribaud <albert.aribaud@free.fr>
  14  *
  15  * See file CREDITS for list of people who contributed to this
  16  * project.
  17  *
  18  * This program is free software; you can redistribute it and/or
  19  * modify it under the terms of the GNU General Public License as
  20  * published by the Free Software Foundation; either version 2 of
  21  * the License, or (at your option) any later version.
  22  *
  23  * This program is distributed in the hope that it will be useful,
  24  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  25  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  26  * GNU General Public License for more details.
  27  *
  28  * You should have received a copy of the GNU General Public License
  29  * along with this program; if not, write to the Free Software
  30  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  31  * MA 02111-1307 USA
  32  */
  33
  34 #include <asm-offsets.h>
  35 #include <config.h>
  36 #include <version.h>
  37
  38 /*
  39  *************************************************************************
  40  *
  41  * Jump vector table as in table 3.1 in [1]
  42  *
  43  *************************************************************************
  44  */
  45
  46
  47 .globl _start
  48 _start:
  49         b       reset
  50         ldr     pc, _undefined_instruction
  51         ldr     pc, _software_interrupt
  52         ldr     pc, _prefetch_abort
  53         ldr     pc, _data_abort
  54         ldr     pc, _not_used
  55         ldr     pc, _irq
  56         ldr     pc, _fiq
  57
  58 _undefined_instruction:
  59         .word undefined_instruction
  60 _software_interrupt:
  61         .word software_interrupt
  62 _prefetch_abort:
  63         .word prefetch_abort
  64 _data_abort:
  65         .word data_abort
  66 _not_used:
  67         .word not_used
  68 _irq:
  69         .word irq
  70 _fiq:
  71         .word fiq
  72
  73         .balignl 16,0xdeadbeef
  74
  75 _vectors_end:
  76
  77 /*
  78  *************************************************************************
  79  *
  80  * Startup Code (reset vector)
  81  *
  82  * do important init only if we don't start from memory!
  83  * setup Memory and board specific bits prior to relocation.
  84  * relocate armboot to ram
  85  * setup stack
  86  *
  87  *************************************************************************
  88  */
  89
  90 .globl _TEXT_BASE
  91 _TEXT_BASE:
  92         .word   CONFIG_SYS_TEXT_BASE
  93
  94 /*
  95  * These are defined in the board-specific linker script.
  96  * Subtracting _start from them lets the linker put their
  97  * relative position in the executable instead of leaving
  98  * them null.
  99  */
 100 .globl _bss_start_ofs
 101 _bss_start_ofs:
 102         .word __bss_start - _start
 103
 104 .globl _bss_end_ofs
 105 _bss_end_ofs:
 106         .word _end - _start
 107
 108 #ifdef CONFIG_USE_IRQ
 109 /* IRQ stack memory (calculated at run-time) */
 110 .globl IRQ_STACK_START
 111 IRQ_STACK_START:
 112         .word   0x0badc0de
 113
 114 /* IRQ stack memory (calculated at run-time) */
 115 .globl FIQ_STACK_START
 116 FIQ_STACK_START:
 117         .word 0x0badc0de
 118 #endif
 119
 120 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 121 .globl IRQ_STACK_START_IN
 122 IRQ_STACK_START_IN:
 123         .word   0x0badc0de
 124
 125 /*
 126  * the actual reset code
 127  */
 128
 129 reset:
 130         /*
 131          * set the cpu to SVC32 mode
 132          */
 133         mrs     r0,cpsr
 134         bic     r0,r0,#0x1f
 135         orr     r0,r0,#0xd3
 136         msr     cpsr,r0
 137
 138         /*
 139          * we do sys-critical inits only at reboot,
 140          * not when booting from ram!
 141          */
 142 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 143         bl      cpu_init_crit
 144 #endif
 145
 146 /* Set stackpointer in internal RAM to call board_init_f */
 147 call_board_init_f:
 148         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 149         ldr     r0,=0x00000000
 150         bl      board_init_f
 151
 152 /*------------------------------------------------------------------------------*/
 153
 154 /*
 155  * void relocate_code (addr_sp, gd, addr_moni)
 156  *
 157  * This "function" does not return, instead it continues in RAM
 158  * after relocating the monitor code.
 159  *
 160  */
 161         .globl  relocate_code
 162 relocate_code:
 163         mov     r4, r0  /* save addr_sp */
 164         mov     r5, r1  /* save addr of gd */
 165         mov     r6, r2  /* save addr of destination */
 166         mov     r7, r2  /* save addr of destination */
 167
 168         /* Set up the stack                                                 */
 169 stack_setup:
 170         mov     sp, r4
 171
 172         adr     r0, _start
 173         ldr     r2, _TEXT_BASE
 174         ldr     r3, _bss_start_ofs
 175         add     r2, r0, r3              /* r2 <- source end address         */
 176         cmp     r0, r6
 177         beq     clear_bss
 178
 179 copy_loop:
 180         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 181         stmia   r6!, {r9-r10}           /* copy to   target address [r1]    */
 182         cmp     r0, r2                  /* until source end address [r2]    */
 183         blo     copy_loop
 184
 185 #ifndef CONFIG_PRELOADER
 186         /*
 187          * fix .rel.dyn relocations
 188          */
 189         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 190         sub     r9, r7, r0              /* r9 <- relocation offset */
 191         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 192         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 193         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 194         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 195         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 196         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 197 fixloop:
 198         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 199         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 200         ldr     r1, [r2, #4]
 201         and     r8, r1, #0xff
 202         cmp     r8, #23                 /* relative fixup? */
 203         beq     fixrel
 204         cmp     r8, #2                  /* absolute fixup? */
 205         beq     fixabs
 206         /* ignore unknown type of fixup */
 207         b       fixnext
 208 fixabs:
 209         /* absolute fix: set location to (offset) symbol value */
 210         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 211         add     r1, r10, r1             /* r1 <- address of symbol in table */
 212         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 213         add     r1, r9                  /* r1 <- relocated sym addr */
 214         b       fixnext
 215 fixrel:
 216         /* relative fix: increase location by offset */
 217         ldr     r1, [r0]
 218         add     r1, r1, r9
 219 fixnext:
 220         str     r1, [r0]
 221         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 222         cmp     r2, r3
 223         blo     fixloop
 224 #endif
 225
 226 clear_bss:
 227 #ifndef CONFIG_PRELOADER
 228         ldr     r0, _bss_start_ofs
 229         ldr     r1, _bss_end_ofs
 230         ldr     r3, _TEXT_BASE          /* Text base */
 231         mov     r4, r7                  /* reloc addr */
 232         add     r0, r0, r4
 233         add     r1, r1, r4
 234         mov     r2, #0x00000000         /* clear                            */
 235
 236 clbss_l:str     r2, [r0]                /* clear loop...                    */
 237         add     r0, r0, #4
 238         cmp     r0, r1
 239         blo     clbss_l
 240 #endif
 241
 242 /*
 243  * We are done. Do not return, instead branch to second part of board
 244  * initialization, now running from RAM.
 245  */
 246 #ifdef CONFIG_NAND_SPL
 247         ldr     pc, _nand_boot
 248
 249 _nand_boot: .word nand_boot
 250 #else
 251         ldr     r0, _board_init_r_ofs
 252         adr     r1, _start
 253         add     lr, r0, r1
 254         add     lr, lr, r9
 255         /* setup parameters for board_init_r */
 256         mov     r0, r5          /* gd_t */
 257         mov     r1, r7          /* dest_addr */
 258         /* jump to it ... */
 259         mov     pc, lr
 260
 261 _board_init_r_ofs:
 262         .word board_init_r - _start
 263 #endif
 264
 265 _rel_dyn_start_ofs:
 266         .word __rel_dyn_start - _start
 267 _rel_dyn_end_ofs:
 268         .word __rel_dyn_end - _start
 269 _dynsym_start_ofs:
 270         .word __dynsym_start - _start
 271
 272 /*
 273  *************************************************************************
 274  *
 275  * CPU_init_critical registers
 276  *
 277  * setup important registers
 278  * setup memory timing
 279  *
 280  *************************************************************************
 281  */
 282
 283
 284 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 285 cpu_init_crit:
 286         /*
 287          * flush v4 I/D caches
 288          */
 289         mov     r0, #0
 290         mcr     p15, 0, r0, c7, c5, 0   /* flush v4 I-cache */
 291         mcr     p15, 0, r0, c7, c6, 0   /* flush v4 D-cache */
 292
 293         /*
 294          * disable MMU stuff and caches
 295          */
 296         mrc     p15, 0, r0, c1, c0, 0
 297         bic     r0, r0, #0x00002300     /* clear bits 13, 9:8 (--V- --RS) */
 298         bic     r0, r0, #0x00000087     /* clear bits 7, 2:0 (B--- -CAM) */
 299         orr     r0, r0, #0x00000002     /* set bit 2 (A) Align */
 300         orr     r0, r0, #0x00001000     /* set bit 12 (I) I-Cache */
 301         mcr     p15, 0, r0, c1, c0, 0
 302
 303         /*
 304          * Go setup Memory and board specific bits prior to relocation.
 305          */
 306         mov     ip, lr          /* perserve link reg across call */
 307         bl      lowlevel_init   /* go setup memory */
 308         mov     lr, ip          /* restore link */
 309         mov     pc, lr          /* back to my caller */
 310 #endif
 311 /*
 312  *************************************************************************
 313  *
 314  * Interrupt handling
 315  *
 316  *************************************************************************
 317  */
 318
 319 @
 320 @ IRQ stack frame.
 321 @
 322 #define S_FRAME_SIZE    72
 323
 324 #define S_OLD_R0        68
 325 #define S_PSR           64
 326 #define S_PC            60
 327 #define S_LR            56
 328 #define S_SP            52
 329
 330 #define S_IP            48
 331 #define S_FP            44
 332 #define S_R10           40
 333 #define S_R9            36
 334 #define S_R8            32
 335 #define S_R7            28
 336 #define S_R6            24
 337 #define S_R5            20
 338 #define S_R4            16
 339 #define S_R3            12
 340 #define S_R2            8
 341 #define S_R1            4
 342 #define S_R0            0
 343
 344 #define MODE_SVC 0x13
 345 #define I_BIT    0x80
 346
 347 /*
 348  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 349  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 350  */
 351
 352         .macro  bad_save_user_regs
 353         @ carve out a frame on current user stack
 354         sub     sp, sp, #S_FRAME_SIZE
 355         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
 356
 357         ldr     r2, IRQ_STACK_START_IN
 358         @ get values for "aborted" pc and cpsr (into parm regs)
 359         ldmia   r2, {r2 - r3}
 360         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 361         add     r5, sp, #S_SP
 362         mov     r1, lr
 363         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
 364         mov     r0, sp          @ save current stack into r0 (param register)
 365         .endm
 366
 367         .macro  irq_save_user_regs
 368         sub     sp, sp, #S_FRAME_SIZE
 369         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 370         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 371         add     r8, sp, #S_PC
 372         stmdb   r8, {sp, lr}^           @ Calling SP, LR
 373         str     lr, [r8, #0]            @ Save calling PC
 374         mrs     r6, spsr
 375         str     r6, [r8, #4]            @ Save CPSR
 376         str     r0, [r8, #8]            @ Save OLD_R0
 377         mov     r0, sp
 378         .endm
 379
 380         .macro  irq_restore_user_regs
 381         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 382         mov     r0, r0
 383         ldr     lr, [sp, #S_PC]                 @ Get PC
 384         add     sp, sp, #S_FRAME_SIZE
 385         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
 386         .endm
 387
 388         .macro get_bad_stack
 389         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 390
 391         str     lr, [r13]       @ save caller lr in position 0 of saved stack
 392         mrs     lr, spsr        @ get the spsr
 393         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
 394         mov     r13, #MODE_SVC  @ prepare SVC-Mode
 395         @ msr   spsr_c, r13
 396         msr     spsr, r13       @ switch modes, make sure moves will execute
 397         mov     lr, pc          @ capture return pc
 398         movs    pc, lr          @ jump to next instruction & switch modes.
 399         .endm
 400
 401         .macro get_irq_stack                    @ setup IRQ stack
 402         ldr     sp, IRQ_STACK_START
 403         .endm
 404
 405         .macro get_fiq_stack                    @ setup FIQ stack
 406         ldr     sp, FIQ_STACK_START
 407         .endm
 408
 409 /*
 410  * exception handlers
 411  */
 412         .align  5
 413 undefined_instruction:
 414         get_bad_stack
 415         bad_save_user_regs
 416         bl      do_undefined_instruction
 417
 418         .align  5
 419 software_interrupt:
 420         get_bad_stack
 421         bad_save_user_regs
 422         bl      do_software_interrupt
 423
 424         .align  5
 425 prefetch_abort:
 426         get_bad_stack
 427         bad_save_user_regs
 428         bl      do_prefetch_abort
 429
 430         .align  5
 431 data_abort:
 432         get_bad_stack
 433         bad_save_user_regs
 434         bl      do_data_abort
 435
 436         .align  5
 437 not_used:
 438         get_bad_stack
 439         bad_save_user_regs
 440         bl      do_not_used
 441
 442 #ifdef CONFIG_USE_IRQ
 443
 444         .align  5
 445 irq:
 446         get_irq_stack
 447         irq_save_user_regs
 448         bl      do_irq
 449         irq_restore_user_regs
 450
 451         .align  5
 452 fiq:
 453         get_fiq_stack
 454         /* someone ought to write a more effiction fiq_save_user_regs */
 455         irq_save_user_regs
 456         bl      do_fiq
 457         irq_restore_user_regs
 458
 459 #else
 460
 461         .align  5
 462 irq:
 463         get_bad_stack
 464         bad_save_user_regs
 465         bl      do_irq
 466
 467         .align  5
 468 fiq:
 469         get_bad_stack
 470         bad_save_user_regs
 471         bl      do_fiq
 472
 473 #endif
 474
 475 # ifdef CONFIG_INTEGRATOR
 476
 477         /* Satisfied by general board level routine */
 478
 479 #else
 480
 481         .align  5
 482 .globl reset_cpu
 483 reset_cpu:
 484
 485         ldr     r1, rstctl1     /* get clkm1 reset ctl */
 486         mov     r3, #0x0
 487         strh    r3, [r1]        /* clear it */
 488         mov     r3, #0x8
 489         strh    r3, [r1]        /* force dsp+arm reset */
 490 _loop_forever:
 491         b       _loop_forever
 492
 493 rstctl1:
 494         .word   0xfffece10
 495
 496 #endif  /* #ifdef CONFIG_INTEGRATOR */