board/hermes/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2010
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9
  10 SECTIONS
  11 {
  12   /* Read-only sections, merged into text segment: */
  13   . = + SIZEOF_HEADERS;
  14   .text      :
  15   {
  16     /* WARNING - the following is hand-optimized to fit within  */
  17     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  18     arch/powerpc/cpu/mpc8xx/start.o     (.text*)
  19     arch/powerpc/cpu/mpc8xx/traps.o     (.text*)
  20     board/hermes/built-in.o             (.text*)
  21
  22     . = env_offset;
  23     common/env_embedded.o               (.text*)
  24
  25     *(.text*)
  26   }
  27   _etext = .;
  28   PROVIDE (etext = .);
  29   .rodata    :
  30   {
  31     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  32   }
  33
  34   /* Read-write section, merged into data segment: */
  35   . = (. + 0x00FF) & 0xFFFFFF00;
  36   _erotext = .;
  37   PROVIDE (erotext = .);
  38   .reloc   :
  39   {
  40     _GOT2_TABLE_ = .;
  41     KEEP(*(.got2))
  42     KEEP(*(.got))
  43     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  44     _FIXUP_TABLE_ = .;
  45     KEEP(*(.fixup))
  46   }
  47   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  48   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  49
  50   .data    :
  51   {
  52     *(.data*)
  53     *(.sdata*)
  54   }
  55   _edata  =  .;
  56   PROVIDE (edata = .);
  57
  58   . = .;
  59
  60   . = ALIGN(4);
  61   .u_boot_list : {
  62         KEEP(*(SORT(.u_boot_list*)));
  63   }
  64
  65
  66   . = .;
  67   __start___ex_table = .;
  68   __ex_table : { *(__ex_table) }
  69   __stop___ex_table = .;
  70
  71   . = ALIGN(256);
  72   __init_begin = .;
  73   .text.init : { *(.text.init) }
  74   .data.init : { *(.data.init) }
  75   . = ALIGN(256);
  76   __init_end = .;
  77
  78   __bss_start = .;
  79   .bss (NOLOAD)       :
  80   {
  81    *(.bss*)
  82    *(.sbss*)
  83    *(COMMON)
  84    . = ALIGN(4);
  85   }
  86   __bss_end = . ;
  87   PROVIDE (end = .);
  88 }