arch/arm/cpu/armv7/start.S

   1 /*
   2  * armboot - Startup Code for OMAP3530/ARM Cortex CPU-core
   3  *
   4  * Copyright (c) 2004   Texas Instruments <r-woodruff2@ti.com>
   5  *
   6  * Copyright (c) 2001   Marius Gröger <mag@sysgo.de>
   7  * Copyright (c) 2002   Alex Züpke <azu@sysgo.de>
   8  * Copyright (c) 2002   Gary Jennejohn <garyj@denx.de>
   9  * Copyright (c) 2003   Richard Woodruff <r-woodruff2@ti.com>
  10  * Copyright (c) 2003   Kshitij <kshitij@ti.com>
  11  * Copyright (c) 2006-2008 Syed Mohammed Khasim <x0khasim@ti.com>
  12  *
  13  * See file CREDITS for list of people who contributed to this
  14  * project.
  15  *
  16  * This program is free software; you can redistribute it and/or
  17  * modify it under the terms of the GNU General Public License as
  18  * published by the Free Software Foundation; either version 2 of
  19  * the License, or (at your option) any later version.
  20  *
  21  * This program is distributed in the hope that it will be useful,
  22  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  23  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24  * GNU General Public License for more details.
  25  *
  26  * You should have received a copy of the GNU General Public License
  27  * along with this program; if not, write to the Free Software
  28  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  29  * MA 02111-1307 USA
  30  */
  31
  32 #include <asm-offsets.h>
  33 #include <config.h>
  34 #include <version.h>
  35
  36 .globl _start
  37 _start: b       reset
  38         ldr     pc, _undefined_instruction
  39         ldr     pc, _software_interrupt
  40         ldr     pc, _prefetch_abort
  41         ldr     pc, _data_abort
  42         ldr     pc, _not_used
  43         ldr     pc, _irq
  44         ldr     pc, _fiq
  45
  46 _undefined_instruction: .word undefined_instruction
  47 _software_interrupt:    .word software_interrupt
  48 _prefetch_abort:        .word prefetch_abort
  49 _data_abort:            .word data_abort
  50 _not_used:              .word not_used
  51 _irq:                   .word irq
  52 _fiq:                   .word fiq
  53 _pad:                   .word 0x12345678 /* now 16*4=64 */
  54 .global _end_vect
  55 _end_vect:
  56
  57         .balignl 16,0xdeadbeef
  58 /*************************************************************************
  59  *
  60  * Startup Code (reset vector)
  61  *
  62  * do important init only if we don't start from memory!
  63  * setup Memory and board specific bits prior to relocation.
  64  * relocate armboot to ram
  65  * setup stack
  66  *
  67  *************************************************************************/
  68
  69 .globl _TEXT_BASE
  70 _TEXT_BASE:
  71         .word   CONFIG_SYS_TEXT_BASE
  72
  73 /*
  74  * These are defined in the board-specific linker script.
  75  */
  76 .globl _bss_start_ofs
  77 _bss_start_ofs:
  78         .word __bss_start - _start
  79
  80 .globl _bss_end_ofs
  81 _bss_end_ofs:
  82         .word _end - _start
  83
  84 #ifdef CONFIG_USE_IRQ
  85 /* IRQ stack memory (calculated at run-time) */
  86 .globl IRQ_STACK_START
  87 IRQ_STACK_START:
  88         .word   0x0badc0de
  89
  90 /* IRQ stack memory (calculated at run-time) */
  91 .globl FIQ_STACK_START
  92 FIQ_STACK_START:
  93         .word 0x0badc0de
  94 #endif
  95
  96 /* IRQ stack memory (calculated at run-time) + 8 bytes */
  97 .globl IRQ_STACK_START_IN
  98 IRQ_STACK_START_IN:
  99         .word   0x0badc0de
 100
 101 .globl _datarel_start_ofs
 102 _datarel_start_ofs:
 103         .word __datarel_start - _start
 104
 105 .globl _datarelrolocal_start_ofs
 106 _datarelrolocal_start_ofs:
 107         .word __datarelrolocal_start - _start
 108
 109 .globl _datarellocal_start_ofs
 110 _datarellocal_start_ofs:
 111         .word __datarellocal_start - _start
 112
 113 .globl _datarelro_start_ofs
 114 _datarelro_start_ofs:
 115         .word __datarelro_start - _start
 116
 117 .globl _got_start_ofs
 118 _got_start_ofs:
 119         .word __got_start - _start
 120
 121 .globl _got_end_Ofs
 122 _got_end_ofs:
 123         .word __got_end - _start
 124
 125 /*
 126  * the actual reset code
 127  */
 128
 129 reset:
 130         /*
 131          * set the cpu to SVC32 mode
 132          */
 133         mrs     r0, cpsr
 134         bic     r0, r0, #0x1f
 135         orr     r0, r0, #0xd3
 136         msr     cpsr,r0
 137
 138 #if (CONFIG_OMAP34XX)
 139         /* Copy vectors to mask ROM indirect addr */
 140         adr     r0, _start              @ r0 <- current position of code
 141         add     r0, r0, #4              @ skip reset vector
 142         mov     r2, #64                 @ r2 <- size to copy
 143         add     r2, r0, r2              @ r2 <- source end address
 144         mov     r1, #SRAM_OFFSET0       @ build vect addr
 145         mov     r3, #SRAM_OFFSET1
 146         add     r1, r1, r3
 147         mov     r3, #SRAM_OFFSET2
 148         add     r1, r1, r3
 149 next:
 150         ldmia   r0!, {r3 - r10}         @ copy from source address [r0]
 151         stmia   r1!, {r3 - r10}         @ copy to   target address [r1]
 152         cmp     r0, r2                  @ until source end address [r2]
 153         bne     next                    @ loop until equal */
 154 #if !defined(CONFIG_SYS_NAND_BOOT) && !defined(CONFIG_SYS_ONENAND_BOOT)
 155         /* No need to copy/exec the clock code - DPLL adjust already done
 156          * in NAND/oneNAND Boot.
 157          */
 158         bl      cpy_clk_code            @ put dpll adjust code behind vectors
 159 #endif /* NAND Boot */
 160 #endif
 161         /* the mask ROM code should have PLL and others stable */
 162 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 163         bl      cpu_init_crit
 164 #endif
 165
 166 /* Set stackpointer in internal RAM to call board_init_f */
 167 call_board_init_f:
 168         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 169         ldr     r0,=0x00000000
 170         bl      board_init_f
 171
 172 /*------------------------------------------------------------------------------*/
 173
 174 /*
 175  * void relocate_code (addr_sp, gd, addr_moni)
 176  *
 177  * This "function" does not return, instead it continues in RAM
 178  * after relocating the monitor code.
 179  *
 180  */
 181         .globl  relocate_code
 182 relocate_code:
 183         mov     r4, r0  /* save addr_sp */
 184         mov     r5, r1  /* save addr of gd */
 185         mov     r6, r2  /* save addr of destination */
 186         mov     r7, r2  /* save addr of destination */
 187
 188         /* Set up the stack                                                 */
 189 stack_setup:
 190         mov     sp, r4
 191
 192 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
 193         adr     r0, _start
 194         ldr     r2, _TEXT_BASE
 195         ldr     r3, _bss_start_ofs
 196         add     r2, r0, r3              /* r2 <- source end address         */
 197         cmp     r0, r6
 198 #ifndef CONFIG_PRELOADER
 199         beq     jump_2_ram
 200 #endif
 201
 202 copy_loop:
 203         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 204         stmia   r6!, {r9-r10}           /* copy to   target address [r1]    */
 205         cmp     r0, r2                  /* until source end address [r2]    */
 206         blo     copy_loop
 207
 208 #ifndef CONFIG_PRELOADER
 209         /*
 210          * fix .rel.dyn relocations
 211          */
 212         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 213         sub     r9, r7, r0              /* r9 <- relocation offset */
 214         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 215         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 216         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 217         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 218         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 219         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 220 fixloop:
 221         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 222         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 223         ldr     r1, [r2, #4]
 224         and     r8, r1, #0xff
 225         cmp     r8, #23                 /* relative fixup? */
 226         beq     fixrel
 227         cmp     r8, #2                  /* absolute fixup? */
 228         beq     fixabs
 229         /* ignore unknown type of fixup */
 230         b       fixnext
 231 fixabs:
 232         /* absolute fix: set location to (offset) symbol value */
 233         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 234         add     r1, r10, r1             /* r1 <- address of symbol in table */
 235         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 236         add     r1, r9                  /* r1 <- relocated sym addr */
 237         b       fixnext
 238 fixrel:
 239         /* relative fix: increase location by offset */
 240         ldr     r1, [r0]
 241         add     r1, r1, r9
 242 fixnext:
 243         str     r1, [r0]
 244         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 245         cmp     r2, r3
 246         blo     fixloop
 247
 248 clear_bss:
 249         ldr     r0, _bss_start_ofs
 250         ldr     r1, _bss_end_ofs
 251         ldr     r3, _TEXT_BASE          /* Text base */
 252         mov     r4, r7                  /* reloc addr */
 253         add     r0, r0, r4
 254         add     r1, r1, r4
 255         mov     r2, #0x00000000         /* clear                            */
 256
 257 clbss_l:str     r2, [r0]                /* clear loop...                    */
 258         add     r0, r0, #4
 259         cmp     r0, r1
 260         bne     clbss_l
 261 #endif  /* #ifndef CONFIG_PRELOADER */
 262 #endif  /* #ifndef CONFIG_SKIP_RELOCATE_UBOOT */
 263
 264 /*
 265  * We are done. Do not return, instead branch to second part of board
 266  * initialization, now running from RAM.
 267  */
 268 jump_2_ram:
 269         ldr     r0, _board_init_r_ofs
 270         adr     r1, _start
 271         add     lr, r0, r1
 272 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
 273         add     lr, lr, r9
 274 #endif
 275         /* setup parameters for board_init_r */
 276         mov     r0, r5          /* gd_t */
 277         mov     r1, r7          /* dest_addr */
 278         /* jump to it ... */
 279         mov     pc, lr
 280
 281 _board_init_r_ofs:
 282         .word board_init_r - _start
 283
 284 _rel_dyn_start_ofs:
 285         .word __rel_dyn_start - _start
 286 _rel_dyn_end_ofs:
 287         .word __rel_dyn_end - _start
 288 _dynsym_start_ofs:
 289         .word __dynsym_start - _start
 290
 291 /*************************************************************************
 292  *
 293  * CPU_init_critical registers
 294  *
 295  * setup important registers
 296  * setup memory timing
 297  *
 298  *************************************************************************/
 299 cpu_init_crit:
 300         /*
 301          * Invalidate L1 I/D
 302          */
 303         mov     r0, #0                  @ set up for MCR
 304         mcr     p15, 0, r0, c8, c7, 0   @ invalidate TLBs
 305         mcr     p15, 0, r0, c7, c5, 0   @ invalidate icache
 306
 307         /*
 308          * disable MMU stuff and caches
 309          */
 310         mrc     p15, 0, r0, c1, c0, 0
 311         bic     r0, r0, #0x00002000     @ clear bits 13 (--V-)
 312         bic     r0, r0, #0x00000007     @ clear bits 2:0 (-CAM)
 313         orr     r0, r0, #0x00000002     @ set bit 1 (--A-) Align
 314         orr     r0, r0, #0x00000800     @ set bit 12 (Z---) BTB
 315         mcr     p15, 0, r0, c1, c0, 0
 316
 317         /*
 318          * Jump to board specific initialization...
 319          * The Mask ROM will have already initialized
 320          * basic memory. Go here to bump up clock rate and handle
 321          * wake up conditions.
 322          */
 323         mov     ip, lr                  @ persevere link reg across call
 324         bl      lowlevel_init           @ go setup pll,mux,memory
 325         mov     lr, ip                  @ restore link
 326         mov     pc, lr                  @ back to my caller
 327 /*
 328  *************************************************************************
 329  *
 330  * Interrupt handling
 331  *
 332  *************************************************************************
 333  */
 334 @
 335 @ IRQ stack frame.
 336 @
 337 #define S_FRAME_SIZE    72
 338
 339 #define S_OLD_R0        68
 340 #define S_PSR           64
 341 #define S_PC            60
 342 #define S_LR            56
 343 #define S_SP            52
 344
 345 #define S_IP            48
 346 #define S_FP            44
 347 #define S_R10           40
 348 #define S_R9            36
 349 #define S_R8            32
 350 #define S_R7            28
 351 #define S_R6            24
 352 #define S_R5            20
 353 #define S_R4            16
 354 #define S_R3            12
 355 #define S_R2            8
 356 #define S_R1            4
 357 #define S_R0            0
 358
 359 #define MODE_SVC 0x13
 360 #define I_BIT    0x80
 361
 362 /*
 363  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 364  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 365  */
 366
 367         .macro  bad_save_user_regs
 368         sub     sp, sp, #S_FRAME_SIZE           @ carve out a frame on current
 369                                                 @ user stack
 370         stmia   sp, {r0 - r12}                  @ Save user registers (now in
 371                                                 @ svc mode) r0-r12
 372         ldr     r2, IRQ_STACK_START_IN          @ set base 2 words into abort
 373                                                 @ stack
 374         ldmia   r2, {r2 - r3}                   @ get values for "aborted" pc
 375                                                 @ and cpsr (into parm regs)
 376         add     r0, sp, #S_FRAME_SIZE           @ grab pointer to old stack
 377
 378         add     r5, sp, #S_SP
 379         mov     r1, lr
 380         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 381         mov     r0, sp                          @ save current stack into r0
 382                                                 @ (param register)
 383         .endm
 384
 385         .macro  irq_save_user_regs
 386         sub     sp, sp, #S_FRAME_SIZE
 387         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 388         add     r8, sp, #S_PC                   @ !! R8 NEEDS to be saved !!
 389                                                 @ a reserved stack spot would
 390                                                 @ be good.
 391         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 392         str     lr, [r8, #0]                    @ Save calling PC
 393         mrs     r6, spsr
 394         str     r6, [r8, #4]                    @ Save CPSR
 395         str     r0, [r8, #8]                    @ Save OLD_R0
 396         mov     r0, sp
 397         .endm
 398
 399         .macro  irq_restore_user_regs
 400         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 401         mov     r0, r0
 402         ldr     lr, [sp, #S_PC]                 @ Get PC
 403         add     sp, sp, #S_FRAME_SIZE
 404         subs    pc, lr, #4                      @ return & move spsr_svc into
 405                                                 @ cpsr
 406         .endm
 407
 408         .macro get_bad_stack
 409         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack (enter
 410                                                 @ in banked mode)
 411
 412         str     lr, [r13]                       @ save caller lr in position 0
 413                                                 @ of saved stack
 414         mrs     lr, spsr                        @ get the spsr
 415         str     lr, [r13, #4]                   @ save spsr in position 1 of
 416                                                 @ saved stack
 417
 418         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 419         @ msr   spsr_c, r13
 420         msr     spsr, r13                       @ switch modes, make sure
 421                                                 @ moves will execute
 422         mov     lr, pc                          @ capture return pc
 423         movs    pc, lr                          @ jump to next instruction &
 424                                                 @ switch modes.
 425         .endm
 426
 427         .macro get_bad_stack_swi
 428         sub     r13, r13, #4                    @ space on current stack for
 429                                                 @ scratch reg.
 430         str     r0, [r13]                       @ save R0's value.
 431         ldr     r0, IRQ_STACK_START_IN          @ get data regions start
 432                                                 @ spots for abort stack
 433         str     lr, [r0]                        @ save caller lr in position 0
 434                                                 @ of saved stack
 435         mrs     r0, spsr                        @ get the spsr
 436         str     lr, [r0, #4]                    @ save spsr in position 1 of
 437                                                 @ saved stack
 438         ldr     r0, [r13]                       @ restore r0
 439         add     r13, r13, #4                    @ pop stack entry
 440         .endm
 441
 442         .macro get_irq_stack                    @ setup IRQ stack
 443         ldr     sp, IRQ_STACK_START
 444         .endm
 445
 446         .macro get_fiq_stack                    @ setup FIQ stack
 447         ldr     sp, FIQ_STACK_START
 448         .endm
 449
 450 /*
 451  * exception handlers
 452  */
 453         .align  5
 454 undefined_instruction:
 455         get_bad_stack
 456         bad_save_user_regs
 457         bl      do_undefined_instruction
 458
 459         .align  5
 460 software_interrupt:
 461         get_bad_stack_swi
 462         bad_save_user_regs
 463         bl      do_software_interrupt
 464
 465         .align  5
 466 prefetch_abort:
 467         get_bad_stack
 468         bad_save_user_regs
 469         bl      do_prefetch_abort
 470
 471         .align  5
 472 data_abort:
 473         get_bad_stack
 474         bad_save_user_regs
 475         bl      do_data_abort
 476
 477         .align  5
 478 not_used:
 479         get_bad_stack
 480         bad_save_user_regs
 481         bl      do_not_used
 482
 483 #ifdef CONFIG_USE_IRQ
 484
 485         .align  5
 486 irq:
 487         get_irq_stack
 488         irq_save_user_regs
 489         bl      do_irq
 490         irq_restore_user_regs
 491
 492         .align  5
 493 fiq:
 494         get_fiq_stack
 495         /* someone ought to write a more effective fiq_save_user_regs */
 496         irq_save_user_regs
 497         bl      do_fiq
 498         irq_restore_user_regs
 499
 500 #else
 501
 502         .align  5
 503 irq:
 504         get_bad_stack
 505         bad_save_user_regs
 506         bl      do_irq
 507
 508         .align  5
 509 fiq:
 510         get_bad_stack
 511         bad_save_user_regs
 512         bl      do_fiq
 513
 514 #endif