board/actux2/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_FORMAT ("elf32-bigarm", "elf32-bigarm", "elf32-bigarm")
  25 OUTPUT_ARCH (arm)
  26 ENTRY (_start)
  27 SECTIONS
  28 {
  29         . = 0x00000000;
  30
  31         . = ALIGN (4);
  32         .text : {
  33                 arch/arm/cpu/ixp/start.o(.text*)
  34                 net/libnet.o(.text*)
  35                 board/actux2/libactux2.o(.text*)
  36                 arch/arm/cpu/ixp/libixp.o(.text*)
  37                 drivers/input/libinput.o(.text*)
  38
  39                 . = env_offset;
  40                 common/env_embedded.o(.ppcenv)
  41                 *(.text*)
  42         }
  43
  44         . = ALIGN(4);
  45         .rodata : {
  46                 *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  47         }
  48         . = ALIGN(4);
  49         .data : {
  50                 *(.data*)
  51         }
  52         . = ALIGN(4);
  53         .got : {
  54                 *(.got)
  55         }
  56         . =.;
  57
  58         . = ALIGN(4);
  59         .u_boot_list : {
  60                 KEEP(*(SORT(.u_boot_list*)));
  61         }
  62
  63         . = ALIGN (4);
  64
  65         __image_copy_end = .;
  66
  67         .rel.dyn : {
  68                 __rel_dyn_start = .;
  69                 *(.rel*)
  70                 __rel_dyn_end = .;
  71         }
  72
  73         .dynsym : {
  74                 __dynsym_start = .;
  75                 *(.dynsym)
  76         }
  77
  78         _end = .;
  79
  80 /*
  81  * Compiler-generated __bss_start and __bss_end, see arch/arm/lib/bss.c
  82  * __bss_base and __bss_limit are for linker only (overlay ordering)
  83  */
  84
  85         .bss_start __rel_dyn_start (OVERLAY) : {
  86                 KEEP(*(.__bss_start));
  87                 __bss_base = .;
  88         }
  89
  90         .bss __bss_base (OVERLAY) : {
  91                 *(.bss*)
  92                  . = ALIGN(4);
  93                  __bss_limit = .;
  94         }
  95         .bss_end __bss_limit (OVERLAY) : {
  96                 KEEP(*(.__bss_end));
  97         }
  98
  99         /DISCARD/ : { *(.dynstr*) }
 100         /DISCARD/ : { *(.dynamic*) }
 101         /DISCARD/ : { *(.plt*) }
 102         /DISCARD/ : { *(.interp*) }
 103         /DISCARD/ : { *(.gnu*) }
 104 }