arch/x86/cpu/start16.S

   1 /*
   2  *  U-boot - x86 Startup Code
   3  *
   4  * (C) Copyright 2008-2011
   5  * Graeme Russ, <graeme.russ@gmail.com>
   6  *
   7  * (C) Copyright 2002,2003
   8  * Daniel Engström, Omicron Ceti AB, <daniel@omicron.se>
   9  *
  10  * See file CREDITS for list of people who contributed to this
  11  * project.
  12  *
  13  * This program is free software; you can redistribute it and/or
  14  * modify it under the terms of the GNU General Public License as
  15  * published by the Free Software Foundation; either version 2 of
  16  * the License, or (at your option) any later version.
  17  *
  18  * This program is distributed in the hope that it will be useful,
  19  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  20  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21  * GNU General Public License for more details.
  22  *
  23  * You should have received a copy of the GNU General Public License
  24  * along with this program; if not, write to the Free Software
  25  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  26  * MA 02111-1307 USA
  27  */
  28
  29 #include <asm/global_data.h>
  30 #include <asm/processor-flags.h>
  31
  32 #define BOOT_SEG        0xffff0000      /* linear segment of boot code */
  33 #define a32             .byte 0x67;
  34 #define o32             .byte 0x66;
  35
  36 .section .start16, "ax"
  37 .code16
  38 .globl start16
  39 start16:
  40         /* Set the Cold Boot / Hard Reset flag */
  41         movl    $GD_FLG_COLD_BOOT, %ebx
  42
  43         /*
  44          * First we let the BSP do some early initialization
  45          * this code have to map the flash to its final position
  46          */
  47         jmp     board_init16
  48 .globl board_init16_ret
  49 board_init16_ret:
  50
  51         /* Turn of cache (this might require a 486-class CPU) */
  52         movl    %cr0, %eax
  53         orl     $(X86_CR0_NW | X86_CR0_CD), %eax
  54         movl    %eax, %cr0
  55         wbinvd
  56
  57         /* load the temporary Global Descriptor Table */
  58 o32 cs  lidt    idt_ptr
  59 o32 cs  lgdt    gdt_ptr
  60
  61         /* Now, we enter protected mode */
  62         movl    %cr0, %eax
  63         orl     $X86_CR0_PE, %eax
  64         movl    %eax, %cr0
  65
  66         /* Flush the prefetch queue */
  67         jmp     ff
  68 ff:
  69         /* Finally jump to the 32bit initialization code */
  70         movw    $code32start, %ax
  71         movw    %ax, %bp
  72 o32 cs  ljmp    *(%bp)
  73
  74         /* 48-bit far pointer */
  75 code32start:
  76         .long   _start          /* offset */
  77         .word   0x10            /* segment */
  78
  79 idt_ptr:
  80         .word   0               /* limit */
  81         .long   0               /* base */
  82
  83 /*
  84  * The following Global Descriptor Table is just enough to get us into
  85  * 'Flat Protected Mode' - It will be discarded as soon as the final
  86  * GDT is setup in a safe location in RAM
  87  */
  88 gdt_ptr:
  89         .word   0x20            /* limit (32 bytes = 4 GDT entries) */
  90         .long   BOOT_SEG + gdt  /* base */
  91
  92 /* Some CPUs are picky about GDT alignment... */
  93 .align 16
  94 gdt:
  95         /*
  96          * The GDT table ...
  97          *
  98          *       Selector       Type
  99          *       0x00           NULL
 100          *       0x08           Unused
 101          *       0x10           32bit code
 102          *       0x18           32bit data/stack
 103          */
 104         /* The NULL Desciptor - Mandatory */
 105         .word   0x0000          /* limit_low */
 106         .word   0x0000          /* base_low */
 107         .byte   0x00            /* base_middle */
 108         .byte   0x00            /* access */
 109         .byte   0x00            /* flags + limit_high */
 110         .byte   0x00            /* base_high */
 111
 112         /* Unused Desciptor - (matches Linux) */
 113         .word   0x0000          /* limit_low */
 114         .word   0x0000          /* base_low */
 115         .byte   0x00            /* base_middle */
 116         .byte   0x00            /* access */
 117         .byte   0x00            /* flags + limit_high */
 118         .byte   0x00            /* base_high */
 119
 120         /*
 121          * The Code Segment Descriptor:
 122          * - Base   = 0x00000000
 123          * - Size   = 4GB
 124          * - Access = Present, Ring 0, Exec (Code), Readable
 125          * - Flags  = 4kB Granularity, 32-bit
 126          */
 127         .word   0xffff          /* limit_low */
 128         .word   0x0000          /* base_low */
 129         .byte   0x00            /* base_middle */
 130         .byte   0x9b            /* access */
 131         .byte   0xcf            /* flags + limit_high */
 132         .byte   0x00            /* base_high */
 133
 134         /*
 135          * The Data Segment Descriptor:
 136          * - Base   = 0x00000000
 137          * - Size   = 4GB
 138          * - Access = Present, Ring 0, Non-Exec (Data), Writable
 139          * - Flags  = 4kB Granularity, 32-bit
 140          */
 141         .word   0xffff          /* limit_low */
 142         .word   0x0000          /* base_low */
 143         .byte   0x00            /* base_middle */
 144         .byte   0x93            /* access */
 145         .byte   0xcf            /* flags + limit_high */
 146         .byte   0x00            /* base_high */