board/dave/PPChameleonEVB/u-boot.lds

   1 /*
   2  * Copyright 2007-2009 Freescale Semiconductor, Inc.
   3  *
   4  * See file CREDITS for list of people who contributed to this
   5  * project.
   6  *
   7  * This program is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License as
   9  * published by the Free Software Foundation; either version 2 of
  10  * the License, or (at your option) any later version.
  11  *
  12  * This program is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with this program; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20  * MA 02111-1307 USA
  21  */
  22
  23 #include "config.h"     /* CONFIG_BOARDDIR */
  24
  25 #ifndef RESET_VECTOR_ADDRESS
  26 #define RESET_VECTOR_ADDRESS    0xfffffffc
  27 #endif
  28
  29 OUTPUT_ARCH(powerpc)
  30
  31 PHDRS
  32 {
  33   text PT_LOAD;
  34   bss PT_LOAD;
  35 }
  36
  37 SECTIONS
  38 {
  39   /* Read-only sections, merged into text segment: */
  40   . = + SIZEOF_HEADERS;
  41   .text      :
  42   {
  43     *(.text*)
  44    } :text
  45     _etext = .;
  46     PROVIDE (etext = .);
  47     .rodata    :
  48    {
  49     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  50   } :text
  51
  52   /* Read-write section, merged into data segment: */
  53   . = (. + 0x00FF) & 0xFFFFFF00;
  54   _erotext = .;
  55   PROVIDE (erotext = .);
  56   .reloc   :
  57   {
  58     KEEP(*(.got))
  59     _GOT2_TABLE_ = .;
  60     KEEP(*(.got2))
  61     _FIXUP_TABLE_ = .;
  62     KEEP(*(.fixup))
  63   }
  64   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  65   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  66
  67   .data    :
  68   {
  69     *(.data*)
  70     *(.sdata*)
  71   }
  72   _edata  =  .;
  73   PROVIDE (edata = .);
  74
  75   . = .;
  76   __u_boot_cmd_start = .;
  77   .u_boot_cmd : { *(.u_boot_cmd) }
  78   __u_boot_cmd_end = .;
  79
  80   . = .;
  81   __start___ex_table = .;
  82   __ex_table : { *(__ex_table) }
  83   __stop___ex_table = .;
  84
  85   . = ALIGN(256);
  86   __init_begin = .;
  87   .text.init : { *(.text.init) }
  88   .data.init : { *(.data.init) }
  89   . = ALIGN(256);
  90   __init_end = .;
  91
  92   ppcenv_assert = ASSERT(. < 0xFFFF8000, ".bss section too big, overlaps .ppcenv section. Please update your confguration: CONFIG_SYS_MONITOR_BASE, CONFIG_SYS_MONITOR_LEN and CONFIG_SYS_TEXT_BASE may need to be modified.");
  93   . = 0xFFFF8000;
  94   .ppcenv :
  95   {
  96     common/env_embedded.o(.ppcenv);
  97   }
  98
  99   .resetvec RESET_VECTOR_ADDRESS :
 100   {
 101     KEEP(*(.resetvec))
 102   } :text = 0xffff
 103
 104   . = RESET_VECTOR_ADDRESS + 0x4;
 105
 106   /*
 107    * Make sure that the bss segment isn't linked at 0x0, otherwise its
 108    * address won't be updated during relocation fixups.  Note that
 109    * this is a temporary fix.  Code to dynamically the fixup the bss
 110    * location will be added in the future.  When the bss relocation
 111    * fixup code is present this workaround should be removed.
 112    */
 113 #if (RESET_VECTOR_ADDRESS == 0xfffffffc)
 114   . |= 0x10;
 115 #endif
 116
 117   __bss_start = .;
 118   .bss (NOLOAD)       :
 119   {
 120    *(.bss*)
 121    *(.sbss*)
 122    *(COMMON)
 123   } :bss
 124
 125   . = ALIGN(4);
 126   _end = . ;
 127   PROVIDE (end = .);
 128 }