board/gen860t/u-boot.lds

   1 /*
   2  * Linker command file for the GEN860T board.
   3  *
   4  * (C) Copyright 2000-2010
   5  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_ARCH(powerpc)
  27 SECTIONS
  28 {
  29   /*
  30    * Read-only sections, merged into text segment:
  31    */
  32   . = + SIZEOF_HEADERS;
  33   .text :
  34   {
  35     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  36     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  37
  38     *(.text*)
  39   }
  40   _etext = .;
  41   PROVIDE (etext = .);
  42   .rodata    :
  43   {
  44     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  45   }
  46
  47   /*
  48    * Read-write section, merged into data segment:
  49    */
  50   . = (. + 0x00FF) & 0xFFFFFF00;
  51   _erotext = .;
  52   PROVIDE (erotext = .);
  53   .reloc   :
  54   {
  55     _GOT2_TABLE_ = .;
  56     KEEP(*(.got2))
  57     KEEP(*(.got))
  58     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  59     _FIXUP_TABLE_ = .;
  60     KEEP(*(.fixup))
  61   }
  62   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  63   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  64
  65   .data    :
  66   {
  67     *(.data*)
  68     *(.sdata*)
  69   }
  70   _edata  =  .;
  71   PROVIDE (edata = .);
  72
  73   . = .;
  74
  75   . = ALIGN(4);
  76   .u_boot_list : {
  77         KEEP(*(SORT(.u_boot_list*)));
  78   }
  79
  80
  81   . = .;
  82   __start___ex_table = .;
  83   __ex_table : { *(__ex_table) }
  84   __stop___ex_table = .;
  85
  86   . = ALIGN(256);
  87   __init_begin = .;
  88   .text.init : { *(.text.init) }
  89   .data.init : { *(.data.init) }
  90   . = ALIGN(256);
  91   __init_end = .;
  92
  93   __bss_start = .;
  94   .bss (NOLOAD)       :
  95   {
  96    *(.bss*)
  97    *(.sbss*)
  98    *(COMMON)
  99    . = ALIGN(4);
 100   }
 101   __bss_end = . ;
 102   PROVIDE (end = .);
 103 }