arch/arm/cpu/u-boot-spl.lds

   1 /*
   2  * Copyright (c) 2004-2008 Texas Instruments
   3  *
   4  * (C) Copyright 2002
   5  * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  11 OUTPUT_ARCH(arm)
  12 ENTRY(_start)
  13 SECTIONS
  14 {
  15         . = 0x00000000;
  16
  17         . = ALIGN(4);
  18         .text :
  19         {
  20                 __image_copy_start = .;
  21                 CPUDIR/start.o (.text*)
  22                 *(.text*)
  23         }
  24
  25         . = ALIGN(4);
  26         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  27
  28         . = ALIGN(4);
  29         .data : {
  30                 *(.data*)
  31         }
  32
  33         . = ALIGN(4);
  34
  35         . = .;
  36
  37         __image_copy_end = .;
  38
  39         .rel.dyn : {
  40                 __rel_dyn_start = .;
  41                 *(.rel*)
  42                 __rel_dyn_end = .;
  43         }
  44
  45         _end = .;
  46
  47         .bss __rel_dyn_start (OVERLAY) : {
  48                 __bss_start = .;
  49                 *(.bss*)
  50                  . = ALIGN(4);
  51                 __bss_end = .;
  52         }
  53
  54         .dynsym _end : { *(.dynsym) }
  55         .dynbss : { *(.dynbss) }
  56         .dynstr : { *(.dynstr*) }
  57         .dynamic : { *(.dynamic*) }
  58         .hash : { *(.hash*) }
  59         .plt : { *(.plt*) }
  60         .interp : { *(.interp*) }
  61         .gnu : { *(.gnu*) }
  62         .ARM.exidx : { *(.ARM.exidx*) }
  63 }
  64
  65 #if defined(CONFIG_SPL_MAX_SIZE)
  66 ASSERT(__image_copy_end - __image_copy_start < (CONFIG_SPL_MAX_SIZE), \
  67         "SPL image too big");
  68 #endif
  69
  70 #if defined(CONFIG_SPL_BSS_MAX_SIZE)
  71 ASSERT(__bss_end - __bss_start < (CONFIG_SPL_BSS_MAX_SIZE), \
  72         "SPL image BSS too big");
  73 #endif
  74
  75 #if defined(CONFIG_SPL_MAX_FOOTPRINT)
  76 ASSERT(__bss_end - _start < (CONFIG_SPL_MAX_FOOTPRINT), \
  77         "SPL image plus BSS too big");
  78 #endif