arch/x86/cpu/u-boot.lds

   1 /*
   2  * (C) Copyright 2002
   3  * Daniel Engström, Omicron Ceti AB, daniel@omicron.se.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 #include <config.h>
  25 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  26 OUTPUT_ARCH(i386)
  27 ENTRY(_start)
  28
  29 SECTIONS
  30 {
  31         . = CONFIG_SYS_TEXT_BASE;       /* Location of bootcode in flash */
  32         __text_start = .;
  33         .text  : { *(.text*); }
  34
  35         . = ALIGN(4);
  36
  37         . = ALIGN(4);
  38         .u_boot_list : {
  39                 KEEP(*(SORT(.u_boot_list*)));
  40         }
  41
  42         . = ALIGN(4);
  43         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  44
  45         . = ALIGN(4);
  46         .data : { *(.data*) }
  47
  48         . = ALIGN(4);
  49         .hash : { *(.hash*) }
  50
  51         . = ALIGN(4);
  52         .got : { *(.got*) }
  53
  54         . = ALIGN(4);
  55         __data_end = .;
  56         __init_end = .;
  57
  58         . = ALIGN(4);
  59         .dynsym : { *(.dynsym*) }
  60
  61         . = ALIGN(4);
  62         __rel_dyn_start = .;
  63         .rel.dyn : { *(.rel.dyn) }
  64         __rel_dyn_end = .;
  65         . = ALIGN(4);
  66         _end = .;
  67
  68         .bss __rel_dyn_start (OVERLAY) : {
  69                 __bss_start = .;
  70                 *(.bss)
  71                 *(COM*)
  72                 . = ALIGN(4);
  73                 __bss_end = .;
  74         }
  75
  76         /DISCARD/ : { *(.dynstr*) }
  77         /DISCARD/ : { *(.dynamic*) }
  78         /DISCARD/ : { *(.plt*) }
  79         /DISCARD/ : { *(.interp*) }
  80         /DISCARD/ : { *(.gnu*) }
  81
  82         /* 16bit realmode trampoline code */
  83         .realmode REALMODE_BASE : AT ( LOADADDR(.rel.dyn) + SIZEOF(.rel.dyn) ) { KEEP(*(.realmode)) }
  84
  85         __realmode_start = LOADADDR(.realmode);
  86         __realmode_size = SIZEOF(.realmode);
  87
  88         /* 16bit BIOS emulation code (just enough to boot Linux) */
  89         .bios 0 : AT ( LOADADDR(.realmode) + SIZEOF(.realmode) ) { KEEP(*(.bios)) }
  90
  91         __bios_start = LOADADDR(.bios);
  92         __bios_size = SIZEOF(.bios);
  93
  94 #ifdef CONFIG_X86_RESET_VECTOR
  95
  96         /*
  97          * The following expressions place the 16-bit Real-Mode code and
  98          * Reset Vector at the end of the Flash ROM
  99          */
 100         . = START_16;
 101         .start16 : AT (CONFIG_SYS_TEXT_BASE + (CONFIG_SYS_MONITOR_LEN - RESET_SEG_SIZE + START_16)) { KEEP(*(.start16)); }
 102
 103         . = RESET_VEC_LOC;
 104         .resetvec : AT (CONFIG_SYS_TEXT_BASE + (CONFIG_SYS_MONITOR_LEN - RESET_SEG_SIZE + RESET_VEC_LOC)) { KEEP(*(.resetvec)); }
 105 #endif
 106 }