arch/arm/cpu/armv7/rmobile/lowlevel_init_ca15.S

   1 /*
   2  * arch/arm/cpu/armv7/rmobile/lowlevel_init_ca15.S
   3  *     This file is lager low level initialize.
   4  *
   5  * Copyright (C) 2013, 2014 Renesas Electronics Corporation
   6  *
   7  * SPDX-License-Identifier: GPL-2.0
   8  */
   9
  10 #include <config.h>
  11 #include <linux/linkage.h>
  12
  13 ENTRY(lowlevel_init)
  14         mrc     p15, 0, r4, c0, c0, 5 /* mpidr */
  15         orr     r4, r4, r4, lsr #6
  16         and     r4, r4, #7 /* id 0-3 = ca15.0,1,2,3 */
  17
  18         b do_lowlevel_init
  19
  20         .pool
  21
  22 /*
  23  * CPU ID #1-#3 come here
  24  */
  25         .align  4
  26 do_cpu_waiting:
  27         ldr     r1, =0xe6180000 /* sysc */
  28 1:      ldr     r0, [r1, #0x20] /* sbar */
  29         tst     r0, r0
  30         beq     1b
  31         bx      r0
  32
  33 /*
  34  * Only CPU ID #0 comes here
  35  */
  36         .align  4
  37 do_lowlevel_init:
  38         /* surpress wfe if ca15 */
  39         tst r4, #4
  40         mrceq p15, 0, r0, c1, c0, 1     /* actlr */
  41         orreq r0, r0, #(1<<7)
  42         mcreq p15, 0, r0, c1, c0, 1
  43
  44         /* and set l2 latency */
  45         mrceq p15, 1, r0, c9, c0, 2     /* l2ctlr */
  46         orreq r0, r0, #0x00000800
  47         orreq r0, r0, #0x00000003
  48         mcreq p15, 1, r0, c9, c0, 2
  49
  50         mrc p15, 0, r0, c0, c0, 5       /* r0 = MPIDR */
  51         and r0, r0, #0xf00
  52         lsr r0, r0, #8
  53         tst r0, #1                      /* only need for cluster 0 */
  54         bne _exit_init_l2_a15
  55
  56         mrc p15, 1, r0, c9, c0, 2       /* r0 = L2CTLR */
  57         and r1, r0, #7
  58         cmp r1, #3                      /* has already been set up */
  59         bicne r0, r0, #0xe7
  60         orrne r0, r0, #0x83             /* L2CTLR[7:6] + L2CTLR[2:0] */
  61         orrne r0, r0, #0x20             /* L2CTLR[5] */
  62         mcrne p15, 1, r0, c9, c0, 2
  63
  64 _exit_init_l2_a15:
  65         ldr     r3, =(CONFIG_SYS_INIT_SP_ADDR)
  66         sub     sp, r3, #4
  67         str     lr, [sp]
  68
  69         /* initialize system */
  70         bl s_init
  71
  72         ldr     lr, [sp]
  73         mov     pc, lr
  74         nop
  75 ENDPROC(lowlevel_init)
  76         .ltorg