arch/arm/cpu/arm_intcm/start.S

   1 /*
   2  *  armboot - Startup Code for ARM926EJS CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
  13  *
  14  * See file CREDITS for list of people who contributed to this
  15  * project.
  16  *
  17  * This program is free software; you can redistribute it and/or
  18  * modify it under the terms of the GNU General Public License as
  19  * published by the Free Software Foundation; either version 2 of
  20  * the License, or (at your option) any later version.
  21  *
  22  * This program is distributed in the hope that it will be useful,
  23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25  * GNU General Public License for more details.
  26  *
  27  * You should have received a copy of the GNU General Public License
  28  * along with this program; if not, write to the Free Software
  29  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  30  * MA 02111-1307 USA
  31  */
  32
  33 #include <asm-offsets.h>
  34 #include <config.h>
  35 #include <version.h>
  36
  37 /*
  38  *************************************************************************
  39  *
  40  * Jump vector table
  41  *
  42  *************************************************************************
  43  */
  44
  45 .globl _start
  46 _start:
  47         b       reset
  48         ldr     pc, _undefined_instruction
  49         ldr     pc, _software_interrupt
  50         ldr     pc, _prefetch_abort
  51         ldr     pc, _data_abort
  52         ldr     pc, _not_used
  53         ldr     pc, _irq
  54         ldr     pc, _fiq
  55
  56 _undefined_instruction:
  57         .word undefined_instruction
  58 _software_interrupt:
  59         .word software_interrupt
  60 _prefetch_abort:
  61         .word prefetch_abort
  62 _data_abort:
  63         .word data_abort
  64 _not_used:
  65         .word not_used
  66 _irq:
  67         .word irq
  68 _fiq:
  69         .word fiq
  70
  71         .balignl 16,0xdeadbeef
  72
  73 /*
  74  *************************************************************************
  75  *
  76  * Startup Code (reset vector)
  77  *
  78  * do important init only if we don't start from memory!
  79  * setup memory and board specific bits prior to relocation.
  80  * relocate armboot to ram
  81  * setup stack
  82  *
  83  *************************************************************************
  84  */
  85
  86 .globl _TEXT_BASE
  87 _TEXT_BASE:
  88         .word   CONFIG_SYS_TEXT_BASE /* address of _start in the linked image */
  89
  90 /*
  91  * These are defined in the board-specific linker script.
  92  * Subtracting _start from them lets the linker put their
  93  * relative position in the executable instead of leaving
  94  * them null.
  95  */
  96 .globl _bss_start_ofs
  97 _bss_start_ofs:
  98         .word __bss_start - _start
  99
 100 .globl _bss_end_ofs
 101 _bss_end_ofs:
 102         .word __bss_end__ - _start
 103
 104 .globl _end_ofs
 105 _end_ofs:
 106         .word _end - _start
 107
 108 #ifdef CONFIG_USE_IRQ
 109 /* IRQ stack memory (calculated at run-time) */
 110 .globl IRQ_STACK_START
 111 IRQ_STACK_START:
 112         .word   0x0badc0de
 113
 114 /* IRQ stack memory (calculated at run-time) */
 115 .globl FIQ_STACK_START
 116 FIQ_STACK_START:
 117         .word 0x0badc0de
 118 #endif
 119
 120 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 121 .globl IRQ_STACK_START_IN
 122 IRQ_STACK_START_IN:
 123         .word   0x0badc0de
 124
 125 /*
 126  * the actual reset code
 127  */
 128
 129 reset:
 130         /*
 131          * set the cpu to SVC32 mode
 132          */
 133         mrs     r0,cpsr
 134         bic     r0,r0,#0x1f
 135         orr     r0,r0,#0xd3
 136         msr     cpsr,r0
 137
 138         /*
 139          * we do sys-critical inits only at reboot,
 140          * not when booting from ram!
 141          */
 142 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 143         bl      cpu_init_crit
 144 #endif
 145
 146 /* Set stackpointer in internal RAM to call board_init_f */
 147 call_board_init_f:
 148         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 149         bic     sp, sp, #7 /* 8-byte alignment for ABI compliance */
 150         ldr     r0,=0x00000000
 151         bl      board_init_f
 152
 153 /*------------------------------------------------------------------------------*/
 154
 155 /*
 156  * void relocate_code (addr_sp, gd, addr_moni)
 157  *
 158  * This "function" does not return, instead it continues in RAM
 159  * after relocating the monitor code.
 160  *
 161  */
 162         .globl  relocate_code
 163 relocate_code:
 164         mov     r4, r0  /* save addr_sp */
 165         mov     r5, r1  /* save addr of gd */
 166         mov     r6, r2  /* save addr of destination */
 167
 168         /* Set up the stack                                                 */
 169 stack_setup:
 170         mov     sp, r4
 171
 172         adr     r0, _start
 173         cmp     r0, r6
 174         moveq   r9, #0          /* no relocation. relocation offset(r9) = 0 */
 175         beq     clear_bss               /* skip relocation */
 176         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 177         ldr     r3, _bss_start_ofs
 178         add     r2, r0, r3              /* r2 <- source end address         */
 179
 180 copy_loop:
 181         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 182         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
 183         cmp     r0, r2                  /* until source end address [r2]    */
 184         blo     copy_loop
 185
 186 #ifndef CONFIG_SPL_BUILD
 187         /*
 188          * fix .rel.dyn relocations
 189          */
 190         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 191         sub     r9, r6, r0              /* r9 <- relocation offset */
 192         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 193         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 194         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 195         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 196         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 197         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 198 fixloop:
 199         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 200         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 201         ldr     r1, [r2, #4]
 202         and     r7, r1, #0xff
 203         cmp     r7, #23                 /* relative fixup? */
 204         beq     fixrel
 205         cmp     r7, #2                  /* absolute fixup? */
 206         beq     fixabs
 207         /* ignore unknown type of fixup */
 208         b       fixnext
 209 fixabs:
 210         /* absolute fix: set location to (offset) symbol value */
 211         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 212         add     r1, r10, r1             /* r1 <- address of symbol in table */
 213         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 214         add     r1, r1, r9              /* r1 <- relocated sym addr */
 215         b       fixnext
 216 fixrel:
 217         /* relative fix: increase location by offset */
 218         ldr     r1, [r0]
 219         add     r1, r1, r9
 220 fixnext:
 221         str     r1, [r0]
 222         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 223         cmp     r2, r3
 224         blo     fixloop
 225 #endif
 226
 227 clear_bss:
 228 #ifndef CONFIG_SPL_BUILD
 229         ldr     r0, _bss_start_ofs
 230         ldr     r1, _bss_end_ofs
 231         mov     r4, r6                  /* reloc addr */
 232         add     r0, r0, r4
 233         add     r1, r1, r4
 234         mov     r2, #0x00000000         /* clear                            */
 235
 236 clbss_l:cmp     r0, r1                  /* clear loop... */
 237         bhs     clbss_e                 /* if reached end of bss, exit */
 238         str     r2, [r0]
 239         add     r0, r0, #4
 240         b       clbss_l
 241 clbss_e:
 242
 243         bl coloured_LED_init
 244         bl red_led_on
 245 #endif
 246
 247 /*
 248  * We are done. Do not return, instead branch to second part of board
 249  * initialization, now running from RAM.
 250  */
 251 #ifdef CONFIG_NAND_SPL
 252         ldr     r0, _nand_boot_ofs
 253         mov     pc, r0
 254
 255 _nand_boot_ofs:
 256         .word nand_boot
 257 #else
 258         ldr     r0, _board_init_r_ofs
 259         adr     r1, _start
 260         add     lr, r0, r1
 261         add     lr, lr, r9
 262         /* setup parameters for board_init_r */
 263         mov     r0, r5          /* gd_t */
 264         mov     r1, r6          /* dest_addr */
 265         /* jump to it ... */
 266         mov     pc, lr
 267
 268 _board_init_r_ofs:
 269         .word board_init_r - _start
 270 #endif
 271
 272 _rel_dyn_start_ofs:
 273         .word __rel_dyn_start - _start
 274 _rel_dyn_end_ofs:
 275         .word __rel_dyn_end - _start
 276 _dynsym_start_ofs:
 277         .word __dynsym_start - _start
 278
 279 /*
 280  *************************************************************************
 281  *
 282  * CPU_init_critical registers
 283  *
 284  * setup important registers
 285  * setup memory timing
 286  *
 287  *************************************************************************
 288  */
 289
 290 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 291 cpu_init_crit:
 292         /*  arm_int_generic assumes the ARM boot monitor, or user software,
 293          * has initialized the platform
 294          */
 295         mov     pc, lr          /* back to my caller */
 296 #endif
 297 /*
 298  *************************************************************************
 299  *
 300  * Interrupt handling
 301  *
 302  *************************************************************************
 303  */
 304
 305 @
 306 @ IRQ stack frame.
 307 @
 308 #define S_FRAME_SIZE    72
 309
 310 #define S_OLD_R0        68
 311 #define S_PSR           64
 312 #define S_PC            60
 313 #define S_LR            56
 314 #define S_SP            52
 315
 316 #define S_IP            48
 317 #define S_FP            44
 318 #define S_R10           40
 319 #define S_R9            36
 320 #define S_R8            32
 321 #define S_R7            28
 322 #define S_R6            24
 323 #define S_R5            20
 324 #define S_R4            16
 325 #define S_R3            12
 326 #define S_R2            8
 327 #define S_R1            4
 328 #define S_R0            0
 329
 330 #define MODE_SVC 0x13
 331 #define I_BIT    0x80
 332
 333 /*
 334  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 335  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 336  */
 337
 338         .macro  bad_save_user_regs
 339         @ carve out a frame on current user stack
 340         sub     sp, sp, #S_FRAME_SIZE
 341         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
 342
 343         ldr     r2, IRQ_STACK_START_IN
 344         @ get values for "aborted" pc and cpsr (into parm regs)
 345         ldmia   r2, {r2 - r3}
 346         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 347         add     r5, sp, #S_SP
 348         mov     r1, lr
 349         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
 350         mov     r0, sp          @ save current stack into r0 (param register)
 351         .endm
 352
 353         .macro  irq_save_user_regs
 354         sub     sp, sp, #S_FRAME_SIZE
 355         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 356         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 357         add     r8, sp, #S_PC
 358         stmdb   r8, {sp, lr}^           @ Calling SP, LR
 359         str     lr, [r8, #0]            @ Save calling PC
 360         mrs     r6, spsr
 361         str     r6, [r8, #4]            @ Save CPSR
 362         str     r0, [r8, #8]            @ Save OLD_R0
 363         mov     r0, sp
 364         .endm
 365
 366         .macro  irq_restore_user_regs
 367         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 368         mov     r0, r0
 369         ldr     lr, [sp, #S_PC]                 @ Get PC
 370         add     sp, sp, #S_FRAME_SIZE
 371         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
 372         .endm
 373
 374         .macro get_bad_stack
 375         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 376
 377         str     lr, [r13]       @ save caller lr in position 0 of saved stack
 378         mrs     lr, spsr        @ get the spsr
 379         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
 380         mov     r13, #MODE_SVC  @ prepare SVC-Mode
 381         @ msr   spsr_c, r13
 382         msr     spsr, r13       @ switch modes, make sure moves will execute
 383         mov     lr, pc          @ capture return pc
 384         movs    pc, lr          @ jump to next instruction & switch modes.
 385         .endm
 386
 387         .macro get_irq_stack                    @ setup IRQ stack
 388         ldr     sp, IRQ_STACK_START
 389         .endm
 390
 391         .macro get_fiq_stack                    @ setup FIQ stack
 392         ldr     sp, FIQ_STACK_START
 393         .endm
 394
 395 /*
 396  * exception handlers
 397  */
 398         .align  5
 399 .globl undefined_instruction
 400 undefined_instruction:
 401         get_bad_stack
 402         bad_save_user_regs
 403         bl      do_undefined_instruction
 404
 405         .align  5
 406 .globl software_interrupt
 407 software_interrupt:
 408         get_bad_stack
 409         bad_save_user_regs
 410         bl      do_software_interrupt
 411
 412         .align  5
 413 .globl prefetch_abort
 414 prefetch_abort:
 415         get_bad_stack
 416         bad_save_user_regs
 417         bl      do_prefetch_abort
 418
 419         .align  5
 420 .globl data_abort
 421 data_abort:
 422         get_bad_stack
 423         bad_save_user_regs
 424         bl      do_data_abort
 425
 426         .align  5
 427 .globl not_used
 428 not_used:
 429         get_bad_stack
 430         bad_save_user_regs
 431         bl      do_not_used
 432
 433 #ifdef CONFIG_USE_IRQ
 434         .align  5
 435 .globl irq
 436 irq:
 437         get_irq_stack
 438         irq_save_user_regs
 439         bl      do_irq
 440         irq_restore_user_regs
 441
 442         .align  5
 443 .globl fiq
 444 fiq:
 445         get_fiq_stack
 446         /* someone ought to write a more effiction fiq_save_user_regs */
 447         irq_save_user_regs
 448         bl      do_fiq
 449         irq_restore_user_regs
 450
 451 #else
 452
 453         .align  5
 454 .globl irq
 455 irq:
 456         get_bad_stack
 457         bad_save_user_regs
 458         bl      do_irq
 459
 460         .align  5
 461 .globl fiq
 462 fiq:
 463         get_bad_stack
 464         bad_save_user_regs
 465         bl      do_fiq
 466
 467 #endif