board/adder/u-boot.lds

   1 /*
   2  * (C) Copyright 2001-2003
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * Modified by Yuli Barcohen <yuli@arabellasw.com>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_ARCH(powerpc)
  27 SECTIONS
  28 {
  29   /* Read-only sections, merged into text segment: */
  30   . = + SIZEOF_HEADERS;
  31   .interp        : { *(.interp)         }
  32   .hash          : { *(.hash)           }
  33   .dynsym        : { *(.dynsym)         }
  34   .dynstr        : { *(.dynstr)         }
  35   .rel.text      : { *(.rel.text)       }
  36   .rela.text     : { *(.rela.text)      }
  37   .rel.data      : { *(.rel.data)       }
  38   .rela.data     : { *(.rela.data)      }
  39   .rel.rodata    : { *(.rel.rodata)     }
  40   .rela.rodata   : { *(.rela.rodata)    }
  41   .rel.got       : { *(.rel.got)        }
  42   .rela.got      : { *(.rela.got)       }
  43   .rel.ctors     : { *(.rel.ctors)      }
  44   .rela.ctors    : { *(.rela.ctors)     }
  45   .rel.dtors     : { *(.rel.dtors)      }
  46   .rela.dtors    : { *(.rela.dtors)     }
  47   .rel.bss       : { *(.rel.bss)        }
  48   .rela.bss      : { *(.rela.bss)       }
  49   .rel.plt       : { *(.rel.plt)        }
  50   .rela.plt      : { *(.rela.plt)       }
  51   .init          : { *(.init)           }
  52   .plt           : { *(.plt)            }
  53   .text          :
  54   {
  55     arch/powerpc/cpu/mpc8xx/start.o     (.text)
  56     *(.text)
  57     *(.got1)
  58     . = ALIGN(16);
  59     *(.eh_frame)
  60     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  61   }
  62   .fini      : { *(.fini)    } =0
  63   .ctors     : { *(.ctors)   }
  64   .dtors     : { *(.dtors)   }
  65
  66   /* Read-write section, merged into data segment: */
  67   . = (. + 0x0FFF) & 0xFFFFF000;
  68   _erotext = .;
  69   PROVIDE (erotext = .);
  70   .reloc   :
  71   {
  72     *(.got)
  73     _GOT2_TABLE_ = .;
  74     *(.got2)
  75     _FIXUP_TABLE_ = .;
  76     *(.fixup)
  77   }
  78   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  79   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  80
  81   .data    :
  82   {
  83     *(.data)
  84     *(.data1)
  85     *(.sdata)
  86     *(.sdata2)
  87     *(.dynamic)
  88     CONSTRUCTORS
  89   }
  90   _edata  =  .;
  91   PROVIDE (edata = .);
  92
  93   . = .;
  94   __u_boot_cmd_start = .;
  95   .u_boot_cmd : { *(.u_boot_cmd) }
  96   __u_boot_cmd_end = .;
  97
  98
  99   . = .;
 100   __start___ex_table = .;
 101   __ex_table : { *(__ex_table) }
 102   __stop___ex_table = .;
 103
 104   . = ALIGN(4096);
 105   __init_begin = .;
 106   .text.init : { *(.text.init) }
 107   .data.init : { *(.data.init) }
 108   . = ALIGN(4096);
 109   __init_end = .;
 110
 111   __bss_start = .;
 112   .bss (NOLOAD)       :
 113   {
 114    *(.sbss) *(.scommon)
 115    *(.dynbss)
 116    *(.bss)
 117    *(COMMON)
 118    . = ALIGN(4);
 119   }
 120   _end = . ;
 121   PROVIDE (end = .);
 122 }
 123 ENTRY(_start)