board/genietv/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25
  26 SECTIONS
  27 {
  28   /* Read-only sections, merged into text segment: */
  29   . = + SIZEOF_HEADERS;
  30   .text      :
  31   {
  32     /* WARNING - the following is hand-optimized to fit within  */
  33     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  34
  35     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  36     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  37     lib/libgeneric.o                    (.text*)
  38     net/libnet.o                        (.text*)
  39     arch/powerpc/cpu/mpc8xx/libmpc8xx.o (.text*)
  40     board/genietv/libgenietv.o          (.text*)
  41     arch/powerpc/lib/libpowerpc.o       (.text*)
  42     *(.text.do_load_serial*)
  43     *(.text.do_mem_*)
  44     *(.text.do_bootm*)
  45
  46     . = env_offset;
  47     common/env_embedded.o               (.text*)
  48
  49     *(.text*)
  50   }
  51   _etext = .;
  52   PROVIDE (etext = .);
  53   .rodata    :
  54   {
  55     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  56   }
  57
  58   /* Read-write section, merged into data segment: */
  59   . = (. + 0x0FFF) & 0xFFFFF000;
  60   _erotext = .;
  61   PROVIDE (erotext = .);
  62   .reloc   :
  63   {
  64     _GOT2_TABLE_ = .;
  65     KEEP(*(.got2))
  66     KEEP(*(.got))
  67     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  68     _FIXUP_TABLE_ = .;
  69     KEEP(*(.fixup))
  70   }
  71   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  72   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  73
  74   .data    :
  75   {
  76     *(.data*)
  77     *(.sdata*)
  78   }
  79   _edata  =  .;
  80   PROVIDE (edata = .);
  81
  82   . = .;
  83
  84   . = ALIGN(4);
  85   .u_boot_list : {
  86         KEEP(*(SORT(.u_boot_list*)));
  87   }
  88
  89
  90   . = .;
  91   __start___ex_table = .;
  92   __ex_table : { *(__ex_table) }
  93   __stop___ex_table = .;
  94
  95   . = ALIGN(4096);
  96   __init_begin = .;
  97   .text.init : { *(.text.init) }
  98   .data.init : { *(.data.init) }
  99   . = ALIGN(4096);
 100   __init_end = .;
 101
 102   __bss_start = .;
 103   .bss (NOLOAD)       :
 104   {
 105    *(.bss*)
 106    *(.sbss*)
 107    *(COMMON)
 108   }
 109   . = ALIGN(256 * 1024);
 110   .ppcenv       :
 111   {
 112     common/env_embedded.o (.ppcenv)
 113   }
 114   . = ALIGN(4);
 115   __bss_end__ = . ;
 116   PROVIDE (end = .);
 117 }