board/esd/ocrtc/u-boot.lds

   1 /*
   2  * (C) Copyright 2001
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 /* Do we need any of these for elf?
  26    __DYNAMIC = 0;    */
  27 SECTIONS
  28 {
  29   .resetvec 0xFFFFFFFC :
  30   {
  31     *(.resetvec)
  32   } = 0xffff
  33
  34   /* Read-only sections, merged into text segment: */
  35   . = + SIZEOF_HEADERS;
  36   .interp : { *(.interp) }
  37   .hash          : { *(.hash)           }
  38   .dynsym        : { *(.dynsym)         }
  39   .dynstr        : { *(.dynstr)         }
  40   .rel.text      : { *(.rel.text)               }
  41   .rela.text     : { *(.rela.text)      }
  42   .rel.data      : { *(.rel.data)               }
  43   .rela.data     : { *(.rela.data)      }
  44   .rel.rodata    : { *(.rel.rodata)     }
  45   .rela.rodata   : { *(.rela.rodata)    }
  46   .rel.got       : { *(.rel.got)                }
  47   .rela.got      : { *(.rela.got)               }
  48   .rel.ctors     : { *(.rel.ctors)      }
  49   .rela.ctors    : { *(.rela.ctors)     }
  50   .rel.dtors     : { *(.rel.dtors)      }
  51   .rela.dtors    : { *(.rela.dtors)     }
  52   .rel.bss       : { *(.rel.bss)                }
  53   .rela.bss      : { *(.rela.bss)               }
  54   .rel.plt       : { *(.rel.plt)                }
  55   .rela.plt      : { *(.rela.plt)               }
  56   .init          : { *(.init)   }
  57   .plt : { *(.plt) }
  58   .text      :
  59   {
  60     /* WARNING - the following is hand-optimized to fit within  */
  61     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  62
  63     cpu/ppc4xx/start.o  (.text)
  64     cpu/ppc4xx/traps.o  (.text)
  65     cpu/ppc4xx/interrupts.o     (.text)
  66     cpu/ppc4xx/4xx_uart.o       (.text)
  67     cpu/ppc4xx/cpu_init.o       (.text)
  68     cpu/ppc4xx/speed.o  (.text)
  69     common/dlmalloc.o   (.text)
  70     lib_generic/crc32.o         (.text)
  71     lib_ppc/extable.o   (.text)
  72     lib_generic/zlib.o          (.text)
  73
  74 /*    . = env_offset;*/
  75 /*    common/env_embedded.o(.text)*/
  76
  77     *(.text)
  78     *(.fixup)
  79     *(.got1)
  80   }
  81   _etext = .;
  82   PROVIDE (etext = .);
  83   .rodata    :
  84   {
  85     *(.eh_frame)
  86     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  87   }
  88   .fini      : { *(.fini)    } =0
  89   .ctors     : { *(.ctors)   }
  90   .dtors     : { *(.dtors)   }
  91
  92   /* Read-write section, merged into data segment: */
  93   . = (. + 0x00FF) & 0xFFFFFF00;
  94   _erotext = .;
  95   PROVIDE (erotext = .);
  96   .reloc   :
  97   {
  98     *(.got)
  99     _GOT2_TABLE_ = .;
 100     *(.got2)
 101     _FIXUP_TABLE_ = .;
 102     *(.fixup)
 103   }
 104   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 105   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 106
 107   .data    :
 108   {
 109     *(.data)
 110     *(.data1)
 111     *(.sdata)
 112     *(.sdata2)
 113     *(.dynamic)
 114     CONSTRUCTORS
 115   }
 116   _edata  =  .;
 117   PROVIDE (edata = .);
 118
 119   . = .;
 120   __u_boot_cmd_start = .;
 121   .u_boot_cmd : { *(.u_boot_cmd) }
 122   __u_boot_cmd_end = .;
 123
 124
 125   . = .;
 126   __start___ex_table = .;
 127   __ex_table : { *(__ex_table) }
 128   __stop___ex_table = .;
 129
 130   . = ALIGN(256);
 131   __init_begin = .;
 132   .text.init : { *(.text.init) }
 133   .data.init : { *(.data.init) }
 134   . = ALIGN(256);
 135   __init_end = .;
 136
 137   __bss_start = .;
 138   .bss (NOLOAD)       :
 139   {
 140    *(.sbss) *(.scommon)
 141    *(.dynbss)
 142    *(.bss)
 143    *(COMMON)
 144    . = ALIGN(4);
 145   }
 146   _end = . ;
 147   PROVIDE (end = .);
 148 }