arch/x86/cpu/u-boot.lds

   1 /*
   2  * (C) Copyright 2002
   3  * Daniel Engström, Omicron Ceti AB, daniel@omicron.se.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 #include <config.h>
  25 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  26 OUTPUT_ARCH(i386)
  27 ENTRY(_start)
  28
  29 SECTIONS
  30 {
  31         . = CONFIG_SYS_TEXT_BASE;       /* Location of bootcode in flash */
  32         __text_start = .;
  33         .text  : { *(.text*); }
  34
  35         . = ALIGN(4);
  36
  37         . = ALIGN(4);
  38         .u_boot_list : {
  39         #include <u-boot.lst>
  40         }
  41
  42         . = ALIGN(4);
  43         .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
  44
  45         . = ALIGN(4);
  46         .data : { *(.data*) }
  47
  48         . = ALIGN(4);
  49         .dynsym : { *(.dynsym*) }
  50
  51         . = ALIGN(4);
  52         .hash : { *(.hash*) }
  53
  54         . = ALIGN(4);
  55         .got : { *(.got*) }
  56
  57         . = ALIGN(4);
  58         __data_end = .;
  59
  60         . = ALIGN(4);
  61         __bss_start = ABSOLUTE(.);
  62         .bss (NOLOAD) : { *(.bss) }
  63         . = ALIGN(4);
  64         __bss_end = ABSOLUTE(.);
  65
  66         . = ALIGN(4);
  67         __rel_dyn_start = .;
  68         .rel.dyn : { *(.rel.dyn) }
  69         __rel_dyn_end = .;
  70
  71         /DISCARD/ : { *(.dynstr*) }
  72         /DISCARD/ : { *(.dynamic*) }
  73         /DISCARD/ : { *(.plt*) }
  74         /DISCARD/ : { *(.interp*) }
  75         /DISCARD/ : { *(.gnu*) }
  76
  77         /* 16bit realmode trampoline code */
  78         .realmode REALMODE_BASE : AT ( LOADADDR(.rel.dyn) + SIZEOF(.rel.dyn) ) { KEEP(*(.realmode)) }
  79
  80         __realmode_start = LOADADDR(.realmode);
  81         __realmode_size = SIZEOF(.realmode);
  82
  83         /* 16bit BIOS emulation code (just enough to boot Linux) */
  84         .bios 0 : AT ( LOADADDR(.realmode) + SIZEOF(.realmode) ) { KEEP(*(.bios)) }
  85
  86         __bios_start = LOADADDR(.bios);
  87         __bios_size = SIZEOF(.bios);
  88
  89         /*
  90          * The following expressions place the 16-bit Real-Mode code and
  91          * Reset Vector at the end of the Flash ROM
  92          */
  93         . = START_16;
  94         .start16 : AT (CONFIG_SYS_TEXT_BASE + (CONFIG_SYS_MONITOR_LEN - RESET_SEG_SIZE + START_16)) { KEEP(*(.start16)); }
  95
  96         . = RESET_VEC_LOC;
  97         .resetvec : AT (CONFIG_SYS_TEXT_BASE + (CONFIG_SYS_MONITOR_LEN - RESET_SEG_SIZE + RESET_VEC_LOC)) { KEEP(*(.resetvec)); }
  98 }