board/gen860t/u-boot.lds

   1 /*
   2  * Linker command file for the GEN860T board.
   3  *
   4  * (C) Copyright 2000
   5  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26 OUTPUT_ARCH(powerpc)
  27 SECTIONS
  28 {
  29   /*
  30    * Read-only sections, merged into text segment:
  31    */
  32   . = + SIZEOF_HEADERS;
  33   .interp        : { *(.interp)         }
  34   .hash          : { *(.hash)           }
  35   .dynsym        : { *(.dynsym)         }
  36   .dynstr        : { *(.dynstr)         }
  37   .rel.text      : { *(.rel.text)       }
  38   .rela.text     : { *(.rela.text)      }
  39   .rel.data      : { *(.rel.data)       }
  40   .rela.data     : { *(.rela.data)      }
  41   .rel.rodata    : { *(.rel.rodata)     }
  42   .rela.rodata   : { *(.rela.rodata)    }
  43   .rel.got       : { *(.rel.got)        }
  44   .rela.got      : { *(.rela.got)       }
  45   .rel.ctors     : { *(.rel.ctors)      }
  46   .rela.ctors    : { *(.rela.ctors)     }
  47   .rel.dtors     : { *(.rel.dtors)      }
  48   .rela.dtors    : { *(.rela.dtors)     }
  49   .rel.bss       : { *(.rel.bss)        }
  50   .rela.bss      : { *(.rela.bss)       }
  51   .rel.plt       : { *(.rel.plt)        }
  52   .rela.plt      : { *(.rela.plt)       }
  53   .init          : { *(.init)           }
  54   .plt           : { *(.plt)            }
  55   .text :
  56   {
  57     cpu/mpc8xx/start.o          (.text)
  58     *(.text)
  59     *(.fixup)
  60     *(.got1)
  61   }
  62   _etext = .;
  63   PROVIDE (etext = .);
  64   .rodata    :
  65   {
  66     *(.eh_frame)
  67     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  68   }
  69   .fini      : { *(.fini)    } =0
  70   .ctors     : { *(.ctors)   }
  71   .dtors     : { *(.dtors)   }
  72
  73   /*
  74    * Read-write section, merged into data segment:
  75    */
  76   . = (. + 0x00FF) & 0xFFFFFF00;
  77   _erotext = .;
  78   PROVIDE (erotext = .);
  79   .reloc   :
  80   {
  81     *(.got)
  82     _GOT2_TABLE_ = .;
  83     *(.got2)
  84     _FIXUP_TABLE_ = .;
  85     *(.fixup)
  86   }
  87   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  88   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  89
  90   .data    :
  91   {
  92     *(.data)
  93     *(.data1)
  94     *(.sdata)
  95     *(.sdata2)
  96     *(.dynamic)
  97     CONSTRUCTORS
  98   }
  99   _edata  =  .;
 100   PROVIDE (edata = .);
 101
 102   . = .;
 103   __u_boot_cmd_start = .;
 104   .u_boot_cmd : { *(.u_boot_cmd) }
 105   __u_boot_cmd_end = .;
 106
 107
 108   . = .;
 109   __start___ex_table = .;
 110   __ex_table : { *(__ex_table) }
 111   __stop___ex_table = .;
 112
 113   . = ALIGN(256);
 114   __init_begin = .;
 115   .text.init : { *(.text.init) }
 116   .data.init : { *(.data.init) }
 117   . = ALIGN(256);
 118   __init_end = .;
 119
 120   __bss_start = .;
 121   .bss (NOLOAD)       :
 122   {
 123    *(.sbss) *(.scommon)
 124    *(.dynbss)
 125    *(.bss)
 126    *(COMMON)
 127    . = ALIGN(4);
 128   }
 129   _end = . ;
 130   PROVIDE (end = .);
 131 }