arch/arm/cpu/arm946es/start.S

   1 /*
   2  *  armboot - Startup Code for ARM926EJS CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
  13  *  Copyright (c) 2010  Albert Aribaud <albert.u.boot@aribaud.net>
  14  *
  15  * See file CREDITS for list of people who contributed to this
  16  * project.
  17  *
  18  * This program is free software; you can redistribute it and/or
  19  * modify it under the terms of the GNU General Public License as
  20  * published by the Free Software Foundation; either version 2 of
  21  * the License, or (at your option) any later version.
  22  *
  23  * This program is distributed in the hope that it will be useful,
  24  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  25  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  26  * GNU General Public License for more details.
  27  *
  28  * You should have received a copy of the GNU General Public License
  29  * along with this program; if not, write to the Free Software
  30  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  31  * MA 02111-1307 USA
  32  */
  33
  34 #include <asm-offsets.h>
  35 #include <config.h>
  36 #include <version.h>
  37
  38 /*
  39  *************************************************************************
  40  *
  41  * Jump vector table as in table 3.1 in [1]
  42  *
  43  *************************************************************************
  44  */
  45
  46
  47 .globl _start
  48 _start:
  49         b       reset
  50         ldr     pc, _undefined_instruction
  51         ldr     pc, _software_interrupt
  52         ldr     pc, _prefetch_abort
  53         ldr     pc, _data_abort
  54         ldr     pc, _not_used
  55         ldr     pc, _irq
  56         ldr     pc, _fiq
  57
  58 _undefined_instruction:
  59         .word undefined_instruction
  60 _software_interrupt:
  61         .word software_interrupt
  62 _prefetch_abort:
  63         .word prefetch_abort
  64 _data_abort:
  65         .word data_abort
  66 _not_used:
  67         .word not_used
  68 _irq:
  69         .word irq
  70 _fiq:
  71         .word fiq
  72
  73         .balignl 16,0xdeadbeef
  74
  75 _vectors_end:
  76
  77 /*
  78  *************************************************************************
  79  *
  80  * Startup Code (reset vector)
  81  *
  82  * do important init only if we don't start from memory!
  83  * setup Memory and board specific bits prior to relocation.
  84  * relocate armboot to ram
  85  * setup stack
  86  *
  87  *************************************************************************
  88  */
  89
  90 .globl _TEXT_BASE
  91 _TEXT_BASE:
  92         .word   CONFIG_SYS_TEXT_BASE
  93
  94 /*
  95  * These are defined in the board-specific linker script.
  96  * Subtracting _start from them lets the linker put their
  97  * relative position in the executable instead of leaving
  98  * them null.
  99  */
 100 .globl _bss_start_ofs
 101 _bss_start_ofs:
 102         .word __bss_start - _start
 103
 104 .globl _bss_end_ofs
 105 _bss_end_ofs:
 106         .word __bss_end__ - _start
 107
 108 .globl _end_ofs
 109 _end_ofs:
 110         .word _end - _start
 111
 112 #ifdef CONFIG_USE_IRQ
 113 /* IRQ stack memory (calculated at run-time) */
 114 .globl IRQ_STACK_START
 115 IRQ_STACK_START:
 116         .word   0x0badc0de
 117
 118 /* IRQ stack memory (calculated at run-time) */
 119 .globl FIQ_STACK_START
 120 FIQ_STACK_START:
 121         .word 0x0badc0de
 122 #endif
 123
 124 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 125 .globl IRQ_STACK_START_IN
 126 IRQ_STACK_START_IN:
 127         .word   0x0badc0de
 128
 129 /*
 130  * the actual reset code
 131  */
 132
 133 reset:
 134         /*
 135          * set the cpu to SVC32 mode
 136          */
 137         mrs     r0,cpsr
 138         bic     r0,r0,#0x1f
 139         orr     r0,r0,#0xd3
 140         msr     cpsr,r0
 141
 142         /*
 143          * we do sys-critical inits only at reboot,
 144          * not when booting from ram!
 145          */
 146 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 147         bl      cpu_init_crit
 148 #endif
 149
 150 /* Set stackpointer in internal RAM to call board_init_f */
 151 call_board_init_f:
 152         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 153         bic     sp, sp, #7 /* 8-byte alignment for ABI compliance */
 154         ldr     r0,=0x00000000
 155         bl      board_init_f
 156
 157 /*------------------------------------------------------------------------------*/
 158
 159 /*
 160  * void relocate_code (addr_sp, gd, addr_moni)
 161  *
 162  * This "function" does not return, instead it continues in RAM
 163  * after relocating the monitor code.
 164  *
 165  */
 166         .globl  relocate_code
 167 relocate_code:
 168         mov     r4, r0  /* save addr_sp */
 169         mov     r5, r1  /* save addr of gd */
 170         mov     r6, r2  /* save addr of destination */
 171
 172         /* Set up the stack                                                 */
 173 stack_setup:
 174         mov     sp, r4
 175
 176         adr     r0, _start
 177         cmp     r0, r6
 178         moveq   r9, #0          /* no relocation. relocation offset(r9) = 0 */
 179         beq     clear_bss               /* skip relocation */
 180         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 181         ldr     r3, _bss_start_ofs
 182         add     r2, r0, r3              /* r2 <- source end address         */
 183
 184 copy_loop:
 185         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 186         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
 187         cmp     r0, r2                  /* until source end address [r2]    */
 188         blo     copy_loop
 189
 190 #ifndef CONFIG_SPL_BUILD
 191         /*
 192          * fix .rel.dyn relocations
 193          */
 194         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 195         sub     r9, r6, r0              /* r9 <- relocation offset */
 196         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 197         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 198         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 199         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 200         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 201         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 202 fixloop:
 203         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 204         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 205         ldr     r1, [r2, #4]
 206         and     r7, r1, #0xff
 207         cmp     r7, #23                 /* relative fixup? */
 208         beq     fixrel
 209         cmp     r7, #2                  /* absolute fixup? */
 210         beq     fixabs
 211         /* ignore unknown type of fixup */
 212         b       fixnext
 213 fixabs:
 214         /* absolute fix: set location to (offset) symbol value */
 215         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 216         add     r1, r10, r1             /* r1 <- address of symbol in table */
 217         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 218         add     r1, r1, r9              /* r1 <- relocated sym addr */
 219         b       fixnext
 220 fixrel:
 221         /* relative fix: increase location by offset */
 222         ldr     r1, [r0]
 223         add     r1, r1, r9
 224 fixnext:
 225         str     r1, [r0]
 226         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 227         cmp     r2, r3
 228         blo     fixloop
 229 #endif
 230
 231 clear_bss:
 232 #ifndef CONFIG_SPL_BUILD
 233         ldr     r0, _bss_start_ofs
 234         ldr     r1, _bss_end_ofs
 235         mov     r4, r6                  /* reloc addr */
 236         add     r0, r0, r4
 237         add     r1, r1, r4
 238         mov     r2, #0x00000000         /* clear                            */
 239
 240 clbss_l:cmp     r0, r1                  /* clear loop... */
 241         bhs     clbss_e                 /* if reached end of bss, exit */
 242         str     r2, [r0]
 243         add     r0, r0, #4
 244         b       clbss_l
 245 clbss_e:
 246 #endif
 247
 248 /*
 249  * We are done. Do not return, instead branch to second part of board
 250  * initialization, now running from RAM.
 251  */
 252 #ifdef CONFIG_NAND_SPL
 253         ldr     pc, _nand_boot
 254
 255 _nand_boot: .word nand_boot
 256 #else
 257         ldr     r0, _board_init_r_ofs
 258         adr     r1, _start
 259         add     lr, r0, r1
 260         add     lr, lr, r9
 261         /* setup parameters for board_init_r */
 262         mov     r0, r5          /* gd_t */
 263         mov     r1, r6          /* dest_addr */
 264         /* jump to it ... */
 265         mov     pc, lr
 266
 267 _board_init_r_ofs:
 268         .word board_init_r - _start
 269 #endif
 270
 271 _rel_dyn_start_ofs:
 272         .word __rel_dyn_start - _start
 273 _rel_dyn_end_ofs:
 274         .word __rel_dyn_end - _start
 275 _dynsym_start_ofs:
 276         .word __dynsym_start - _start
 277
 278 /*
 279  *************************************************************************
 280  *
 281  * CPU_init_critical registers
 282  *
 283  * setup important registers
 284  * setup memory timing
 285  *
 286  *************************************************************************
 287  */
 288
 289
 290 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 291 cpu_init_crit:
 292         /*
 293          * flush v4 I/D caches
 294          */
 295         mov     r0, #0
 296         mcr     p15, 0, r0, c7, c5, 0   /* flush v4 I-cache */
 297         mcr     p15, 0, r0, c7, c6, 0   /* flush v4 D-cache */
 298
 299         /*
 300          * disable MMU stuff and caches
 301          */
 302         mrc     p15, 0, r0, c1, c0, 0
 303         bic     r0, r0, #0x00002300     /* clear bits 13, 9:8 (--V- --RS) */
 304         bic     r0, r0, #0x00000087     /* clear bits 7, 2:0 (B--- -CAM) */
 305         orr     r0, r0, #0x00000002     /* set bit 2 (A) Align */
 306         orr     r0, r0, #0x00001000     /* set bit 12 (I) I-Cache */
 307         mcr     p15, 0, r0, c1, c0, 0
 308
 309         /*
 310          * Go setup Memory and board specific bits prior to relocation.
 311          */
 312         mov     ip, lr          /* perserve link reg across call */
 313         bl      lowlevel_init   /* go setup memory */
 314         mov     lr, ip          /* restore link */
 315         mov     pc, lr          /* back to my caller */
 316 #endif
 317 /*
 318  *************************************************************************
 319  *
 320  * Interrupt handling
 321  *
 322  *************************************************************************
 323  */
 324
 325 @
 326 @ IRQ stack frame.
 327 @
 328 #define S_FRAME_SIZE    72
 329
 330 #define S_OLD_R0        68
 331 #define S_PSR           64
 332 #define S_PC            60
 333 #define S_LR            56
 334 #define S_SP            52
 335
 336 #define S_IP            48
 337 #define S_FP            44
 338 #define S_R10           40
 339 #define S_R9            36
 340 #define S_R8            32
 341 #define S_R7            28
 342 #define S_R6            24
 343 #define S_R5            20
 344 #define S_R4            16
 345 #define S_R3            12
 346 #define S_R2            8
 347 #define S_R1            4
 348 #define S_R0            0
 349
 350 #define MODE_SVC 0x13
 351 #define I_BIT    0x80
 352
 353 /*
 354  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 355  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 356  */
 357
 358         .macro  bad_save_user_regs
 359         @ carve out a frame on current user stack
 360         sub     sp, sp, #S_FRAME_SIZE
 361         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
 362
 363         ldr     r2, IRQ_STACK_START_IN
 364         @ get values for "aborted" pc and cpsr (into parm regs)
 365         ldmia   r2, {r2 - r3}
 366         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 367         add     r5, sp, #S_SP
 368         mov     r1, lr
 369         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
 370         mov     r0, sp          @ save current stack into r0 (param register)
 371         .endm
 372
 373         .macro  irq_save_user_regs
 374         sub     sp, sp, #S_FRAME_SIZE
 375         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 376         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 377         add     r8, sp, #S_PC
 378         stmdb   r8, {sp, lr}^           @ Calling SP, LR
 379         str     lr, [r8, #0]            @ Save calling PC
 380         mrs     r6, spsr
 381         str     r6, [r8, #4]            @ Save CPSR
 382         str     r0, [r8, #8]            @ Save OLD_R0
 383         mov     r0, sp
 384         .endm
 385
 386         .macro  irq_restore_user_regs
 387         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 388         mov     r0, r0
 389         ldr     lr, [sp, #S_PC]                 @ Get PC
 390         add     sp, sp, #S_FRAME_SIZE
 391         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
 392         .endm
 393
 394         .macro get_bad_stack
 395         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 396
 397         str     lr, [r13]       @ save caller lr in position 0 of saved stack
 398         mrs     lr, spsr        @ get the spsr
 399         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
 400         mov     r13, #MODE_SVC  @ prepare SVC-Mode
 401         @ msr   spsr_c, r13
 402         msr     spsr, r13       @ switch modes, make sure moves will execute
 403         mov     lr, pc          @ capture return pc
 404         movs    pc, lr          @ jump to next instruction & switch modes.
 405         .endm
 406
 407         .macro get_irq_stack                    @ setup IRQ stack
 408         ldr     sp, IRQ_STACK_START
 409         .endm
 410
 411         .macro get_fiq_stack                    @ setup FIQ stack
 412         ldr     sp, FIQ_STACK_START
 413         .endm
 414
 415 /*
 416  * exception handlers
 417  */
 418         .align  5
 419 undefined_instruction:
 420         get_bad_stack
 421         bad_save_user_regs
 422         bl      do_undefined_instruction
 423
 424         .align  5
 425 software_interrupt:
 426         get_bad_stack
 427         bad_save_user_regs
 428         bl      do_software_interrupt
 429
 430         .align  5
 431 prefetch_abort:
 432         get_bad_stack
 433         bad_save_user_regs
 434         bl      do_prefetch_abort
 435
 436         .align  5
 437 data_abort:
 438         get_bad_stack
 439         bad_save_user_regs
 440         bl      do_data_abort
 441
 442         .align  5
 443 not_used:
 444         get_bad_stack
 445         bad_save_user_regs
 446         bl      do_not_used
 447
 448 #ifdef CONFIG_USE_IRQ
 449
 450         .align  5
 451 irq:
 452         get_irq_stack
 453         irq_save_user_regs
 454         bl      do_irq
 455         irq_restore_user_regs
 456
 457         .align  5
 458 fiq:
 459         get_fiq_stack
 460         /* someone ought to write a more effiction fiq_save_user_regs */
 461         irq_save_user_regs
 462         bl      do_fiq
 463         irq_restore_user_regs
 464
 465 #else
 466
 467         .align  5
 468 irq:
 469         get_bad_stack
 470         bad_save_user_regs
 471         bl      do_irq
 472
 473         .align  5
 474 fiq:
 475         get_bad_stack
 476         bad_save_user_regs
 477         bl      do_fiq
 478
 479 #endif
 480
 481 # ifdef CONFIG_INTEGRATOR
 482
 483         /* Satisfied by general board level routine */
 484
 485 #else
 486
 487         .align  5
 488 .globl reset_cpu
 489 reset_cpu:
 490
 491         ldr     r1, rstctl1     /* get clkm1 reset ctl */
 492         mov     r3, #0x0
 493         strh    r3, [r1]        /* clear it */
 494         mov     r3, #0x8
 495         strh    r3, [r1]        /* force dsp+arm reset */
 496 _loop_forever:
 497         b       _loop_forever
 498
 499 rstctl1:
 500         .word   0xfffece10
 501
 502 #endif  /* #ifdef CONFIG_INTEGRATOR */