arch/arm/cpu/arm_intcm/start.S

   1 /*
   2  *  armboot - Startup Code for ARM926EJS CPU-core
   3  *
   4  *  Copyright (c) 2003  Texas Instruments
   5  *
   6  *  ----- Adapted for OMAP1610 OMAP730 from ARM925t code ------
   7  *
   8  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   9  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
  10  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
  11  *  Copyright (c) 2003  Richard Woodruff <r-woodruff2@ti.com>
  12  *  Copyright (c) 2003  Kshitij <kshitij@ti.com>
  13  *
  14  * See file CREDITS for list of people who contributed to this
  15  * project.
  16  *
  17  * This program is free software; you can redistribute it and/or
  18  * modify it under the terms of the GNU General Public License as
  19  * published by the Free Software Foundation; either version 2 of
  20  * the License, or (at your option) any later version.
  21  *
  22  * This program is distributed in the hope that it will be useful,
  23  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  24  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  25  * GNU General Public License for more details.
  26  *
  27  * You should have received a copy of the GNU General Public License
  28  * along with this program; if not, write to the Free Software
  29  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  30  * MA 02111-1307 USA
  31  */
  32
  33 #include <asm-offsets.h>
  34 #include <config.h>
  35 #include <version.h>
  36
  37 /*
  38  *************************************************************************
  39  *
  40  * Jump vector table
  41  *
  42  *************************************************************************
  43  */
  44
  45 .globl _start
  46 _start:
  47         b       reset
  48         ldr     pc, _undefined_instruction
  49         ldr     pc, _software_interrupt
  50         ldr     pc, _prefetch_abort
  51         ldr     pc, _data_abort
  52         ldr     pc, _not_used
  53         ldr     pc, _irq
  54         ldr     pc, _fiq
  55
  56 _undefined_instruction:
  57         .word undefined_instruction
  58 _software_interrupt:
  59         .word software_interrupt
  60 _prefetch_abort:
  61         .word prefetch_abort
  62 _data_abort:
  63         .word data_abort
  64 _not_used:
  65         .word not_used
  66 _irq:
  67         .word irq
  68 _fiq:
  69         .word fiq
  70
  71         .balignl 16,0xdeadbeef
  72
  73 /*
  74  *************************************************************************
  75  *
  76  * Startup Code (reset vector)
  77  *
  78  * do important init only if we don't start from memory!
  79  * setup memory and board specific bits prior to relocation.
  80  * relocate armboot to ram
  81  * setup stack
  82  *
  83  *************************************************************************
  84  */
  85
  86 .globl _TEXT_BASE
  87 _TEXT_BASE:
  88 #if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_TEXT_BASE)
  89         .word   CONFIG_SPL_TEXT_BASE
  90 #else
  91         .word   CONFIG_SYS_TEXT_BASE
  92 #endif
  93
  94 /*
  95  * These are defined in the board-specific linker script.
  96  * Subtracting _start from them lets the linker put their
  97  * relative position in the executable instead of leaving
  98  * them null.
  99  */
 100 .globl _bss_start_ofs
 101 _bss_start_ofs:
 102         .word __bss_start - _start
 103
 104 .globl _bss_end_ofs
 105 _bss_end_ofs:
 106         .word __bss_end - _start
 107
 108 .globl _end_ofs
 109 _end_ofs:
 110         .word _end - _start
 111
 112 #ifdef CONFIG_USE_IRQ
 113 /* IRQ stack memory (calculated at run-time) */
 114 .globl IRQ_STACK_START
 115 IRQ_STACK_START:
 116         .word   0x0badc0de
 117
 118 /* IRQ stack memory (calculated at run-time) */
 119 .globl FIQ_STACK_START
 120 FIQ_STACK_START:
 121         .word 0x0badc0de
 122 #endif
 123
 124 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 125 .globl IRQ_STACK_START_IN
 126 IRQ_STACK_START_IN:
 127         .word   0x0badc0de
 128
 129 /*
 130  * the actual reset code
 131  */
 132
 133 reset:
 134         /*
 135          * set the cpu to SVC32 mode
 136          */
 137         mrs     r0,cpsr
 138         bic     r0,r0,#0x1f
 139         orr     r0,r0,#0xd3
 140         msr     cpsr,r0
 141
 142         /*
 143          * we do sys-critical inits only at reboot,
 144          * not when booting from ram!
 145          */
 146 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 147         bl      cpu_init_crit
 148 #endif
 149
 150         bl      _main
 151
 152 /*------------------------------------------------------------------------------*/
 153
 154 #ifndef CONFIG_SPL_BUILD
 155 /*
 156  * void relocate_code(addr_moni)
 157  *
 158  * This function relocates the monitor code.
 159  */
 160         .globl  relocate_code
 161 relocate_code:
 162         mov     r6, r0  /* save addr of destination */
 163
 164         adr     r0, _start
 165         subs    r9, r6, r0              /* r9 <- relocation offset */
 166         beq     relocate_done           /* skip relocation */
 167         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 168         ldr     r3, _image_copy_end_ofs
 169         add     r2, r0, r3              /* r2 <- source end address         */
 170
 171 copy_loop:
 172         ldmia   r0!, {r10-r11}          /* copy from source address [r0]    */
 173         stmia   r1!, {r10-r11}          /* copy to   target address [r1]    */
 174         cmp     r0, r2                  /* until source end address [r2]    */
 175         blo     copy_loop
 176
 177         /*
 178          * fix .rel.dyn relocations
 179          */
 180         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 181         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 182         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 183         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 184         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 185         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 186         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 187 fixloop:
 188         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 189         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 190         ldr     r1, [r2, #4]
 191         and     r7, r1, #0xff
 192         cmp     r7, #23                 /* relative fixup? */
 193         beq     fixrel
 194         cmp     r7, #2                  /* absolute fixup? */
 195         beq     fixabs
 196         /* ignore unknown type of fixup */
 197         b       fixnext
 198 fixabs:
 199         /* absolute fix: set location to (offset) symbol value */
 200         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 201         add     r1, r10, r1             /* r1 <- address of symbol in table */
 202         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 203         add     r1, r1, r9              /* r1 <- relocated sym addr */
 204         b       fixnext
 205 fixrel:
 206         /* relative fix: increase location by offset */
 207         ldr     r1, [r0]
 208         add     r1, r1, r9
 209 fixnext:
 210         str     r1, [r0]
 211         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 212         cmp     r2, r3
 213         blo     fixloop
 214
 215 relocate_done:
 216
 217         bx      lr
 218
 219 _image_copy_end_ofs:
 220         .word __image_copy_end - _start
 221 _rel_dyn_start_ofs:
 222         .word __rel_dyn_start - _start
 223 _rel_dyn_end_ofs:
 224         .word __rel_dyn_end - _start
 225 _dynsym_start_ofs:
 226         .word __dynsym_start - _start
 227
 228 #endif
 229
 230         .globl  c_runtime_cpu_setup
 231 c_runtime_cpu_setup:
 232
 233         mov     pc, lr
 234
 235 /*
 236  *************************************************************************
 237  *
 238  * CPU_init_critical registers
 239  *
 240  * setup important registers
 241  * setup memory timing
 242  *
 243  *************************************************************************
 244  */
 245
 246 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 247 cpu_init_crit:
 248         /*  arm_int_generic assumes the ARM boot monitor, or user software,
 249          * has initialized the platform
 250          */
 251         mov     pc, lr          /* back to my caller */
 252 #endif
 253 /*
 254  *************************************************************************
 255  *
 256  * Interrupt handling
 257  *
 258  *************************************************************************
 259  */
 260
 261 @
 262 @ IRQ stack frame.
 263 @
 264 #define S_FRAME_SIZE    72
 265
 266 #define S_OLD_R0        68
 267 #define S_PSR           64
 268 #define S_PC            60
 269 #define S_LR            56
 270 #define S_SP            52
 271
 272 #define S_IP            48
 273 #define S_FP            44
 274 #define S_R10           40
 275 #define S_R9            36
 276 #define S_R8            32
 277 #define S_R7            28
 278 #define S_R6            24
 279 #define S_R5            20
 280 #define S_R4            16
 281 #define S_R3            12
 282 #define S_R2            8
 283 #define S_R1            4
 284 #define S_R0            0
 285
 286 #define MODE_SVC 0x13
 287 #define I_BIT    0x80
 288
 289 /*
 290  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 291  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 292  */
 293
 294         .macro  bad_save_user_regs
 295         @ carve out a frame on current user stack
 296         sub     sp, sp, #S_FRAME_SIZE
 297         stmia   sp, {r0 - r12}  @ Save user registers (now in svc mode) r0-r12
 298
 299         ldr     r2, IRQ_STACK_START_IN
 300         @ get values for "aborted" pc and cpsr (into parm regs)
 301         ldmia   r2, {r2 - r3}
 302         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 303         add     r5, sp, #S_SP
 304         mov     r1, lr
 305         stmia   r5, {r0 - r3}   @ save sp_SVC, lr_SVC, pc, cpsr
 306         mov     r0, sp          @ save current stack into r0 (param register)
 307         .endm
 308
 309         .macro  irq_save_user_regs
 310         sub     sp, sp, #S_FRAME_SIZE
 311         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 312         @ !!!! R8 NEEDS to be saved !!!! a reserved stack spot would be good.
 313         add     r8, sp, #S_PC
 314         stmdb   r8, {sp, lr}^           @ Calling SP, LR
 315         str     lr, [r8, #0]            @ Save calling PC
 316         mrs     r6, spsr
 317         str     r6, [r8, #4]            @ Save CPSR
 318         str     r0, [r8, #8]            @ Save OLD_R0
 319         mov     r0, sp
 320         .endm
 321
 322         .macro  irq_restore_user_regs
 323         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 324         mov     r0, r0
 325         ldr     lr, [sp, #S_PC]                 @ Get PC
 326         add     sp, sp, #S_FRAME_SIZE
 327         subs    pc, lr, #4              @ return & move spsr_svc into cpsr
 328         .endm
 329
 330         .macro get_bad_stack
 331         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 332
 333         str     lr, [r13]       @ save caller lr in position 0 of saved stack
 334         mrs     lr, spsr        @ get the spsr
 335         str     lr, [r13, #4]   @ save spsr in position 1 of saved stack
 336         mov     r13, #MODE_SVC  @ prepare SVC-Mode
 337         @ msr   spsr_c, r13
 338         msr     spsr, r13       @ switch modes, make sure moves will execute
 339         mov     lr, pc          @ capture return pc
 340         movs    pc, lr          @ jump to next instruction & switch modes.
 341         .endm
 342
 343         .macro get_irq_stack                    @ setup IRQ stack
 344         ldr     sp, IRQ_STACK_START
 345         .endm
 346
 347         .macro get_fiq_stack                    @ setup FIQ stack
 348         ldr     sp, FIQ_STACK_START
 349         .endm
 350
 351 /*
 352  * exception handlers
 353  */
 354         .align  5
 355 .globl undefined_instruction
 356 undefined_instruction:
 357         get_bad_stack
 358         bad_save_user_regs
 359         bl      do_undefined_instruction
 360
 361         .align  5
 362 .globl software_interrupt
 363 software_interrupt:
 364         get_bad_stack
 365         bad_save_user_regs
 366         bl      do_software_interrupt
 367
 368         .align  5
 369 .globl prefetch_abort
 370 prefetch_abort:
 371         get_bad_stack
 372         bad_save_user_regs
 373         bl      do_prefetch_abort
 374
 375         .align  5
 376 .globl data_abort
 377 data_abort:
 378         get_bad_stack
 379         bad_save_user_regs
 380         bl      do_data_abort
 381
 382         .align  5
 383 .globl not_used
 384 not_used:
 385         get_bad_stack
 386         bad_save_user_regs
 387         bl      do_not_used
 388
 389 #ifdef CONFIG_USE_IRQ
 390         .align  5
 391 .globl irq
 392 irq:
 393         get_irq_stack
 394         irq_save_user_regs
 395         bl      do_irq
 396         irq_restore_user_regs
 397
 398         .align  5
 399 .globl fiq
 400 fiq:
 401         get_fiq_stack
 402         /* someone ought to write a more effiction fiq_save_user_regs */
 403         irq_save_user_regs
 404         bl      do_fiq
 405         irq_restore_user_regs
 406
 407 #else
 408
 409         .align  5
 410 .globl irq
 411 irq:
 412         get_bad_stack
 413         bad_save_user_regs
 414         bl      do_irq
 415
 416         .align  5
 417 .globl fiq
 418 fiq:
 419         get_bad_stack
 420         bad_save_user_regs
 421         bl      do_fiq
 422
 423 #endif