arch/powerpc/cpu/mpc8220/u-boot.lds

   1 /*
   2  * (C) Copyright 2003-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   .text      :
  30   {
  31     arch/powerpc/cpu/mpc8220/start.o    (.text*)
  32     *(.text*)
  33     . = ALIGN(16);
  34     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  35   }
  36
  37   /* Read-write section, merged into data segment: */
  38   . = (. + 0x0FFF) & 0xFFFFF000;
  39   _erotext = .;
  40   PROVIDE (erotext = .);
  41   .reloc   :
  42   {
  43     _GOT2_TABLE_ = .;
  44     KEEP(*(.got2))
  45     KEEP(*(.got))
  46     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  47     _FIXUP_TABLE_ = .;
  48     KEEP(*(.fixup))
  49   }
  50   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  51   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  52
  53   .data    :
  54   {
  55     *(.data*)
  56     *(.sdata*)
  57   }
  58   _edata  =  .;
  59   PROVIDE (edata = .);
  60
  61   . = .;
  62
  63   . = ALIGN(4);
  64   .u_boot_list : {
  65         KEEP(*(SORT(.u_boot_list*)));
  66   }
  67
  68
  69   . = .;
  70   __start___ex_table = .;
  71   __ex_table : { *(__ex_table) }
  72   __stop___ex_table = .;
  73
  74   . = ALIGN(4096);
  75   __init_begin = .;
  76   .text.init : { *(.text.init) }
  77   .data.init : { *(.data.init) }
  78   . = ALIGN(4096);
  79   __init_end = .;
  80
  81   __bss_start = .;
  82   .bss (NOLOAD)       :
  83   {
  84    *(.bss*)
  85    *(.sbss*)
  86    *(COMMON)
  87    . = ALIGN(4);
  88   }
  89   __bss_end__ = . ;
  90   PROVIDE (end = .);
  91 }