arch/arm/cpu/lh7a40x/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <garyj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 #include <asm-offsets.h>
  28 #include <config.h>
  29 #include <version.h>
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       reset
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (reset vector)
  65  *
  66  * do important init only if we don't start from memory!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 .globl _TEXT_BASE
  75 _TEXT_BASE:
  76         .word   CONFIG_SYS_TEXT_BASE
  77
  78 /*
  79  * These are defined in the board-specific linker script.
  80  * Subtracting _start from them lets the linker put their
  81  * relative position in the executable instead of leaving
  82  * them null.
  83  */
  84 .globl _bss_start_ofs
  85 _bss_start_ofs:
  86         .word __bss_start - _start
  87
  88 .globl _bss_end_ofs
  89 _bss_end_ofs:
  90         .word _end - _start
  91
  92 #ifdef CONFIG_USE_IRQ
  93 /* IRQ stack memory (calculated at run-time) */
  94 .globl IRQ_STACK_START
  95 IRQ_STACK_START:
  96         .word   0x0badc0de
  97
  98 /* IRQ stack memory (calculated at run-time) */
  99 .globl FIQ_STACK_START
 100 FIQ_STACK_START:
 101         .word 0x0badc0de
 102 #endif
 103
 104 /* IRQ stack memory (calculated at run-time) + 8 bytes */
 105 .globl IRQ_STACK_START_IN
 106 IRQ_STACK_START_IN:
 107         .word   0x0badc0de
 108
 109 /*
 110  * the actual reset code
 111  */
 112
 113 reset:
 114         /*
 115          * set the cpu to SVC32 mode
 116          */
 117         mrs     r0,cpsr
 118         bic     r0,r0,#0x1f
 119         orr     r0,r0,#0xd3
 120         msr     cpsr,r0
 121
 122 #define pWDTCTL         0x80001400  /* Watchdog Timer control register */
 123 #define pINTENC         0x8000050C  /* Interupt-Controller enable clear register */
 124 #define pCLKSET         0x80000420  /* clock divisor register */
 125
 126         /* disable watchdog, set watchdog control register to
 127          * all zeros (default reset)
 128          */
 129         ldr     r0, =pWDTCTL
 130         mov     r1, #0x0
 131         str     r1, [r0]
 132
 133         /*
 134          * mask all IRQs by setting all bits in the INTENC register (default)
 135          */
 136         mov     r1, #0xffffffff
 137         ldr     r0, =pINTENC
 138         str     r1, [r0]
 139
 140         /* FCLK:HCLK:PCLK = 1:2:2 */
 141         /* default FCLK is 200 MHz, using 14.7456 MHz fin */
 142         ldr     r0, =pCLKSET
 143         ldr r1, =0x0004ee39
 144 @       ldr r1, =0x0005ee39     @ 1: 2: 4
 145         str     r1, [r0]
 146
 147         /*
 148          * we do sys-critical inits only at reboot,
 149          * not when booting from ram!
 150          */
 151 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 152         bl      cpu_init_crit
 153 #endif
 154
 155 /* Set stackpointer in internal RAM to call board_init_f */
 156 call_board_init_f:
 157         ldr     sp, =(CONFIG_SYS_INIT_SP_ADDR)
 158         ldr     r0,=0x00000000
 159         bl      board_init_f
 160
 161 /*------------------------------------------------------------------------------*/
 162
 163 /*
 164  * void relocate_code (addr_sp, gd, addr_moni)
 165  *
 166  * This "function" does not return, instead it continues in RAM
 167  * after relocating the monitor code.
 168  *
 169  */
 170         .globl  relocate_code
 171 relocate_code:
 172         mov     r4, r0  /* save addr_sp */
 173         mov     r5, r1  /* save addr of gd */
 174         mov     r6, r2  /* save addr of destination */
 175         mov     r7, r2  /* save addr of destination */
 176
 177         /* Set up the stack                                                 */
 178 stack_setup:
 179         mov     sp, r4
 180
 181         adr     r0, _start
 182         ldr     r2, _TEXT_BASE
 183         ldr     r3, _bss_start_ofs
 184         add     r2, r0, r3              /* r2 <- source end address         */
 185         cmp     r0, r6
 186         beq     clear_bss
 187
 188 copy_loop:
 189         ldmia   r0!, {r9-r10}           /* copy from source address [r0]    */
 190         stmia   r6!, {r9-r10}           /* copy to   target address [r1]    */
 191         cmp     r0, r2                  /* until source end address [r2]    */
 192         blo     copy_loop
 193
 194 #ifndef CONFIG_PRELOADER
 195         /*
 196          * fix .rel.dyn relocations
 197          */
 198         ldr     r0, _TEXT_BASE          /* r0 <- Text base */
 199         sub     r9, r7, r0              /* r9 <- relocation offset */
 200         ldr     r10, _dynsym_start_ofs  /* r10 <- sym table ofs */
 201         add     r10, r10, r0            /* r10 <- sym table in FLASH */
 202         ldr     r2, _rel_dyn_start_ofs  /* r2 <- rel dyn start ofs */
 203         add     r2, r2, r0              /* r2 <- rel dyn start in FLASH */
 204         ldr     r3, _rel_dyn_end_ofs    /* r3 <- rel dyn end ofs */
 205         add     r3, r3, r0              /* r3 <- rel dyn end in FLASH */
 206 fixloop:
 207         ldr     r0, [r2]                /* r0 <- location to fix up, IN FLASH! */
 208         add     r0, r0, r9              /* r0 <- location to fix up in RAM */
 209         ldr     r1, [r2, #4]
 210         and     r8, r1, #0xff
 211         cmp     r8, #23                 /* relative fixup? */
 212         beq     fixrel
 213         cmp     r8, #2                  /* absolute fixup? */
 214         beq     fixabs
 215         /* ignore unknown type of fixup */
 216         b       fixnext
 217 fixabs:
 218         /* absolute fix: set location to (offset) symbol value */
 219         mov     r1, r1, LSR #4          /* r1 <- symbol index in .dynsym */
 220         add     r1, r10, r1             /* r1 <- address of symbol in table */
 221         ldr     r1, [r1, #4]            /* r1 <- symbol value */
 222         add     r1, r9                  /* r1 <- relocated sym addr */
 223         b       fixnext
 224 fixrel:
 225         /* relative fix: increase location by offset */
 226         ldr     r1, [r0]
 227         add     r1, r1, r9
 228 fixnext:
 229         str     r1, [r0]
 230         add     r2, r2, #8              /* each rel.dyn entry is 8 bytes */
 231         cmp     r2, r3
 232         blo     fixloop
 233 #endif
 234
 235 clear_bss:
 236 #ifndef CONFIG_PRELOADER
 237         ldr     r0, _bss_start_ofs
 238         ldr     r1, _bss_end_ofs
 239         ldr     r3, _TEXT_BASE          /* Text base */
 240         mov     r4, r7                  /* reloc addr */
 241         add     r0, r0, r4
 242         add     r1, r1, r4
 243         mov     r2, #0x00000000         /* clear                            */
 244
 245 clbss_l:str     r2, [r0]                /* clear loop...                    */
 246         add     r0, r0, #4
 247         cmp     r0, r1
 248         bne     clbss_l
 249 #endif
 250
 251 /*
 252  * We are done. Do not return, instead branch to second part of board
 253  * initialization, now running from RAM.
 254  */
 255         ldr     r0, _board_init_r_ofs
 256         adr     r1, _start
 257         add     lr, r0, r1
 258         add     lr, lr, r9
 259         /* setup parameters for board_init_r */
 260         mov     r0, r5          /* gd_t */
 261         mov     r1, r7          /* dest_addr */
 262         /* jump to it ... */
 263         mov     pc, lr
 264
 265 _board_init_r_ofs:
 266         .word board_init_r - _start
 267
 268 _rel_dyn_start_ofs:
 269         .word __rel_dyn_start - _start
 270 _rel_dyn_end_ofs:
 271         .word __rel_dyn_end - _start
 272 _dynsym_start_ofs:
 273         .word __dynsym_start - _start
 274
 275 /*
 276  *************************************************************************
 277  *
 278  * CPU_init_critical registers
 279  *
 280  * setup important registers
 281  * setup memory timing
 282  *
 283  *************************************************************************
 284  */
 285
 286
 287 cpu_init_crit:
 288         /*
 289          * flush v4 I/D caches
 290          */
 291         mov     r0, #0
 292         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 293         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 294
 295         /*
 296          * disable MMU stuff and caches
 297          */
 298         mrc     p15, 0, r0, c1, c0, 0
 299         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 300         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 301         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 302         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 303         orr     r0, r0, #0x40000000     @ set bit 30 (nF) notFastBus
 304         mcr     p15, 0, r0, c1, c0, 0
 305
 306
 307         /*
 308          * before relocating, we have to setup RAM timing
 309          * because memory timing is board-dependend, you will
 310          * find a lowlevel_init.S in your board directory.
 311          */
 312         mov     ip, lr
 313         bl      lowlevel_init
 314         mov     lr, ip
 315
 316         mov     pc, lr
 317
 318
 319 /*
 320  *************************************************************************
 321  *
 322  * Interrupt handling
 323  *
 324  *************************************************************************
 325  */
 326
 327 @
 328 @ IRQ stack frame.
 329 @
 330 #define S_FRAME_SIZE    72
 331
 332 #define S_OLD_R0        68
 333 #define S_PSR           64
 334 #define S_PC            60
 335 #define S_LR            56
 336 #define S_SP            52
 337
 338 #define S_IP            48
 339 #define S_FP            44
 340 #define S_R10           40
 341 #define S_R9            36
 342 #define S_R8            32
 343 #define S_R7            28
 344 #define S_R6            24
 345 #define S_R5            20
 346 #define S_R4            16
 347 #define S_R3            12
 348 #define S_R2            8
 349 #define S_R1            4
 350 #define S_R0            0
 351
 352 #define MODE_SVC 0x13
 353 #define I_BIT    0x80
 354
 355 /*
 356  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 357  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 358  */
 359
 360         .macro  bad_save_user_regs
 361         sub     sp, sp, #S_FRAME_SIZE
 362         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 363         ldr     r2, IRQ_STACK_START_IN
 364         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 365         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 366
 367         add     r5, sp, #S_SP
 368         mov     r1, lr
 369         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 370         mov     r0, sp
 371         .endm
 372
 373         .macro  irq_save_user_regs
 374         sub     sp, sp, #S_FRAME_SIZE
 375         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 376         add     r8, sp, #S_PC
 377         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 378         str     lr, [r8, #0]                    @ Save calling PC
 379         mrs     r6, spsr
 380         str     r6, [r8, #4]                    @ Save CPSR
 381         str     r0, [r8, #8]                    @ Save OLD_R0
 382         mov     r0, sp
 383         .endm
 384
 385         .macro  irq_restore_user_regs
 386         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 387         mov     r0, r0
 388         ldr     lr, [sp, #S_PC]                 @ Get PC
 389         add     sp, sp, #S_FRAME_SIZE
 390         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 391         .endm
 392
 393         .macro get_bad_stack
 394         ldr     r13, IRQ_STACK_START_IN         @ setup our mode stack
 395
 396         str     lr, [r13]                       @ save caller lr / spsr
 397         mrs     lr, spsr
 398         str     lr, [r13, #4]
 399
 400         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 401         @ msr   spsr_c, r13
 402         msr     spsr, r13
 403         mov     lr, pc
 404         movs    pc, lr
 405         .endm
 406
 407         .macro get_irq_stack                    @ setup IRQ stack
 408         ldr     sp, IRQ_STACK_START
 409         .endm
 410
 411         .macro get_fiq_stack                    @ setup FIQ stack
 412         ldr     sp, FIQ_STACK_START
 413         .endm
 414
 415 /*
 416  * exception handlers
 417  */
 418         .align  5
 419 undefined_instruction:
 420         get_bad_stack
 421         bad_save_user_regs
 422         bl      do_undefined_instruction
 423
 424         .align  5
 425 software_interrupt:
 426         get_bad_stack
 427         bad_save_user_regs
 428         bl      do_software_interrupt
 429
 430         .align  5
 431 prefetch_abort:
 432         get_bad_stack
 433         bad_save_user_regs
 434         bl      do_prefetch_abort
 435
 436         .align  5
 437 data_abort:
 438         get_bad_stack
 439         bad_save_user_regs
 440         bl      do_data_abort
 441
 442         .align  5
 443 not_used:
 444         get_bad_stack
 445         bad_save_user_regs
 446         bl      do_not_used
 447
 448 #ifdef CONFIG_USE_IRQ
 449
 450         .align  5
 451 irq:
 452         get_irq_stack
 453         irq_save_user_regs
 454         bl      do_irq
 455         irq_restore_user_regs
 456
 457         .align  5
 458 fiq:
 459         get_fiq_stack
 460         /* someone ought to write a more effiction fiq_save_user_regs */
 461         irq_save_user_regs
 462         bl      do_fiq
 463         irq_restore_user_regs
 464
 465 #else
 466
 467         .align  5
 468 irq:
 469         get_bad_stack
 470         bad_save_user_regs
 471         bl      do_irq
 472
 473         .align  5
 474 fiq:
 475         get_bad_stack
 476         bad_save_user_regs
 477         bl      do_fiq
 478
 479 #endif
 480
 481         .align  5
 482 .globl reset_cpu
 483 reset_cpu:
 484         bl      disable_interrupts
 485
 486         /* Disable watchdog */
 487         ldr     r1, =pWDTCTL
 488         mov     r3, #0
 489         str     r3, [r1]
 490
 491         /* reset counter */
 492         ldr     r3, =0x00001984
 493         str     r3, [r1, #4]
 494
 495         /* Enable the watchdog */
 496         mov     r3, #1
 497         str     r3, [r1]
 498
 499 _loop_forever:
 500         b       _loop_forever