arch/arm/lib/crt0_64.S

   1 /*
   2  * crt0 - C-runtime startup Code for AArch64 U-Boot
   3  *
   4  * (C) Copyright 2013
   5  * David Feng <fenghua@phytium.com.cn>
   6  *
   7  * (C) Copyright 2012
   8  * Albert ARIBAUD <albert.u.boot@aribaud.net>
   9  *
  10  * SPDX-License-Identifier:     GPL-2.0+
  11  */
  12
  13 #include <config.h>
  14 #include <asm-offsets.h>
  15 #include <asm/macro.h>
  16 #include <linux/linkage.h>
  17
  18 /*
  19  * This file handles the target-independent stages of the U-Boot
  20  * start-up where a C runtime environment is needed. Its entry point
  21  * is _main and is branched into from the target's start.S file.
  22  *
  23  * _main execution sequence is:
  24  *
  25  * 1. Set up initial environment for calling board_init_f().
  26  *    This environment only provides a stack and a place to store
  27  *    the GD ('global data') structure, both located in some readily
  28  *    available RAM (SRAM, locked cache...). In this context, VARIABLE
  29  *    global data, initialized or not (BSS), are UNAVAILABLE; only
  30  *    CONSTANT initialized data are available.
  31  *
  32  * 2. Call board_init_f(). This function prepares the hardware for
  33  *    execution from system RAM (DRAM, DDR...) As system RAM may not
  34  *    be available yet, , board_init_f() must use the current GD to
  35  *    store any data which must be passed on to later stages. These
  36  *    data include the relocation destination, the future stack, and
  37  *    the future GD location.
  38  *
  39  * (the following applies only to non-SPL builds)
  40  *
  41  * 3. Set up intermediate environment where the stack and GD are the
  42  *    ones allocated by board_init_f() in system RAM, but BSS and
  43  *    initialized non-const data are still not available.
  44  *
  45  * 4. Call relocate_code(). This function relocates U-Boot from its
  46  *    current location into the relocation destination computed by
  47  *    board_init_f().
  48  *
  49  * 5. Set up final environment for calling board_init_r(). This
  50  *    environment has BSS (initialized to 0), initialized non-const
  51  *    data (initialized to their intended value), and stack in system
  52  *    RAM. GD has retained values set by board_init_f(). Some CPUs
  53  *    have some work left to do at this point regarding memory, so
  54  *    call c_runtime_cpu_setup.
  55  *
  56  * 6. Branch to board_init_r().
  57  */
  58
  59 ENTRY(_main)
  60
  61 /*
  62  * Set up initial C runtime environment and call board_init_f(0).
  63  */
  64         ldr     x0, =(CONFIG_SYS_INIT_SP_ADDR)
  65         sub     x18, x0, #GD_SIZE       /* allocate one GD above SP */
  66         bic     x18, x18, #0x7          /* 8-byte alignment for GD */
  67 zero_gd:
  68         sub     x0, x0, #0x8
  69         str     xzr, [x0]
  70         cmp     x0, x18
  71         b.gt    zero_gd
  72 #if defined(CONFIG_SYS_MALLOC_F_LEN)
  73         sub     x0, x18, #CONFIG_SYS_MALLOC_F_LEN
  74         str     x0, [x18, #GD_MALLOC_BASE]
  75 #endif
  76         bic     sp, x0, #0xf    /* 16-byte alignment for ABI compliance */
  77         mov     x0, #0
  78         bl      board_init_f
  79
  80 /*
  81  * Set up intermediate environment (new sp and gd) and call
  82  * relocate_code(addr_moni). Trick here is that we'll return
  83  * 'here' but relocated.
  84  */
  85         ldr     x0, [x18, #GD_START_ADDR_SP]    /* x0 <- gd->start_addr_sp */
  86         bic     sp, x0, #0xf    /* 16-byte alignment for ABI compliance */
  87         ldr     x18, [x18, #GD_BD]              /* x18 <- gd->bd */
  88         sub     x18, x18, #GD_SIZE              /* new GD is below bd */
  89
  90         adr     lr, relocation_return
  91         ldr     x9, [x18, #GD_RELOC_OFF]        /* x9 <- gd->reloc_off */
  92         add     lr, lr, x9      /* new return address after relocation */
  93         ldr     x0, [x18, #GD_RELOCADDR]        /* x0 <- gd->relocaddr */
  94         b       relocate_code
  95
  96 relocation_return:
  97
  98 /*
  99  * Set up final (full) environment
 100  */
 101         bl      c_runtime_cpu_setup             /* still call old routine */
 102
 103 /*
 104  * Clear BSS section
 105  */
 106         ldr     x0, =__bss_start                /* this is auto-relocated! */
 107         ldr     x1, =__bss_end                  /* this is auto-relocated! */
 108         mov     x2, #0
 109 clear_loop:
 110         str     x2, [x0]
 111         add     x0, x0, #8
 112         cmp     x0, x1
 113         b.lo    clear_loop
 114
 115         /* call board_init_r(gd_t *id, ulong dest_addr) */
 116         mov     x0, x18                         /* gd_t */
 117         ldr     x1, [x18, #GD_RELOCADDR]        /* dest_addr */
 118         b       board_init_r                    /* PC relative jump */
 119
 120         /* NOTREACHED - board_init_r() does not return */
 121
 122 ENDPROC(_main)