arch/arm/cpu/u-boot-spl.lds

   1 /*
   2  * Copyright (c) 2004-2008 Texas Instruments
   3  *
   4  * (C) Copyright 2002
   5  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  27 OUTPUT_ARCH(arm)
  28 ENTRY(_start)
  29 SECTIONS
  30 {
  31         . = 0x00000000;
  32
  33         . = ALIGN(4);
  34         .text :
  35         {
  36                 __image_copy_start = .;
  37                 CPUDIR/start.o (.text*)
  38                 *(.text*)
  39         }
  40
  41         . = ALIGN(4);
  42         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  43
  44         . = ALIGN(4);
  45         .data : {
  46                 *(.data*)
  47         }
  48
  49         . = ALIGN(4);
  50
  51         . = .;
  52
  53         __image_copy_end = .;
  54
  55         .rel.dyn : {
  56                 __rel_dyn_start = .;
  57                 *(.rel*)
  58                 __rel_dyn_end = .;
  59         }
  60
  61         .dynsym : {
  62                 __dynsym_start = .;
  63                 *(.dynsym)
  64         }
  65
  66         _end = .;
  67
  68         /*
  69          * Deprecated: this MMU section is used by pxa at present but
  70          * should not be used by new boards/CPUs.
  71          */
  72         . = ALIGN(4096);
  73         .mmutable : {
  74                 *(.mmutable)
  75         }
  76
  77         .bss __rel_dyn_start (OVERLAY) : {
  78                 __bss_start = .;
  79                 *(.bss*)
  80                  . = ALIGN(4);
  81                 __bss_end = .;
  82         }
  83
  84         /DISCARD/ : { *(.dynstr*) }
  85         /DISCARD/ : { *(.dynamic*) }
  86         /DISCARD/ : { *(.plt*) }
  87         /DISCARD/ : { *(.interp*) }
  88         /DISCARD/ : { *(.gnu*) }
  89 }
  90
  91 #if defined(CONFIG_SPL_TEXT_BASE) && defined(CONFIG_SPL_MAX_SIZE)
  92 ASSERT(__bss_end < (CONFIG_SPL_TEXT_BASE + CONFIG_SPL_MAX_SIZE), "SPL image too big");
  93 #endif