board/genietv/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9
  10 SECTIONS
  11 {
  12   /* Read-only sections, merged into text segment: */
  13   . = + SIZEOF_HEADERS;
  14   .text      :
  15   {
  16     /* WARNING - the following is hand-optimized to fit within  */
  17     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  18
  19     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  20     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  21     lib/built-in.o                      (.text*)
  22     net/built-in.o                      (.text*)
  23     arch/powerpc/cpu/mpc8xx/built-in.o  (.text*)
  24     board/genietv/built-in.o            (.text*)
  25     arch/powerpc/lib/built-in.o         (.text*)
  26     *(.text.do_load_serial*)
  27     *(.text.do_mem_*)
  28     *(.text.do_bootm*)
  29
  30     . = env_offset;
  31     common/env_embedded.o               (.text*)
  32
  33     *(.text*)
  34   }
  35   _etext = .;
  36   PROVIDE (etext = .);
  37   .rodata    :
  38   {
  39     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  40   }
  41
  42   /* Read-write section, merged into data segment: */
  43   . = (. + 0x0FFF) & 0xFFFFF000;
  44   _erotext = .;
  45   PROVIDE (erotext = .);
  46   .reloc   :
  47   {
  48     _GOT2_TABLE_ = .;
  49     KEEP(*(.got2))
  50     KEEP(*(.got))
  51     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  52     _FIXUP_TABLE_ = .;
  53     KEEP(*(.fixup))
  54   }
  55   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  56   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  57
  58   .data    :
  59   {
  60     *(.data*)
  61     *(.sdata*)
  62   }
  63   _edata  =  .;
  64   PROVIDE (edata = .);
  65
  66   . = .;
  67
  68   . = ALIGN(4);
  69   .u_boot_list : {
  70         KEEP(*(SORT(.u_boot_list*)));
  71   }
  72
  73
  74   . = .;
  75   __start___ex_table = .;
  76   __ex_table : { *(__ex_table) }
  77   __stop___ex_table = .;
  78
  79   . = ALIGN(4096);
  80   __init_begin = .;
  81   .text.init : { *(.text.init) }
  82   .data.init : { *(.data.init) }
  83   . = ALIGN(4096);
  84   __init_end = .;
  85
  86   __bss_start = .;
  87   .bss (NOLOAD)       :
  88   {
  89    *(.bss*)
  90    *(.sbss*)
  91    *(COMMON)
  92   }
  93   . = ALIGN(256 * 1024);
  94   .ppcenv       :
  95   {
  96     common/env_embedded.o (.ppcenv)
  97   }
  98   . = ALIGN(4);
  99   __bss_end = . ;
 100   PROVIDE (end = .);
 101 }