arch/arm/cpu/armv7/start.S

   1 /*
   2  * armboot - Startup Code for OMAP3530/ARM Cortex CPU-core
   3  *
   4  * Copyright (c) 2004   Texas Instruments <r-woodruff2@ti.com>
   5  *
   6  * Copyright (c) 2001   Marius Gröger <mag@sysgo.de>
   7  * Copyright (c) 2002   Alex Züpke <azu@sysgo.de>
   8  * Copyright (c) 2002   Gary Jennejohn <garyj@denx.de>
   9  * Copyright (c) 2003   Richard Woodruff <r-woodruff2@ti.com>
  10  * Copyright (c) 2003   Kshitij <kshitij@ti.com>
  11  * Copyright (c) 2006-2008 Syed Mohammed Khasim <x0khasim@ti.com>
  12  *
  13  * See file CREDITS for list of people who contributed to this
  14  * project.
  15  *
  16  * This program is free software; you can redistribute it and/or
  17  * modify it under the terms of the GNU General Public License as
  18  * published by the Free Software Foundation; either version 2 of
  19  * the License, or (at your option) any later version.
  20  *
  21  * This program is distributed in the hope that it will be useful,
  22  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  23  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24  * GNU General Public License for more details.
  25  *
  26  * You should have received a copy of the GNU General Public License
  27  * along with this program; if not, write to the Free Software
  28  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  29  * MA 02111-1307 USA
  30  */
  31
  32 #include <asm-offsets.h>
  33 #include <config.h>
  34 #include <version.h>
  35 #include <asm/system.h>
  36 #include <linux/linkage.h>
  37
  38 .globl _start
  39 _start: b       reset
  40         ldr     pc, _undefined_instruction
  41         ldr     pc, _software_interrupt
  42         ldr     pc, _prefetch_abort
  43         ldr     pc, _data_abort
  44         ldr     pc, _not_used
  45         ldr     pc, _irq
  46         ldr     pc, _fiq
  47 #ifdef CONFIG_SPL_BUILD
  48 _undefined_instruction: .word _undefined_instruction
  49 _software_interrupt:    .word _software_interrupt
  50 _prefetch_abort:        .word _prefetch_abort
  51 _data_abort:            .word _data_abort
  52 _not_used:              .word _not_used
  53 _irq:                   .word _irq
  54 _fiq:                   .word _fiq
  55 _pad:                   .word 0x12345678 /* now 16*4=64 */
  56 #else
  57 _undefined_instruction: .word undefined_instruction
  58 _software_interrupt:    .word software_interrupt
  59 _prefetch_abort:        .word prefetch_abort
  60 _data_abort:            .word data_abort
  61 _not_used:              .word not_used
  62 _irq:                   .word irq
  63 _fiq:                   .word fiq
  64 _pad:                   .word 0x12345678 /* now 16*4=64 */
  65 #endif  /* CONFIG_SPL_BUILD */
  66
  67 .global _end_vect
  68 _end_vect:
  69
  70         .balignl 16,0xdeadbeef
  71 /*************************************************************************
  72  *
  73  * Startup Code (reset vector)
  74  *
  75  * do important init only if we don't start from memory!
  76  * setup Memory and board specific bits prior to relocation.
  77  * relocate armboot to ram
  78  * setup stack
  79  *
  80  *************************************************************************/
  81
  82 .globl _TEXT_BASE
  83 _TEXT_BASE:
  84         .word   _start
  85
  86 /*
  87  * These are defined in the board-specific linker script.
  88  */
  89 .globl _bss_start_ofs
  90 _bss_start_ofs:
  91         .word __bss_start - _start
  92
  93 .global _image_copy_end_ofs
  94 _image_copy_end_ofs:
  95         .word   __image_copy_end - _start
  96
  97 .globl _bss_end_ofs
  98 _bss_end_ofs:
  99         .word __bss_end__ - _start
 100
 101 .globl _end_ofs
 102 _end_ofs:
 103         .word _end - _start
 104
 105 #ifdef CONFIG_USE_IRQ
 106 /* IRQ stack memory (calculated at run-time) */
 107 .globl IRQ_STACK_START
 108 IRQ_STACK_START:
 109         .word   0x0badc0de
 110
 111 /* IRQ stack memory (calculated at run-time) */
 112 .globl FIQ_STACK_START
 113 FIQ_STACK_START:
 114         .word 0x0badc0de
 115 #endif
 116
 117 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 118 .globl IRQ_STACK_START_IN
 119 IRQ_STACK_START_IN:
 120         .word   0x0badc0de
 121
 122 /*
 123  * the actual reset code
 124  */
 125
 126 reset:
 127         bl      save_boot_params
 128         /*
 129          * set the cpu to SVC32 mode
 130          */
 131         mrs     r0, cpsr
 132         bic     r0, r0, #0x1f
 133         orr     r0, r0, #0xd3
 134         msr     cpsr,r0
 135
 136 /*
 137  * Setup vector:
 138  * (OMAP4 spl TEXT_BASE is not 32 byte aligned.
 139  * Continue to use ROM code vector only in OMAP4 spl)
 140  */
 141 #if !(defined(CONFIG_OMAP44XX) && defined(CONFIG_SPL_BUILD))
 142         /* Set V=0 in CP15 SCTRL register - for VBAR to point to vector */
 143         mrc     p15, 0, r0, c1, c0, 0   @ Read CP15 SCTRL Register
 144         bic     r0, #CR_V               @ V = 0
 145         mcr     p15, 0, r0, c1, c0, 0   @ Write CP15 SCTRL Register
 146
 147         /* Set vector address in CP15 VBAR register */
 148         ldr     r0, =_start
 149         mcr     p15, 0, r0, c12, c0, 0  @Set VBAR
 150 #endif
 151
 152         /* the mask ROM code should have PLL and others stable */
 153 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 154         bl      cpu_init_cp15
 155         bl      cpu_init_crit
 156 #endif
 157
 158         bl      _main
 159
 160 /*------------------------------------------------------------------------------*/
 161
 162 #ifndef CONFIG_SPL_BUILD
 163 /*
 164  * void relocate_code (addr_sp, gd, addr_moni)
 165  *
 166  * This "function" does not return, instead it continues in RAM
 167  * after relocating the monitor code.
 168  *
 169  */
 170 ENTRY(relocate_code)
 171         mov     r4, r0  /* save addr_sp */
 172         mov     r5, r1  /* save addr of gd */
 173         mov     r6, r2  /* save addr of destination */
 174
 175         adr     r0, _start
 176         subs    r9, r6, r0
 177         beq     relocate_done           /* skip relocation */
 178         mov     r1, r6                  /* r1 <- scratch for copy_loop */
 179         ldr     r3, _image_copy_end_ofs
 180         add     r2, r0, r3              /* r2 <- source end address         */
 181
 182 copy_loop:
 183         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 184         stmia   r1!, {r9-r10}           /* copy to   target address [r1]    */
 185         cmp     r0, r2                  /* until source end address [r2]    */
 186         blo     copy_loop
 187
 188         /*
 189          * fix .rel.dyn relocations
 190          */
 191         adr     r0, _start              /* r0 <- beginning of code */
 192         sub     r9, r6, r0              /* r9 <- relocation offset */
 193         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 194         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 195         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 196         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 197         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 198         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 199         mov     r4, r0
 200 fixloop:
 201         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 202         cmp     r0, r4
 203         blo     skipfix
 204         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 205         ldr     r1, [r2, #4]
 206         and     r7, r1, #0xff
 207         cmp     r7, #23                 /* relative fixup? */
 208         beq     fixrel
 209         cmp     r7, #2                  /* absolute fixup? */
 210         beq     fixabs
 211         /* ignore unknown type of fixup */
 212         b       fixnext
 213 fixabs:
 214         /* absolute fix: set location to (offset) symbol value */
 215         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 216         add     r1, r10, r1             /* r1 <- address of symbol in table */
 217         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 218         add     r1, r1, r9              /* r1 <- relocated sym addr */
 219         b       fixnext
 220 fixrel:
 221         /* relative fix: increase location by offset */
 222         ldr     r1, [r0]
 223         add     r1, r1, r9
 224 fixnext:
 225         str     r1, [r0]
 226 skipfix:
 227         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 228         cmp     r2, r3
 229         blo     fixloop
 230
 231 relocate_done:
 232
 233         bx      lr
 234
 235 _rel_dyn_start_ofs:
 236         .word __rel_dyn_start - _start
 237 _rel_dyn_end_ofs:
 238         .word __rel_dyn_end - _start
 239 _dynsym_start_ofs:
 240         .word __dynsym_start - _start
 241 ENDPROC(relocate_code)
 242
 243 #endif
 244
 245 ENTRY(c_runtime_cpu_setup)
 246 /*
 247  * If I-cache is enabled invalidate it
 248  */
 249 #ifndef CONFIG_SYS_ICACHE_OFF
 250         mcr     p15, 0, r0, c7, c5, 0   @ invalidate icache
 251         mcr     p15, 0, r0, c7, c10, 4  @ DSB
 252         mcr     p15, 0, r0, c7, c5, 4   @ ISB
 253 #endif
 254 /*
 255  * Move vector table
 256  */
 257 #if !defined(CONFIG_TEGRA20)
 258         /* Set vector address in CP15 VBAR register */
 259         ldr     r0, =_start
 260         add     r0, r0, r9
 261         mcr     p15, 0, r0, c12, c0, 0  @Set VBAR
 262 #endif /* !Tegra20 */
 263
 264         bx      lr
 265
 266 ENDPROC(c_runtime_cpu_setup)
 267
 268 /*************************************************************************
 269  *
 270  * void save_boot_params(u32 r0, u32 r1, u32 r2, u32 r3)
 271  *      __attribute__((weak));
 272  *
 273  * Stack pointer is not yet initialized at this moment
 274  * Don't save anything to stack even if compiled with -O0
 275  *
 276  *************************************************************************/
 277 ENTRY(save_boot_params)
 278         bx      lr                      @ back to my caller
 279 ENDPROC(save_boot_params)
 280         .weak   save_boot_params
 281
 282 /*************************************************************************
 283  *
 284  * cpu_init_cp15
 285  *
 286  * Setup CP15 registers (cache, MMU, TLBs). The I-cache is turned on unless
 287  * CONFIG_SYS_ICACHE_OFF is defined.
 288  *
 289  *************************************************************************/
 290 ENTRY(cpu_init_cp15)
 291         /*
 292          * Invalidate L1 I/D
 293          */
 294         mov     r0, #0                  @ set up for MCR
 295         mcr     p15, 0, r0, c8, c7, 0   @ invalidate TLBs
 296         mcr     p15, 0, r0, c7, c5, 0   @ invalidate icache
 297         mcr     p15, 0, r0, c7, c5, 6   @ invalidate BP array
 298         mcr     p15, 0, r0, c7, c10, 4  @ DSB
 299         mcr     p15, 0, r0, c7, c5, 4   @ ISB
 300
 301         /*
 302          * disable MMU stuff and caches
 303          */
 304         mrc     p15, 0, r0, c1, c0, 0
 305         bic     r0, r0, #0x00002000     @ clear bits 13 (--V-)
 306         bic     r0, r0, #0x00000007     @ clear bits 2:0 (-CAM)
 307         orr     r0, r0, #0x00000002     @ set bit 1 (--A-) Align
 308         orr     r0, r0, #0x00000800     @ set bit 11 (Z---) BTB
 309 #ifdef CONFIG_SYS_ICACHE_OFF
 310         bic     r0, r0, #0x00001000     @ clear bit 12 (I) I-cache
 311 #else
 312         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-cache
 313 #endif
 314         mcr     p15, 0, r0, c1, c0, 0
 315         mov     pc, lr                  @ back to my caller
 316 ENDPROC(cpu_init_cp15)
 317
 318 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 319 /*************************************************************************
 320  *
 321  * CPU_init_critical registers
 322  *
 323  * setup important registers
 324  * setup memory timing
 325  *
 326  *************************************************************************/
 327 ENTRY(cpu_init_crit)
 328         /*
 329          * Jump to board specific initialization...
 330          * The Mask ROM will have already initialized
 331          * basic memory. Go here to bump up clock rate and handle
 332          * wake up conditions.
 333          */
 334         b       lowlevel_init           @ go setup pll,mux,memory
 335 ENDPROC(cpu_init_crit)
 336 #endif
 337
 338 #ifndef CONFIG_SPL_BUILD
 339 /*
 340  *************************************************************************
 341  *
 342  * Interrupt handling
 343  *
 344  *************************************************************************
 345  */
 346 @
 347 @ IRQ stack frame.
 348 @
 349 #define S_FRAME_SIZE    72
 350
 351 #define S_OLD_R0        68
 352 #define S_PSR           64
 353 #define S_PC            60
 354 #define S_LR            56
 355 #define S_SP            52
 356
 357 #define S_IP            48
 358 #define S_FP            44
 359 #define S_R10           40
 360 #define S_R9            36
 361 #define S_R8            32
 362 #define S_R7            28
 363 #define S_R6            24
 364 #define S_R5            20
 365 #define S_R4            16
 366 #define S_R3            12
 367 #define S_R2            8
 368 #define S_R1            4
 369 #define S_R0            0
 370
 371 #define MODE_SVC 0x13
 372 #define I_BIT    0x80
 373
 374 /*
 375  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 376  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 377  */
 378
 379         .macro  bad_save_user_regs
 380         sub     sp, sp, #S_FRAME_SIZE           @ carve out a frame on current
 381                                                 @ user stack
 382         stmia   sp, {r0 - r12}                  @ Save user registers (now in
 383                                                 @ svc mode) r0-r12
 384         ldr     r2, IRQ_STACK_START_IN          @ set base 2 words into abort
 385                                                 @ stack
 386         ldmia   r2, {r2 - r3}                   @ get values for "aborted" pc
 387                                                 @ and cpsr (into parm regs)
 388         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 389
 390         add     r5, sp, #S_SP
 391         mov     r1, lr
 392         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 393         mov     r0, sp                          @ save current stack into r0
 394                                                 @ (param register)
 395         .endm
 396
 397         .macro  irq_save_user_regs
 398         sub     sp, sp, #S_FRAME_SIZE
 399         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 400         add     r8, sp, #S_PC                   @ !! R8 NEEDS to be saved !!
 401                                                 @ a reserved stack spot would
 402                                                 @ be good.
 403         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 404         str     lr, [r8, #0]                    @ Save calling PC
 405         mrs     r6, spsr
 406         str     r6, [r8, #4]                    @ Save CPSR
 407         str     r0, [r8, #8]                    @ Save OLD_R0
 408         mov     r0, sp
 409         .endm
 410
 411         .macro  irq_restore_user_regs
 412         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 413         mov     r0, r0
 414         ldr     lr, [sp, #S_PC]                 @ Get PC
 415         add     sp, sp, #S_FRAME_SIZE
 416         subs    pc, lr, #4                      @ return & move spsr_svc into
 417                                                 @ cpsr
 418         .endm
 419
 420         .macro get_bad_stack
 421         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack (enter
 422                                                 @ in banked mode)
 423
 424         str     lr, [r13]                       @ save caller lr in position 0
 425                                                 @ of saved stack
 426         mrs     lr, spsr                        @ get the spsr
 427         str     lr, [r13, #4]                   @ save spsr in position 1 of
 428                                                 @ saved stack
 429
 430         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 431         @ msr   spsr_c, r13
 432         msr     spsr, r13                       @ switch modes, make sure
 433                                                 @ moves will execute
 434         mov     lr, pc                          @ capture return pc
 435         movs    pc, lr                          @ jump to next instruction &
 436                                                 @ switch modes.
 437         .endm
 438
 439         .macro get_bad_stack_swi
 440         sub     r13, r13, #4                    @ space on current stack for
 441                                                 @ scratch reg.
 442         str     r0, [r13]                       @ save R0's value.
 443         ldr     r0, IRQ_STACK_START_IN          @ get data regions start
 444                                                 @ spots for abort stack
 445         str     lr, [r0]                        @ save caller lr in position 0
 446                                                 @ of saved stack
 447         mrs     r0, spsr                        @ get the spsr
 448         str     lr, [r0, #4]                    @ save spsr in position 1 of
 449                                                 @ saved stack
 450         ldr     r0, [r13]                       @ restore r0
 451         add     r13, r13, #4                    @ pop stack entry
 452         .endm
 453
 454         .macro get_irq_stack                    @ setup IRQ stack
 455         ldr     sp, IRQ_STACK_START
 456         .endm
 457
 458         .macro get_fiq_stack                    @ setup FIQ stack
 459         ldr     sp, FIQ_STACK_START
 460         .endm
 461
 462 /*
 463  * exception handlers
 464  */
 465         .align  5
 466 undefined_instruction:
 467         get_bad_stack
 468         bad_save_user_regs
 469         bl      do_undefined_instruction
 470
 471         .align  5
 472 software_interrupt:
 473         get_bad_stack_swi
 474         bad_save_user_regs
 475         bl      do_software_interrupt
 476
 477         .align  5
 478 prefetch_abort:
 479         get_bad_stack
 480         bad_save_user_regs
 481         bl      do_prefetch_abort
 482
 483         .align  5
 484 data_abort:
 485         get_bad_stack
 486         bad_save_user_regs
 487         bl      do_data_abort
 488
 489         .align  5
 490 not_used:
 491         get_bad_stack
 492         bad_save_user_regs
 493         bl      do_not_used
 494
 495 #ifdef CONFIG_USE_IRQ
 496
 497         .align  5
 498 irq:
 499         get_irq_stack
 500         irq_save_user_regs
 501         bl      do_irq
 502         irq_restore_user_regs
 503
 504         .align  5
 505 fiq:
 506         get_fiq_stack
 507         /* someone ought to write a more effective fiq_save_user_regs */
 508         irq_save_user_regs
 509         bl      do_fiq
 510         irq_restore_user_regs
 511
 512 #else
 513
 514         .align  5
 515 irq:
 516         get_bad_stack
 517         bad_save_user_regs
 518         bl      do_irq
 519
 520         .align  5
 521 fiq:
 522         get_bad_stack
 523         bad_save_user_regs
 524         bl      do_fiq
 525
 526 #endif /* CONFIG_USE_IRQ */
 527 #endif /* CONFIG_SPL_BUILD */