arch/arm/cpu/armv8/cache.S

   1 /*
   2  * (C) Copyright 2013
   3  * David Feng <fenghua@phytium.com.cn>
   4  *
   5  * This file is based on sample code from ARMv8 ARM.
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 #include <asm-offsets.h>
  11 #include <config.h>
  12 #include <version.h>
  13 #include <asm/macro.h>
  14 #include <linux/linkage.h>
  15
  16 /*
  17  * void __asm_flush_dcache_level(level)
  18  *
  19  * clean and invalidate one level cache.
  20  *
  21  * x0: cache level
  22  * x1: 0 flush & invalidate, 1 invalidate only
  23  * x2~x9: clobbered
  24  */
  25 ENTRY(__asm_flush_dcache_level)
  26         lsl     x12, x0, #1
  27         msr     csselr_el1, x12         /* select cache level */
  28         isb                             /* sync change of cssidr_el1 */
  29         mrs     x6, ccsidr_el1          /* read the new cssidr_el1 */
  30         and     x2, x6, #7              /* x2 <- log2(cache line size)-4 */
  31         add     x2, x2, #4              /* x2 <- log2(cache line size) */
  32         mov     x3, #0x3ff
  33         and     x3, x3, x6, lsr #3      /* x3 <- max number of #ways */
  34         clz     w5, w3                  /* bit position of #ways */
  35         mov     x4, #0x7fff
  36         and     x4, x4, x6, lsr #13     /* x4 <- max number of #sets */
  37         /* x12 <- cache level << 1 */
  38         /* x2 <- line length offset */
  39         /* x3 <- number of cache ways - 1 */
  40         /* x4 <- number of cache sets - 1 */
  41         /* x5 <- bit position of #ways */
  42
  43 loop_set:
  44         mov     x6, x3                  /* x6 <- working copy of #ways */
  45 loop_way:
  46         lsl     x7, x6, x5
  47         orr     x9, x12, x7             /* map way and level to cisw value */
  48         lsl     x7, x4, x2
  49         orr     x9, x9, x7              /* map set number to cisw value */
  50         tbz     w1, #0, 1f
  51         dc      isw, x9
  52         b       2f
  53 1:      dc      cisw, x9                /* clean & invalidate by set/way */
  54 2:      subs    x6, x6, #1              /* decrement the way */
  55         b.ge    loop_way
  56         subs    x4, x4, #1              /* decrement the set */
  57         b.ge    loop_set
  58
  59         ret
  60 ENDPROC(__asm_flush_dcache_level)
  61
  62 /*
  63  * void __asm_flush_dcache_all(int invalidate_only)
  64  *
  65  * x0: 0 flush & invalidate, 1 invalidate only
  66  *
  67  * clean and invalidate all data cache by SET/WAY.
  68  */
  69 ENTRY(__asm_dcache_all)
  70         mov     x1, x0
  71         dsb     sy
  72         mrs     x10, clidr_el1          /* read clidr_el1 */
  73         lsr     x11, x10, #24
  74         and     x11, x11, #0x7          /* x11 <- loc */
  75         cbz     x11, finished           /* if loc is 0, exit */
  76         mov     x15, lr
  77         mov     x0, #0                  /* start flush at cache level 0 */
  78         /* x0  <- cache level */
  79         /* x10 <- clidr_el1 */
  80         /* x11 <- loc */
  81         /* x15 <- return address */
  82
  83 loop_level:
  84         lsl     x12, x0, #1
  85         add     x12, x12, x0            /* x0 <- tripled cache level */
  86         lsr     x12, x10, x12
  87         and     x12, x12, #7            /* x12 <- cache type */
  88         cmp     x12, #2
  89         b.lt    skip                    /* skip if no cache or icache */
  90         bl      __asm_flush_dcache_level        /* x1 = 0 flush, 1 invalidate */
  91 skip:
  92         add     x0, x0, #1              /* increment cache level */
  93         cmp     x11, x0
  94         b.gt    loop_level
  95
  96         mov     x0, #0
  97         msr     csselr_el1, x0          /* restore csselr_el1 */
  98         dsb     sy
  99         isb
 100         mov     lr, x15
 101
 102 finished:
 103         ret
 104 ENDPROC(__asm_dcache_all)
 105
 106 ENTRY(__asm_flush_dcache_all)
 107         mov     x16, lr
 108         mov     x0, #0
 109         bl      __asm_dcache_all
 110         mov     lr, x16
 111         ret
 112 ENDPROC(__asm_flush_dcache_all)
 113
 114 ENTRY(__asm_invalidate_dcache_all)
 115         mov     x16, lr
 116         mov     x0, #0xffff
 117         bl      __asm_dcache_all
 118         mov     lr, x16
 119         ret
 120 ENDPROC(__asm_invalidate_dcache_all)
 121
 122 /*
 123  * void __asm_flush_dcache_range(start, end)
 124  *
 125  * clean & invalidate data cache in the range
 126  *
 127  * x0: start address
 128  * x1: end address
 129  */
 130 ENTRY(__asm_flush_dcache_range)
 131         mrs     x3, ctr_el0
 132         lsr     x3, x3, #16
 133         and     x3, x3, #0xf
 134         mov     x2, #4
 135         lsl     x2, x2, x3              /* cache line size */
 136
 137         /* x2 <- minimal cache line size in cache system */
 138         sub     x3, x2, #1
 139         bic     x0, x0, x3
 140 1:      dc      civac, x0       /* clean & invalidate data or unified cache */
 141         add     x0, x0, x2
 142         cmp     x0, x1
 143         b.lo    1b
 144         dsb     sy
 145         ret
 146 ENDPROC(__asm_flush_dcache_range)
 147
 148 /*
 149  * void __asm_invalidate_icache_all(void)
 150  *
 151  * invalidate all tlb entries.
 152  */
 153 ENTRY(__asm_invalidate_icache_all)
 154         ic      ialluis
 155         isb     sy
 156         ret
 157 ENDPROC(__asm_invalidate_icache_all)