arch/x86/cpu/start.S

   1 /*
   2  *  U-boot - x86 Startup Code
   3  *
   4  * (C) Copyright 2008-2011
   5  * Graeme Russ, <graeme.russ@gmail.com>
   6  *
   7  * (C) Copyright 2002
   8  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
   9  *
  10  * See file CREDITS for list of people who contributed to this
  11  * project.
  12  *
  13  * This program is free software; you can redistribute it and/or
  14  * modify it under the terms of the GNU General Public License as
  15  * published by the Free Software Foundation; either version 2 of
  16  * the License, or (at your option) any later version.
  17  *
  18  * This program is distributed in the hope that it will be useful,
  19  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  20  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21  * GNU General Public License for more details.
  22  *
  23  * You should have received a copy of the GNU General Public License
  24  * along with this program; if not, write to the Free Software
  25  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  26  * MA 02111-1307 USA
  27  */
  28
  29 #include <config.h>
  30 #include <version.h>
  31 #include <asm/global_data.h>
  32 #include <asm/processor-flags.h>
  33 #include <generated/asm-offsets.h>
  34
  35 .section .text
  36 .code32
  37 .globl _start
  38 .type _start, @function
  39 .globl _x86boot_start
  40 _x86boot_start:
  41         /*
  42          * This is the fail safe 32-bit bootstrap entry point. The
  43          * following code is not executed from a cold-reset (actually, a
  44          * lot of it is, but from real-mode after cold reset. It is
  45          * repeated here to put the board into a state as close to cold
  46          * reset as necessary)
  47          */
  48         cli
  49         cld
  50
  51         /* Turn off cache (this might require a 486-class CPU) */
  52         movl    %cr0, %eax
  53         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  54         movl    %eax, %cr0
  55         wbinvd
  56
  57 _start:
  58         /* This is the 32-bit cold-reset entry point */
  59
  60         /* Load the segement registes to match the gdt loaded in start16.S */
  61         movl    $0x18, %eax
  62         movw    %ax, %fs
  63         movw    %ax, %ds
  64         movw    %ax, %gs
  65         movw    %ax, %es
  66         movw    %ax, %ss
  67
  68         /* Clear the interrupt vectors */
  69         lidt    blank_idt_ptr
  70
  71         /* Early platform init (setup gpio, etc ) */
  72         jmp     early_board_init
  73 .globl early_board_init_ret
  74 early_board_init_ret:
  75
  76         /* Initialise Cache-As-RAM */
  77         jmp     car_init
  78 .globl car_init_ret
  79 car_init_ret:
  80         /*
  81          * We now have CONFIG_SYS_CAR_SIZE bytes of Cache-As-RAM (or SRAM,
  82          * or fully initialised SDRAM - we really don't care which)
  83          * starting at CONFIG_SYS_CAR_ADDR to be used as a temporary stack
  84          */
  85         movl    $CONFIG_SYS_INIT_SP_ADDR, %esp
  86
  87         /* Set parameter to board_init_f() to boot flags */
  88         xorl    %eax, %eax
  89         movw    %bx, %ax
  90
  91         /* Enter, U-boot! */
  92         call    board_init_f
  93
  94         /* indicate (lack of) progress */
  95         movw    $0x85, %ax
  96         jmp     die
  97
  98 .globl relocate_code
  99 .type relocate_code, @function
 100 relocate_code:
 101         /*
 102          * SDRAM has been initialised, U-Boot code has been copied into
 103          * RAM, BSS has been cleared and relocation adjustments have been
 104          * made. It is now time to jump into the in-RAM copy of U-Boot
 105          *
 106          * %eax = Address of top of stack
 107          * %edx = Address of Global Data
 108          * %ecx = Base address of in-RAM copy of U-Boot
 109          */
 110
 111         /* Setup stack in RAM */
 112         movl    %eax, %esp
 113
 114         /* Setup call address of in-RAM copy of board_init_r() */
 115         movl    $board_init_r, %ebp
 116         addl    (GENERATED_GD_RELOC_OFF)(%edx), %ebp
 117
 118         /* Setup parameters to board_init_r() */
 119         movl    %edx, %eax
 120         movl    %ecx, %edx
 121
 122         /* Jump to in-RAM copy of board_init_r() */
 123         call    *%ebp
 124
 125 die:
 126         hlt
 127         jmp     die
 128         hlt
 129
 130 blank_idt_ptr:
 131         .word   0               /* limit */
 132         .long   0               /* base */
 133
 134         .p2align        2       /* force 4-byte alignment */
 135
 136 multiboot_header:
 137         /* magic */
 138         .long   0x1BADB002
 139         /* flags */
 140         .long   (1 << 16)
 141         /* checksum */
 142         .long   -0x1BADB002 - (1 << 16)
 143         /* header addr */
 144         .long   multiboot_header - _x86boot_start + CONFIG_SYS_TEXT_BASE
 145         /* load addr */
 146         .long   CONFIG_SYS_TEXT_BASE
 147         /* load end addr */
 148         .long   0
 149         /* bss end addr */
 150         .long   0
 151         /* entry addr */
 152         .long   CONFIG_SYS_TEXT_BASE